subroutine ssyt01_aa	(	character	UPLO,
		integer	N,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( ldafac, * )	AFAC,
		integer	LDAFAC,
		integer, dimension( * )	IPIV,
		real, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( * )	RWORK,
		real	RESID
	)

SSYT01_AA

Purpose:

 SSYT01_AA reconstructs a symmetric indefinite matrix A from its
 block L*D*L' or U*D*U' factorization and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix and EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The original symmetric matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N)
[in]	AFAC	AFAC is REAL array, dimension (LDAFAC,N) The factored form of the matrix A. AFAC contains the block diagonal matrix D and the multipliers used to obtain the factor L or U from the block L*D*L' or U*D*U' factorization as computed by SSYTRF.
[in]	LDAFAC	LDAFAC is INTEGER The leading dimension of the array AFAC. LDAFAC >= max(1,N).
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from SSYTRF.
[out]	C	C is REAL array, dimension (LDC,N)
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESID	RESID is REAL If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 127 of file ssyt01_aa.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, ldc, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      REAL               a( lda, * ), afac( ldafac, * ), c( ldc, * ),
     $                   rwork( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      REAL               anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               slamch, slansy
      EXTERNAL           lsame, slamch, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, slavsy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = slansy( '1', uplo, n, a, lda, rwork )
*
*     Initialize C to the tridiagonal matrix T.
*
      CALL slaset( 'Full', n, n, zero, zero, c, ldc )
      CALL slacpy( 'F', 1, n, afac( 1, 1 ), ldafac+1, c( 1, 1 ), ldc+1 )
      IF( n.GT.1 ) THEN
         IF( lsame( uplo, 'U' ) ) THEN
            CALL slacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 1, 2 ),
     $                   ldc+1 )
            CALL slacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 2, 1 ),
     $                   ldc+1 )
         ELSE
            CALL slacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 1, 2 ),
     $                   ldc+1 )
            CALL slacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 2, 1 ),
     $                   ldc+1 )
         ENDIF
*
*        Call STRMM to form the product U' * D (or L * D ).
*
         IF( lsame( uplo, 'U' ) ) THEN
            CALL strmm( 'Left', uplo, 'Transpose', 'Unit', n-1, n,
     $                  one, afac( 1, 2 ), ldafac, c( 2, 1 ), ldc )
         ELSE
            CALL strmm( 'Left', uplo, 'No transpose', 'Unit', n-1, n,
     $                  one, afac( 2, 1 ), ldafac, c( 2, 1 ), ldc )
         END IF
*
*        Call STRMM again to multiply by U (or L ).
*
         IF( lsame( uplo, 'U' ) ) THEN
            CALL strmm( 'Right', uplo, 'No transpose', 'Unit', n, n-1,
     $                  one, afac( 1, 2 ), ldafac, c( 1, 2 ), ldc )
         ELSE
            CALL strmm( 'Right', uplo, 'Transpose', 'Unit', n, n-1,
     $                  one, afac( 2, 1 ), ldafac, c( 1, 2 ), ldc )
         END IF
      ENDIF
*
*     Apply symmetric pivots
*
      DO j = n, 1, -1
         i = ipiv( j )
         IF( i.NE.j )
     $      CALL sswap( n, c( j, 1 ), ldc, c( i, 1 ), ldc )
      END DO
      DO j = n, 1, -1
         i = ipiv( j )
         IF( i.NE.j )
     $      CALL sswap( n, c( 1, j ), 1, c( 1, i ), 1 )
      END DO
*
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO j = 1, n
            DO i = 1, j
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      ELSE
         DO j = 1, n
            DO i = j, n
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = slansy( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of SSYT01_AA
*

Here is the call graph for this function:

Here is the caller graph for this function: