网络和通信基础知识

可以使用 NetworkInfo 对象了解您的应用程序可以使用的硬件和软件网络接口。NetworkInfo 对象是 singleton 对象，无需您创建。您可以使用静态类属性 networkInfo 访问单个 NetworkInfo 对象。当某一个可用接口更改时，NetworkInfo 对象还将调度 networkChange 事件。

调用 findInterfaces() 方法可以获取 NetworkInterface 对象列表。列表中的每个 NetworkInterface 对象描述一个可用接口。NetworkInterface 对象提供了 IP 地址、硬件地址、最大传输单位以及此接口是否处于活动状态等信息。

以下代码示例跟踪客户端计算机上每个接口的 NetworkInterface 属性：

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

有关详细信息，请参阅：

• NetworkInfo

• NetworkInterface

• InterfaceAddress

AIR 应用程序可以在具有不确定且不断更改的网络连接的环境中运行。为了有助于应用程序管理到在线资源的连接，每当网络连接变为可用或不可用时 Adobe AIR 都会发送一个网络更改事件。NetworkInfo 对象和应用程序的 NativeApplication 对象均会调度 networkChange 事件。为了响应该事件，可添加一个侦听器：

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

并定义一个事件处理函数：

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

networkChange 事件不指示所有网络活动中的更改，仅指示个别网络连接已更改。AIR 不尝试解释网络更改的含义。网络计算机可以具有许多真实连接和虚拟连接，因此中断连接不一定意味着丢失资源。而另一方面，新建连接也无法保证改善资源的可用性。有时，新建连接甚至可能阻止对之前可用资源的访问（例如，连接到 VPN 时）。

通常，应用程序确定其是否可连接到远程资源的唯一方法是，尝试连接该远程资源。服务监控框架提供了一种基于事件的方式来响应对指定主机的网络连接的更改。

使用 DNSResolver 类，您可以查找 DNS 资源记录。DNS 资源记录提供了域名的 IP 地址和 IP 地址的域名等信息。可以查找以下类型的 DNS 资源记录：

• ARecord — 主机的 IPv4 地址。

• AAAARecord — 主机的 IPv6 地址。

• MXRecord — 主机的邮件交换记录。

• PTRRecord — IP 地址的主机名。

• SRVRecord — 服务的服务记录。。

要查找记录，您可将查询字符串和表示记录类型的类对象传递给 DNSResolver 对象的 lookup() 方法。要使用的查询字符串取决于记录类型：

以下代码示例查找主机“example.com”的 IP 地址。

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

有关详细信息，请参阅：

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord