subroutine dlaswlq	(	integer	M,
		integer	N,
		integer	MB,
		integer	NB,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldt, *)	T,
		integer	LDT,
		double precision, dimension( * )	WORK,
		integer	LWORK,
		integer	INFO
	)

Purpose:

DLASWLQ computes a blocked Short-Wide LQ factorization of a M-by-N matrix A, where N >= M: A = L * Q

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= M >= 0.
[in]	MB	MB is INTEGER The row block size to be used in the blocked QR. M >= MB >= 1
[in]	NB	NB is INTEGER The column block size to be used in the blocked QR. NB > M.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, the elements on and bleow the diagonal of the array contain the N-by-N lower triangular matrix L; the elements above the diagonal represent Q by the rows of blocked V (see Further Details).
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	T	T is DOUBLE PRECISION array, dimension (LDT, N * Number_of_row_blocks) where Number_of_row_blocks = CEIL((N-M)/(NB-M)) The blocked upper triangular block reflectors stored in compact form as a sequence of upper triangular blocks. See Further Details below.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= MB.
[out]	WORK	(workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
[in]	LWORK	The dimension of the array WORK. LWORK >= MB*M. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations, representing Q as a product of other orthogonal matrices Q = Q(1) * Q(2) * . . . * Q(k) where each Q(i) zeros out upper diagonal entries of a block of NB rows of A: Q(1) zeros out the upper diagonal entries of rows 1:NB of A Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A . . .

Q(1) is computed by GELQT, which represents Q(1) by Householder vectors stored under the diagonal of rows 1:MB of A, and by upper triangular block reflectors, stored in array T(1:LDT,1:N). For more information see Further Details in GELQT.

Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M). The last Q(k) may use fewer rows. For more information see Further Details in TPQRT.

For more details of the overall algorithm, see the description of Sequential TSQR in Section 2.2 of [1].

[1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,” J. Demmel, L. Grigori, M. Hoemmen, J. Langou, SIAM J. Sci. Comput, vol. 34, no. 1, 2012

Definition at line 152 of file dlaswlq.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER           info, lda, m, n, mb, nb, lwork, ldt
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION  a( lda, * ), work( * ), t( ldt, *)
*     ..
*
*  =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL    lquery
      INTEGER    i, ii, kk, ctr
*     ..
*     .. EXTERNAL FUNCTIONS ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     .. EXTERNAL SUBROUTINES ..
      EXTERNAL           dgelqt, dtplqt, xerbla
*     .. INTRINSIC FUNCTIONS ..
      INTRINSIC          max, min, mod
*     ..
*     .. EXECUTABLE STATEMENTS ..
*
*     TEST THE INPUT ARGUMENTS
*
      info = 0
*
      lquery = ( lwork.EQ.-1 )
*
      IF( m.LT.0 ) THEN
        info = -1
      ELSE IF( n.LT.0 .OR. n.LT.m ) THEN
        info = -2
      ELSE IF( mb.LT.1 .OR. ( mb.GT.m .AND. m.GT.0 )) THEN
        info = -3
      ELSE IF( nb.LE.m ) THEN
        info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
        info = -5
      ELSE IF( ldt.LT.mb ) THEN
        info = -8
      ELSE IF( ( lwork.LT.m*mb) .AND. (.NOT.lquery) ) THEN
        info = -10
      END IF
      IF( info.EQ.0)  THEN
      work(1) = mb*m
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'DLASWLQ', -info )
        RETURN
      ELSE IF (lquery) THEN
       RETURN
      END IF
*
*     Quick return if possible
*
      IF( min(m,n).EQ.0 ) THEN
          RETURN
      END IF
*
*     The LQ Decomposition
*
       IF((m.GE.n).OR.(nb.LE.m).OR.(nb.GE.n)) THEN
        CALL dgelqt( m, n, mb, a, lda, t, ldt, work, info)
        RETURN
       END IF
*
       kk = mod((n-m),(nb-m))
       ii=n-kk+1
*
*      Compute the LQ factorization of the first block A(1:M,1:NB)
*
       CALL dgelqt( m, nb, mb, a(1,1), lda, t, ldt, work, info)
       ctr = 1
*
       DO i = nb+1, ii-nb+m , (nb-m)
*
*      Compute the QR factorization of the current block A(1:M,I:I+NB-M)
*
         CALL dtplqt( m, nb-m, 0, mb, a(1,1), lda, a( 1, i ),
     $                  lda, t(1, ctr * m + 1),
     $                  ldt, work, info )
         ctr = ctr + 1
       END DO
*
*     Compute the QR factorization of the last block A(1:M,II:N)
*
       IF (ii.LE.n) THEN
        CALL dtplqt( m, kk, 0, mb, a(1,1), lda, a( 1, ii ),
     $                  lda, t(1, ctr * m + 1), ldt,
     $                  work, info )
       END IF
*
      work( 1 ) = m * mb
      RETURN
*
*     End of DLASWLQ
*

Here is the call graph for this function:

Here is the caller graph for this function: