perlfaq5 - Files and Formats
This section deals with I/O and the "f" issues: filehandles, flushing, formats, and footers.
(contributed by brian d foy)
You might like to read Mark Jason Dominus's "Suffering From Buffering" at http://perl.plover.com/FAQs/Buffering.html .
Perl normally buffers output so it doesn't make a system call for every bit of output. By saving up output, it makes fewer expensive system calls. For instance, in this little bit of code, you want to print a dot to the screen for every line you process to watch the progress of your program. Instead of seeing a dot for every line, Perl buffers the output and you have a long wait before you see a row of 50 dots all at once:
To get around this, you have to unbuffer the output filehandle, in this
case, STDOUT
. You can set the special variable $|
to a true value
(mnemonic: making your filehandles "piping hot"):
The $|
is one of the per-filehandle special variables, so each
filehandle has its own copy of its value. If you want to merge
standard output and standard error for instance, you have to unbuffer
each (although STDERR might be unbuffered by default):
- {
- my $previous_default = select(STDOUT); # save previous default
- $|++; # autoflush STDOUT
- select(STDERR);
- $|++; # autoflush STDERR, to be sure
- select($previous_default); # restore previous default
- }
- # now should alternate . and +
- while( 1 )
- {
- sleep 1;
- print STDOUT ".";
- print STDERR "+";
- print STDOUT "\n" unless ++$count % 25;
- }
Besides the $|
special variable, you can use binmode
to give
your filehandle a :unix
layer, which is unbuffered:
For more information on output layers, see the entries for binmode
and open
in perlfunc, and the PerlIO
module documentation.
If you are using IO::Handle
or one of its subclasses, you can
call the autoflush
method to change the settings of the
filehandle:
The IO::Handle
objects also have a flush
method. You can flush
the buffer any time you want without auto-buffering
- $io_fh->flush;
(contributed by brian d foy)
The basic idea of inserting, changing, or deleting a line from a text
file involves reading and printing the file to the point you want to
make the change, making the change, then reading and printing the rest
of the file. Perl doesn't provide random access to lines (especially
since the record input separator, $/
, is mutable), although modules
such as Tie::File
can fake it.
A Perl program to do these tasks takes the basic form of opening a file, printing its lines, then closing the file:
Within that basic form, add the parts that you need to insert, change, or delete lines.
To prepend lines to the beginning, print those lines before you enter the loop that prints the existing lines.
To change existing lines, insert the code to modify the lines inside
the while
loop. In this case, the code finds all lowercased
versions of "perl" and uppercases them. The happens for every line, so
be sure that you're supposed to do that on every line!
To change only a particular line, the input line number, $.
, is
useful. First read and print the lines up to the one you want to
change. Next, read the single line you want to change, change it, and
print it. After that, read the rest of the lines and print those:
To skip lines, use the looping controls. The next
in this example
skips comment lines, and the last
stops all processing once it
encounters either __END__
or __DATA__
.
Do the same sort of thing to delete a particular line by using next
to skip the lines you don't want to show up in the output. This
example skips every fifth line:
If, for some odd reason, you really want to see the whole file at once rather than processing line by line, you can slurp it in (as long as you can fit the whole thing in memory!):
Modules such as File::Slurp
and Tie::File
can help with that
too. If you can, however, avoid reading the entire file at once. Perl
won't give that memory back to the operating system until the process
finishes.
You can also use Perl one-liners to modify a file in-place. The
following changes all 'Fred' to 'Barney' in inFile.txt, overwriting
the file with the new contents. With the -p
switch, Perl wraps a
while
loop around the code you specify with -e
, and -i
turns
on in-place editing. The current line is in $_
. With -p
, Perl
automatically prints the value of $_
at the end of the loop. See
perlrun for more details.
- perl -pi -e 's/Fred/Barney/' inFile.txt
To make a backup of inFile.txt
, give -i
a file extension to add:
- perl -pi.bak -e 's/Fred/Barney/' inFile.txt
To change only the fifth line, you can add a test checking $.
, the
input line number, then only perform the operation when the test
passes:
- perl -pi -e 's/Fred/Barney/ if $. == 5' inFile.txt
To add lines before a certain line, you can add a line (or lines!)
before Perl prints $_
:
- perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt
You can even add a line to the beginning of a file, since the current line prints at the end of the loop:
- perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt
To insert a line after one already in the file, use the -n
switch.
It's just like -p
except that it doesn't print $_
at the end of
the loop, so you have to do that yourself. In this case, print $_
first, then print the line that you want to add.
- perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt
To delete lines, only print the ones that you want.
- perl -ni -e 'print unless /d/' inFile.txt
- ... or ...
- perl -pi -e 'next unless /d/' inFile.txt
One fairly efficient way is to count newlines in the file. The following program uses a feature of tr///, as documented in perlop. If your text file doesn't end with a newline, then it's not really a proper text file, so this may report one fewer line than you expect.
This assumes no funny games with newline translations.
-i
option from within a program?
-i
sets the value of Perl's $^I
variable, which in turn affects
the behavior of <>
; see perlrun for more details. By
modifying the appropriate variables directly, you can get the same
behavior within a larger program. For example:
This block modifies all the .c
files in the current directory,
leaving a backup of the original data from each file in a new
.c.orig
file.
(contributed by brian d foy)
Use the File::Copy
module. It comes with Perl and can do a
true copy across file systems, and it does its magic in
a portable fashion.
If you can't use File::Copy
, you'll have to do the work yourself:
open the original file, open the destination file, then print
to the destination file as you read the original. You also have to
remember to copy the permissions, owner, and group to the new file.
If you don't need to know the name of the file, you can use open()
with undef
in place of the file name. In Perl 5.8 or later, the
open()
function creates an anonymous temporary file:
Otherwise, you can use the File::Temp module.
- use File::Temp qw/ tempfile tempdir /;
- $dir = tempdir( CLEANUP => 1 );
- ($fh, $filename) = tempfile( DIR => $dir );
- # or if you don't need to know the filename
- $fh = tempfile( DIR => $dir );
The File::Temp has been a standard module since Perl 5.6.1. If you
don't have a modern enough Perl installed, use the new_tmpfile
class method from the IO::File module to get a filehandle opened for
reading and writing. Use it if you don't need to know the file's name:
If you're committed to creating a temporary file by hand, use the process ID and/or the current time-value. If you need to have many temporary files in one process, use a counter:
- BEGIN {
- use Fcntl;
- my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
- my $base_name = sprintf "%s/%d-%d-0000", $temp_dir, $$, time;
- sub temp_file {
- local *FH;
- my $count = 0;
- until( defined(fileno(FH)) || $count++ > 100 ) {
- $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
- # O_EXCL is required for security reasons.
- sysopen FH, $base_name, O_WRONLY|O_EXCL|O_CREAT;
- }
- if( defined fileno(FH) ) {
- return (*FH, $base_name);
- }
- else {
- return ();
- }
- }
- }
The most efficient way is using pack and unpack. This is faster than using substr when taking many, many strings. It is slower for just a few.
Here is a sample chunk of code to break up and put back together again some fixed-format input lines, in this case from the output of a normal, Berkeley-style ps:
- # sample input line:
- # 15158 p5 T 0:00 perl /home/tchrist/scripts/now-what
- my $PS_T = 'A6 A4 A7 A5 A*';
- open my $ps, '-|', 'ps';
- print scalar <$ps>;
- my @fields = qw( pid tt stat time command );
- while (<$ps>) {
- my %process;
- @process{@fields} = unpack($PS_T, $_);
- for my $field ( @fields ) {
- print "$field: <$process{$field}>\n";
- }
- print 'line=', pack($PS_T, @process{@fields} ), "\n";
- }
We've used a hash slice in order to easily handle the fields of each row. Storing the keys in an array means it's easy to operate on them as a group or loop over them with for. It also avoids polluting the program with global variables and using symbolic references.
As of perl5.6, open() autovivifies file and directory handles as references if you pass it an uninitialized scalar variable. You can then pass these references just like any other scalar, and use them in the place of named handles.
If you like, you can store these filehandles in an array or a hash.
If you access them directly, they aren't simple scalars and you
need to give print
a little help by placing the filehandle
reference in braces. Perl can only figure it out on its own when
the filehandle reference is a simple scalar.
Before perl5.6, you had to deal with various typeglob idioms which you may see in older code.
If you want to create many anonymous handles, you should check out the Symbol or IO::Handle modules.
An indirect filehandle is using something other than a symbol in a place that a filehandle is expected. Here are ways to get indirect filehandles:
- $fh = SOME_FH; # bareword is strict-subs hostile
- $fh = "SOME_FH"; # strict-refs hostile; same package only
- $fh = *SOME_FH; # typeglob
- $fh = \*SOME_FH; # ref to typeglob (bless-able)
- $fh = *SOME_FH{IO}; # blessed IO::Handle from *SOME_FH typeglob
Or, you can use the new
method from one of the IO::* modules to
create an anonymous filehandle, store that in a scalar variable,
and use it as though it were a normal filehandle.
- use IO::Handle; # 5.004 or higher
- $fh = IO::Handle->new();
Then use any of those as you would a normal filehandle. Anywhere that
Perl is expecting a filehandle, an indirect filehandle may be used
instead. An indirect filehandle is just a scalar variable that contains
a filehandle. Functions like print
, open
, seek
, or
the <FH>
diamond operator will accept either a named filehandle
or a scalar variable containing one:
If you're passing a filehandle to a function, you can write the function in two ways:
Or it can localize a typeglob and use the filehandle directly:
Both styles work with either objects or typeglobs of real filehandles. (They might also work with strings under some circumstances, but this is risky.)
- accept_fh(*STDOUT);
- accept_fh($handle);
In the examples above, we assigned the filehandle to a scalar variable
before using it. That is because only simple scalar variables, not
expressions or subscripts of hashes or arrays, can be used with
built-ins like print
, printf
, or the diamond operator. Using
something other than a simple scalar variable as a filehandle is
illegal and won't even compile:
- @fd = (*STDIN, *STDOUT, *STDERR);
- print $fd[1] "Type it: "; # WRONG
- $got = <$fd[0]> # WRONG
- print $fd[2] "What was that: $got"; # WRONG
With print
and printf
, you get around this by using a block and
an expression where you would place the filehandle:
That block is a proper block like any other, so you can put more complicated code there. This sends the message out to one of two places:
This approach of treating print
and printf
like object methods
calls doesn't work for the diamond operator. That's because it's a
real operator, not just a function with a comma-less argument. Assuming
you've been storing typeglobs in your structure as we did above, you
can use the built-in function named readline
to read a record just
as <>
does. Given the initialization shown above for @fd, this
would work, but only because readline() requires a typeglob. It doesn't
work with objects or strings, which might be a bug we haven't fixed yet.
- $got = readline($fd[0]);
Let it be noted that the flakiness of indirect filehandles is not related to whether they're strings, typeglobs, objects, or anything else. It's the syntax of the fundamental operators. Playing the object game doesn't help you at all here.
There's no builtin way to do this, but perlform has a couple of techniques to make it possible for the intrepid hacker.
See Accessing Formatting Internals in perlform for an swrite()
function.
(contributed by Peter J. Holzer, [email protected])
Since Perl 5.8.0 a file handle referring to a string can be created by calling open with a reference to that string instead of the filename. This file handle can then be used to read from or write to the string:
With older versions of Perl, the IO::String
module provides similar
functionality.
(contributed by brian d foy and Benjamin Goldberg)
You can use Number::Format to separate places in a number. It handles locale information for those of you who want to insert full stops instead (or anything else that they want to use, really).
This subroutine will add commas to your number:
This regex from Benjamin Goldberg will add commas to numbers:
- s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
It is easier to see with comments:
- s/(
- ^[-+]? # beginning of number.
- \d+? # first digits before first comma
- (?= # followed by, (but not included in the match) :
- (?>(?:\d{3})+) # some positive multiple of three digits.
- (?!\d) # an *exact* multiple, not x * 3 + 1 or whatever.
- )
- | # or:
- \G\d{3} # after the last group, get three digits
- (?=\d) # but they have to have more digits after them.
- )/$1,/xg;
Use the <> (glob()
) operator, documented in perlfunc.
Versions of Perl older than 5.6 require that you have a shell
installed that groks tildes. Later versions of Perl have this feature
built in. The File::KGlob
module (available from CPAN) gives more
portable glob functionality.
Within Perl, you may use this directly:
- $filename =~ s{
- ^ ~ # find a leading tilde
- ( # save this in $1
- [^/] # a non-slash character
- * # repeated 0 or more times (0 means me)
- )
- }{
- $1
- ? (getpwnam($1))[7]
- : ( $ENV{HOME} || $ENV{LOGDIR} )
- }ex;
Because you're using something like this, which truncates the file and then gives you read-write access:
- open(FH, "+> /path/name"); # WRONG (almost always)
Whoops. You should instead use this, which will fail if the file doesn't exist.
- open(FH, "+< /path/name"); # open for update
Using ">" always clobbers or creates. Using "<" never does either. The "+" doesn't change this.
Here are examples of many kinds of file opens. Those using sysopen() all assume
- use Fcntl;
To open file for reading:
To open file for writing, create new file if needed or else truncate old file:
To open file for writing, create new file, file must not exist:
To open file for appending, create if necessary:
To open file for appending, file must exist:
To open file for update, file must exist:
To open file for update, create file if necessary:
To open file for update, file must not exist:
To open a file without blocking, creating if necessary:
- sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT)
- or die "can't open /foo/somefile: $!":
Be warned that neither creation nor deletion of files is guaranteed to be an atomic operation over NFS. That is, two processes might both successfully create or unlink the same file! Therefore O_EXCL isn't as exclusive as you might wish.
See also the new perlopentut if you have it (new for 5.6).
The <>
operator performs a globbing operation (see above).
In Perl versions earlier than v5.6.0, the internal glob() operator forks
csh(1) to do the actual glob expansion, but
csh can't handle more than 127 items and so gives the error message
Argument list too long
. People who installed tcsh as csh won't
have this problem, but their users may be surprised by it.
To get around this, either upgrade to Perl v5.6.0 or later, do the glob yourself with readdir() and patterns, or use a module like File::KGlob, one that doesn't use the shell to do globbing.
Due to the current implementation on some operating systems, when you use the glob() function or its angle-bracket alias in a scalar context, you may cause a memory leak and/or unpredictable behavior. It's best therefore to use glob() only in list context.
(contributed by Brian McCauley)
The special two argument form of Perl's open() function ignores trailing blanks in filenames and infers the mode from certain leading characters (or a trailing "|"). In older versions of Perl this was the only version of open() and so it is prevalent in old code and books.
Unless you have a particular reason to use the two argument form you should use the three argument form of open() which does not treat any characters in the filename as special.
If your operating system supports a proper mv(1) utility or its functional equivalent, this works:
It may be more portable to use the File::Copy module instead. You just copy to the new file to the new name (checking return values), then delete the old one. This isn't really the same semantically as a rename(), which preserves meta-information like permissions, timestamps, inode info, etc.
Newer versions of File::Copy export a move() function.
Perl's builtin flock() function (see perlfunc for details) will call flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and later), and lockf(3) if neither of the two previous system calls exists. On some systems, it may even use a different form of native locking. Here are some gotchas with Perl's flock():
Produces a fatal error if none of the three system calls (or their close equivalent) exists.
lockf(3) does not provide shared locking, and requires that the filehandle be open for writing (or appending, or read/writing).
Some versions of flock() can't lock files over a network (e.g. on NFS file systems), so you'd need to force the use of fcntl(2) when you build Perl. But even this is dubious at best. See the flock entry of perlfunc and the INSTALL file in the source distribution for information on building Perl to do this.
Two potentially non-obvious but traditional flock semantics are that it waits indefinitely until the lock is granted, and that its locks are merely advisory. Such discretionary locks are more flexible, but offer fewer guarantees. This means that files locked with flock() may be modified by programs that do not also use flock(). Cars that stop for red lights get on well with each other, but not with cars that don't stop for red lights. See the perlport manpage, your port's specific documentation, or your system-specific local manpages for details. It's best to assume traditional behavior if you're writing portable programs. (If you're not, you should as always feel perfectly free to write for your own system's idiosyncrasies (sometimes called "features"). Slavish adherence to portability concerns shouldn't get in the way of your getting your job done.)
For more information on file locking, see also File Locking in perlopentut if you have it (new for 5.6).
A common bit of code NOT TO USE is this:
This is a classic race condition: you take two steps to do something which must be done in one. That's why computer hardware provides an atomic test-and-set instruction. In theory, this "ought" to work:
except that lamentably, file creation (and deletion) is not atomic over NFS, so this won't work (at least, not every time) over the net. Various schemes involving link() have been suggested, but these tend to involve busy-wait, which is also less than desirable.
Didn't anyone ever tell you web-page hit counters were useless? They don't count number of hits, they're a waste of time, and they serve only to stroke the writer's vanity. It's better to pick a random number; they're more realistic.
Anyway, this is what you can do if you can't help yourself.
- use Fcntl qw(:DEFAULT :flock);
- sysopen(FH, "numfile", O_RDWR|O_CREAT) or die "can't open numfile: $!";
- flock(FH, LOCK_EX) or die "can't flock numfile: $!";
- $num = <FH> || 0;
- seek(FH, 0, 0) or die "can't rewind numfile: $!";
- truncate(FH, 0) or die "can't truncate numfile: $!";
- (print FH $num+1, "\n") or die "can't write numfile: $!";
- close FH or die "can't close numfile: $!";
Here's a much better web-page hit counter:
If the count doesn't impress your friends, then the code might. :-)
If you are on a system that correctly implements flock
and you use
the example appending code from "perldoc -f flock" everything will be
OK even if the OS you are on doesn't implement append mode correctly
(if such a system exists.) So if you are happy to restrict yourself to
OSs that implement flock
(and that's not really much of a
restriction) then that is what you should do.
If you know you are only going to use a system that does correctly
implement appending (i.e. not Win32) then you can omit the seek
from the code in the previous answer.
If you know you are only writing code to run on an OS and filesystem
that does implement append mode correctly (a local filesystem on a
modern Unix for example), and you keep the file in block-buffered mode
and you write less than one buffer-full of output between each manual
flushing of the buffer then each bufferload is almost guaranteed to be
written to the end of the file in one chunk without getting
intermingled with anyone else's output. You can also use the
syswrite
function which is simply a wrapper around your system's
write(2)
system call.
There is still a small theoretical chance that a signal will interrupt
the system level write()
operation before completion. There is also
a possibility that some STDIO implementations may call multiple system
level write()
s even if the buffer was empty to start. There may be
some systems where this probability is reduced to zero, and this is
not a concern when using :perlio
instead of your system's STDIO.
If you're just trying to patch a binary, in many cases something as simple as this works:
- perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
However, if you have fixed sized records, then you might do something more like this:
- $RECSIZE = 220; # size of record, in bytes
- $recno = 37; # which record to update
- open(FH, "+<somewhere") || die "can't update somewhere: $!";
- seek(FH, $recno * $RECSIZE, 0);
- read(FH, $record, $RECSIZE) == $RECSIZE || die "can't read record $recno: $!";
- # munge the record
- seek(FH, -$RECSIZE, 1);
- print FH $record;
- close FH;
Locking and error checking are left as an exercise for the reader. Don't forget them or you'll be quite sorry.
If you want to retrieve the time at which the file was last read, written, or had its meta-data (owner, etc) changed, you use the -A, -M, or -C file test operations as documented in perlfunc. These retrieve the age of the file (measured against the start-time of your program) in days as a floating point number. Some platforms may not have all of these times. See perlport for details. To retrieve the "raw" time in seconds since the epoch, you would call the stat function, then use localtime(), gmtime(), or POSIX::strftime() to convert this into human-readable form.
Here's an example:
If you prefer something more legible, use the File::stat module (part of the standard distribution in version 5.004 and later):
The POSIX::strftime() approach has the benefit of being, in theory, independent of the current locale. See perllocale for details.
You use the utime() function documented in utime. By way of example, here's a little program that copies the read and write times from its first argument to all the rest of them.
Error checking is, as usual, left as an exercise for the reader.
The perldoc for utime also has an example that has the same effect as touch(1) on files that already exist.
Certain file systems have a limited ability to store the times on a file at the expected level of precision. For example, the FAT and HPFS filesystem are unable to create dates on files with a finer granularity than two seconds. This is a limitation of the filesystems, not of utime().
To connect one filehandle to several output filehandles, you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
If you only have to do this once, you can print individually to each filehandle.
- for $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
You can use the File::Slurp module to do it in one step.
- use File::Slurp;
- $all_of_it = read_file($filename); # entire file in scalar
- @all_lines = read_file($filename); # one line per element
The customary Perl approach for processing all the lines in a file is to do so one line at a time:
This is tremendously more efficient than reading the entire file into memory as an array of lines and then processing it one element at a time, which is often--if not almost always--the wrong approach. Whenever you see someone do this:
- @lines = <INPUT>;
you should think long and hard about why you need everything loaded at once. It's just not a scalable solution. You might also find it more fun to use the standard Tie::File module, or the DB_File module's $DB_RECNO bindings, which allow you to tie an array to a file so that accessing an element the array actually accesses the corresponding line in the file.
You can read the entire filehandle contents into a scalar.
That temporarily undefs your record separator, and will automatically close the file at block exit. If the file is already open, just use this:
For ordinary files you can also use the read function.
- read( INPUT, $var, -s INPUT );
The third argument tests the byte size of the data on the INPUT filehandle and reads that many bytes into the buffer $var.
Use the $/
variable (see perlvar for details). You can either
set it to ""
to eliminate empty paragraphs ("abc\n\n\n\ndef"
,
for instance, gets treated as two paragraphs and not three), or
"\n\n"
to accept empty paragraphs.
Note that a blank line must have no blanks in it. Thus
"fred\n \nstuff\n\n"
is one paragraph, but "fred\n\nstuff\n\n"
is two.
You can use the builtin getc()
function for most filehandles, but
it won't (easily) work on a terminal device. For STDIN, either use
the Term::ReadKey module from CPAN or use the sample code in
getc.
If your system supports the portable operating system programming interface (POSIX), you can use the following code, which you'll note turns off echo processing as well.
- #!/usr/bin/perl -w
- use strict;
- $| = 1;
- for (1..4) {
- my $got;
- print "gimme: ";
- $got = getone();
- print "--> $got\n";
- }
- exit;
- BEGIN {
- use POSIX qw(:termios_h);
- my ($term, $oterm, $echo, $noecho, $fd_stdin);
- $fd_stdin = fileno(STDIN);
- $term = POSIX::Termios->new();
- $term->getattr($fd_stdin);
- $oterm = $term->getlflag();
- $echo = ECHO | ECHOK | ICANON;
- $noecho = $oterm & ~$echo;
- sub cbreak {
- $term->setlflag($noecho);
- $term->setcc(VTIME, 1);
- $term->setattr($fd_stdin, TCSANOW);
- }
- sub cooked {
- $term->setlflag($oterm);
- $term->setcc(VTIME, 0);
- $term->setattr($fd_stdin, TCSANOW);
- }
- sub getone {
- my $key = '';
- cbreak();
- sysread(STDIN, $key, 1);
- cooked();
- return $key;
- }
- }
- END { cooked() }
The Term::ReadKey module from CPAN may be easier to use. Recent versions include also support for non-portable systems as well.
The very first thing you should do is look into getting the Term::ReadKey extension from CPAN. As we mentioned earlier, it now even has limited support for non-portable (read: not open systems, closed, proprietary, not POSIX, not Unix, etc) systems.
You should also check out the Frequently Asked Questions list in comp.unix.* for things like this: the answer is essentially the same. It's very system dependent. Here's one solution that works on BSD systems:
If you want to find out how many characters are waiting, there's
also the FIONREAD ioctl call to be looked at. The h2ph tool that
comes with Perl tries to convert C include files to Perl code, which
can be require
d. FIONREAD ends up defined as a function in the
sys/ioctl.ph file:
If h2ph wasn't installed or doesn't work for you, you can grep the include files by hand:
- % grep FIONREAD /usr/include/*/*
- /usr/include/asm/ioctls.h:#define FIONREAD 0x541B
Or write a small C program using the editor of champions:
- % cat > fionread.c
- #include <sys/ioctl.h>
- main() {
- printf("%#08x\n", FIONREAD);
- }
- ^D
- % cc -o fionread fionread.c
- % ./fionread
- 0x4004667f
And then hard code it, leaving porting as an exercise to your successor.
FIONREAD requires a filehandle connected to a stream, meaning that sockets, pipes, and tty devices work, but not files.
tail -f
in perl?
First try
- seek(GWFILE, 0, 1);
The statement seek(GWFILE, 0, 1)
doesn't change the current position,
but it does clear the end-of-file condition on the handle, so that the
next <GWFILE>
makes Perl try again to read something.
If that doesn't work (it relies on features of your stdio implementation), then you need something more like this:
If this still doesn't work, look into the clearerr
method
from IO::Handle
, which resets the error and end-of-file states
on the handle.
There's also a File::Tail
module from CPAN.
If you check open, you'll see that several of the ways to call open() should do the trick. For example:
Or even with a literal numeric descriptor:
- $fd = $ENV{MHCONTEXTFD};
- open(MHCONTEXT, "<&=$fd"); # like fdopen(3S)
Note that "<&STDIN" makes a copy, but "<&=STDIN" make an alias. That means if you close an aliased handle, all aliases become inaccessible. This is not true with a copied one.
Error checking, as always, has been left as an exercise for the reader.
If, for some reason, you have a file descriptor instead of a
filehandle (perhaps you used POSIX::open
), you can use the
close()
function from the POSIX
module:
- use POSIX ();
- POSIX::close( $fd );
This should rarely be necessary, as the Perl close()
function is to be
used for things that Perl opened itself, even if it was a dup of a
numeric descriptor as with MHCONTEXT
above. But if you really have
to, you may be able to do this:
Or, just use the fdopen(3S) feature of open()
:
Whoops! You just put a tab and a formfeed into that filename! Remember that within double quoted strings ("like\this"), the backslash is an escape character. The full list of these is in Quote and Quote-like Operators in perlop. Unsurprisingly, you don't have a file called "c:(tab)emp(formfeed)oo" or "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
Either single-quote your strings, or (preferably) use forward slashes.
Since all DOS and Windows versions since something like MS-DOS 2.0 or so
have treated /
and \
the same in a path, you might as well use the
one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
awk, Tcl, Java, or Python, just to mention a few. POSIX paths
are more portable, too.
Because even on non-Unix ports, Perl's glob function follows standard
Unix globbing semantics. You'll need glob("*")
to get all (non-hidden)
files. This makes glob() portable even to legacy systems. Your
port may include proprietary globbing functions as well. Check its
documentation for details.
-i
clobber protected files? Isn't this a bug in Perl?This is elaborately and painstakingly described in the file-dir-perms article in the "Far More Than You Ever Wanted To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
The executive summary: learn how your filesystem works. The permissions on a file say what can happen to the data in that file. The permissions on a directory say what can happen to the list of files in that directory. If you delete a file, you're removing its name from the directory (so the operation depends on the permissions of the directory, not of the file). If you try to write to the file, the permissions of the file govern whether you're allowed to.
Short of loading the file into a database or pre-indexing the lines in the file, there are a couple of things that you can do.
Here's a reservoir-sampling algorithm from the Camel Book:
This has a significant advantage in space over reading the whole file in. You can find a proof of this method in The Art of Computer Programming, Volume 2, Section 3.4.2, by Donald E. Knuth.
You can use the File::Random
module which provides a function
for that algorithm:
Another way is to use the Tie::File
module, which treats the entire
file as an array. Simply access a random array element.
(contributed by brian d foy)
If you are seeing spaces between the elements of your array when you print the array, you are probably interpolating the array in double quotes:
It's the double quotes, not the print
, doing this. Whenever you
interpolate an array in a double quote context, Perl joins the
elements with spaces (or whatever is in $"
, which is a space by
default):
- animals are: camel llama alpaca vicuna
This is different than printing the array without the interpolation:
Now the output doesn't have the spaces between the elements because
the elements of @animals
simply become part of the list to
print
:
- animals are: camelllamaalpacavicuna
You might notice this when each of the elements of @array
end with
a newline. You expect to print one element per line, but notice that
every line after the first is indented:
- this is a line
- this is another line
- this is the third line
That extra space comes from the interpolation of the array. If you don't want to put anything between your array elements, don't use the array in double quotes. You can send it to print without them:
- print @lines;
(contributed by brian d foy)
The File::Find
module, which comes with Perl, does all of the hard
work to traverse a directory structure. It comes with Perl. You simply
call the find
subroutine with a callback subroutine and the
directories you want to traverse:
The File::Find::Closures
, which you can download from CPAN, provides
many ready-to-use subroutines that you can use with File::Find
.
The File::Finder
, which you can download from CPAN, can help you
create the callback subroutine using something closer to the syntax of
the find
command-line utility:
The File::Find::Rule
module, which you can download from CPAN, has
a similar interface, but does the traversal for you too:
(contributed by brian d foy)
If you have an empty directory, you can use Perl's built-in rmdir
. If
the directory is not empty (so, no files or subdirectories), you either
have to empty it yourself (a lot of work) or use a module to help you.
The File::Path
module, which comes with Perl, has a rmtree
which
can take care of all of the hard work for you:
- use File::Path qw(rmtree);
- rmtree( \@directories, 0, 0 );
The first argument to rmtree
is either a string representing a directory path
or an array reference. The second argument controls progress messages, and the
third argument controls the handling of files you don't have permissions to
delete. See the File::Path
module for the details.
(contributed by Shlomi Fish)
To do the equivalent of cp -R
(i.e. copy an entire directory tree
recursively) in portable Perl, you'll either need to write something yourself
or find a good CPAN module such as File::Copy::Recursive.
=head1 REVISION
Revision: $Revision$
Date: $Date$
See perlfaq for source control details and availability.
Copyright (c) 1997-2009 Tom Christiansen, Nathan Torkington, and other authors as noted. All rights reserved.
This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.
Irrespective of its distribution, all code examples here are in the public domain. You are permitted and encouraged to use this code and any derivatives thereof in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit to the FAQ would be courteous but is not required.