LAPACK  3.7.0
LAPACK: Linear Algebra PACKage
subroutine ctplqt2 ( integer  M,
integer  N,
integer  L,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldt, * )  T,
integer  LDT,
integer  INFO 
)
Purpose:

CTPLQT2 computes a LQ a factorization of a complex "triangular-pentagonal" matrix C, which is composed of a triangular block A and pentagonal block B, using the compact WY representation for Q.

Parameters
[in]M
          M is INTEGER
          The total number of rows of the matrix B.
          M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix B, and the order of
          the triangular matrix A.
          N >= 0.
[in]L
          L is INTEGER
          The number of rows of the lower trapezoidal part of B.
          MIN(M,N) >= L >= 0.  See Further Details.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the lower triangular M-by-M matrix A.
          On exit, the elements on and below the diagonal of the array
          contain the lower triangular matrix L.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX array, dimension (LDB,N)
          On entry, the pentagonal M-by-N matrix B.  The first N-L columns
          are rectangular, and the last L columns are lower trapezoidal.
          On exit, B contains the pentagonal matrix V.  See Further Details.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,M).
[out]T
          T is COMPLEX array, dimension (LDT,M)
          The N-by-N upper triangular factor T of the block reflector.
          See Further Details.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= max(1,M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:

The input matrix C is a M-by-(M+N) matrix

C = [ A ][ B ]

where A is an lower triangular N-by-N matrix, and B is M-by-N pentagonal matrix consisting of a M-by-(N-L) rectangular matrix B1 left of a M-by-L upper trapezoidal matrix B2:

B = [ B1 ][ B2 ] [ B1 ] <- M-by-(N-L) rectangular [ B2 ] <- M-by-L lower trapezoidal.

The lower trapezoidal matrix B2 consists of the first L columns of a N-by-N lower triangular matrix, where 0 <= L <= MIN(M,N). If L=0, B is rectangular M-by-N; if M=L=N, B is lower triangular.

The matrix W stores the elementary reflectors H(i) in the i-th row above the diagonal (of A) in the M-by-(M+N) input matrix C

C = [ A ][ B ] [ A ] <- lower triangular N-by-N [ B ] <- M-by-N pentagonal

so that W can be represented as

W = [ I ][ V ] [ I ] <- identity, N-by-N [ V ] <- M-by-N, same form as B.

Thus, all of information needed for W is contained on exit in B, which we call V above. Note that V has the same form as B; that is,

W = [ V1 ][ V2 ] [ V1 ] <- M-by-(N-L) rectangular [ V2 ] <- M-by-L lower trapezoidal.

The rows of V represent the vectors which define the H(i)'s. The (M+N)-by-(M+N) block reflector H is then given by

H = I - W**T * T * W

where W^H is the conjugate transpose of W and T is the upper triangular factor of the block reflector.

Definition at line 162 of file ctplqt2.f.

162 *
163 * -- LAPACK computational routine (version 3.7.0) --
164 * -- LAPACK is a software package provided by Univ. of Tennessee, --
165 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
166 * December 2016
167 *
168 * .. Scalar Arguments ..
169  INTEGER info, lda, ldb, ldt, n, m, l
170 * ..
171 * .. Array Arguments ..
172  COMPLEX a( lda, * ), b( ldb, * ), t( ldt, * )
173 * ..
174 *
175 * =====================================================================
176 *
177 * .. Parameters ..
178  COMPLEX one, zero
179  parameter( zero = ( 0.0e+0, 0.0e+0 ),one = ( 1.0e+0, 0.0e+0 ) )
180 * ..
181 * .. Local Scalars ..
182  INTEGER i, j, p, mp, np
183  COMPLEX alpha
184 * ..
185 * .. External Subroutines ..
186  EXTERNAL clarfg, cgemv, cgerc, ctrmv, xerbla
187 * ..
188 * .. Intrinsic Functions ..
189  INTRINSIC max, min
190 * ..
191 * .. Executable Statements ..
192 *
193 * Test the input arguments
194 *
195  info = 0
196  IF( m.LT.0 ) THEN
197  info = -1
198  ELSE IF( n.LT.0 ) THEN
199  info = -2
200  ELSE IF( l.LT.0 .OR. l.GT.min(m,n) ) THEN
201  info = -3
202  ELSE IF( lda.LT.max( 1, m ) ) THEN
203  info = -5
204  ELSE IF( ldb.LT.max( 1, m ) ) THEN
205  info = -7
206  ELSE IF( ldt.LT.max( 1, m ) ) THEN
207  info = -9
208  END IF
209  IF( info.NE.0 ) THEN
210  CALL xerbla( 'CTPLQT2', -info )
211  RETURN
212  END IF
213 *
214 * Quick return if possible
215 *
216  IF( n.EQ.0 .OR. m.EQ.0 ) RETURN
217 *
218  DO i = 1, m
219 *
220 * Generate elementary reflector H(I) to annihilate B(I,:)
221 *
222  p = n-l+min( l, i )
223  CALL clarfg( p+1, a( i, i ), b( i, 1 ), ldb, t( 1, i ) )
224  t(1,i)=conjg(t(1,i))
225  IF( i.LT.m ) THEN
226  DO j = 1, p
227  b( i, j ) = conjg(b(i,j))
228  END DO
229 *
230 * W(M-I:1) := C(I+1:M,I:N) * C(I,I:N) [use W = T(M,:)]
231 *
232  DO j = 1, m-i
233  t( m, j ) = (a( i+j, i ))
234  END DO
235  CALL cgemv( 'N', m-i, p, one, b( i+1, 1 ), ldb,
236  $ b( i, 1 ), ldb, one, t( m, 1 ), ldt )
237 *
238 * C(I+1:M,I:N) = C(I+1:M,I:N) + alpha * C(I,I:N)*W(M-1:1)^H
239 *
240  alpha = -(t( 1, i ))
241  DO j = 1, m-i
242  a( i+j, i ) = a( i+j, i ) + alpha*(t( m, j ))
243  END DO
244  CALL cgerc( m-i, p, (alpha), t( m, 1 ), ldt,
245  $ b( i, 1 ), ldb, b( i+1, 1 ), ldb )
246  DO j = 1, p
247  b( i, j ) = conjg(b(i,j))
248  END DO
249  END IF
250  END DO
251 *
252  DO i = 2, m
253 *
254 * T(I,1:I-1) := C(I:I-1,1:N)**H * (alpha * C(I,I:N))
255 *
256  alpha = -(t( 1, i ))
257  DO j = 1, i-1
258  t( i, j ) = zero
259  END DO
260  p = min( i-1, l )
261  np = min( n-l+1, n )
262  mp = min( p+1, m )
263  DO j = 1, n-l+p
264  b(i,j)=conjg(b(i,j))
265  END DO
266 *
267 * Triangular part of B2
268 *
269  DO j = 1, p
270  t( i, j ) = (alpha*b( i, n-l+j ))
271  END DO
272  CALL ctrmv( 'L', 'N', 'N', p, b( 1, np ), ldb,
273  $ t( i, 1 ), ldt )
274 *
275 * Rectangular part of B2
276 *
277  CALL cgemv( 'N', i-1-p, l, alpha, b( mp, np ), ldb,
278  $ b( i, np ), ldb, zero, t( i,mp ), ldt )
279 *
280 * B1
281 
282 *
283  CALL cgemv( 'N', i-1, n-l, alpha, b, ldb, b( i, 1 ), ldb,
284  $ one, t( i, 1 ), ldt )
285 *
286 
287 *
288 * T(1:I-1,I) := T(1:I-1,1:I-1) * T(I,1:I-1)
289 *
290  DO j = 1, i-1
291  t(i,j)=conjg(t(i,j))
292  END DO
293  CALL ctrmv( 'L', 'C', 'N', i-1, t, ldt, t( i, 1 ), ldt )
294  DO j = 1, i-1
295  t(i,j)=conjg(t(i,j))
296  END DO
297  DO j = 1, n-l+p
298  b(i,j)=conjg(b(i,j))
299  END DO
300 *
301 * T(I,I) = tau(I)
302 *
303  t( i, i ) = t( 1, i )
304  t( 1, i ) = zero
305  END DO
306  DO i=1,m
307  DO j= i+1,m
308  t(i,j)=(t(j,i))
309  t(j,i)=zero
310  END DO
311  END DO
312 
313 *
314 * End of CTPLQT2
315 *
clarfg
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108
cgemv
subroutine cgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGEMV
Definition: cgemv.f:160
cgerc
subroutine cgerc(M, N, ALPHA, X, INCX, Y, INCY, A, LDA)
CGERC
Definition: cgerc.f:132
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
ctrmv
subroutine ctrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
CTRMV
Definition: ctrmv.f:149

Here is the call graph for this function:

Here is the caller graph for this function: