AIR 中的任务栏图标

通过创建包含命令的 NativeMenu 对象并将其分配给 NativeApplication.nativeApplication.icon.menu 属性，可以向标准停靠栏菜单中添加命令。菜单中的项目显示在标准停靠栏图标菜单项的上方。

通过调用 NativeApplication.nativeApplication.icon.bounce() 方法，可以回弹停靠栏图标。如果将 bounce() priority 参数设置为 informational，则图标将回弹一次。如果将该参数设置为 critical，则图标将始终保持回弹状态，直到用户激活该应用程序。用作 priority 参数的常量由 NotificationType 类定义。

单击停靠栏图标后，NativeApplication 对象将调度 invoke 事件。如果应用程序尚未运行，则系统将启动该应用程序。否则，invoke 事件将传送到正在运行的应用程序实例。

通过创建 NativeMenu 对象并将其分配给 NativeApplication.nativeApplication.icon.menu 属性，可以向系统任务栏图标中添加菜单（操作系统不会提供任何默认菜单）。右键单击图标即可访问系统任务栏图标菜单。

通过设置 tooltip 属性可以向图标添加工具提示：

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

NativeApplication.nativeApplication.icon 属性引用的 SystemTrayIcon 对象可以为 click、mouseDown、mouseUp、rightClick、rightMouseDown 和 rightMouseUp 事件调度 ScreenMouseEvent。可以组合使用这些事件和图标菜单，以便用户能够在您的应用程序没有可见窗口时与应用程序进行交互。

以下示例创建了一个具有系统任务栏图标但没有可见窗口的 AIR 应用程序。（在应用程序描述符中，不得将应用程序的 visible 属性设置为 true，否则窗口在应用程序启动时可见。）

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

如果窗口位于后台，则可以通知用户发生了与该窗口相关的需要关注的事件。在 Mac OS X 中，可以通过回弹应用程序的停靠栏图标来通知用户（如回弹停靠栏中所述）。在 Windows 和 Linux 中，可以通过调用 NativeWindow 实例的 notifyUser() 方法来加亮显示窗口的任务栏按钮。传递给该方法的 type 参数用于确定通知的紧急程度：

• NotificationType.CRITICAL：在用户将窗口置于前台之前，窗口图标一直闪烁。

• NotificationType.INFORMATIONAL：通过更改颜色来加亮显示窗口图标。

  注： 在 Linux 中，仅支持信息性类型的通知。向 notifyUser() 函数传递任何一种类型值都会产生相同的效果。

  以下语句加亮显示窗口的任务栏按钮：

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  在不支持窗口级别通知的操作系统中，调用 NativeWindow.notifyUser() 方法将不起作用。使用 NativeWindow.supportsNotification 属性可确定是否支持窗口通知。

在 Windows 操作系统中，使用 utility 或 lightweight 类型创建的窗口不会显示在任务栏中。不可见窗口也不会显示在任务栏中。

由于初始窗口必定为 normal 类型，因此要创建不会在任务栏中显示任何窗口的应用程序，必须关闭初始窗口或保持初始窗口不可见。若要关闭应用程序中的所有窗口而不终止应用程序，请在关闭最后一个窗口之前，将 NativeApplication 对象的 autoExit 属性设置为 false。如果只是需要使初始窗口变得不可见，请向应用程序描述符文件的 <initalWindow> 元素添加 <visible>false</visible>（且不要将 visible 属性设置为 true 或调用窗口的 activate() 方法）。

在应用程序打开的新窗口中，将传递给窗口构造函数的 NativeWindowInitOption 对象的 type 属性设置为 NativeWindowType.UTILITY 或 NativeWindowType.LIGHTWEIGHT。

在 Mac OS X 中，最小化的窗口显示在停靠任务栏中。通过隐藏窗口而不是最小化窗口可以避免显示最小化的图标。以下示例侦听 nativeWindowDisplayState 更改事件，并在窗口最小化时取消该事件。处理函数会改为将窗口的 visible 属性设置为 false：

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

如果将 visible 属性设置为 false 后窗口最小化到 Mac OS X 停靠栏中，则无法删除该停靠栏图标。用户仍可单击图标来重新显示窗口。