$(
#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#
                           Virtual Deduction Proofs          
#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#*#
$)

$( <MM> <PROOF_ASST> THEOREM=notnot2ALT2UP LOC_AFTER=?
*   $( Converse of double negation. Theorem *2.14 of [WhiteheadRussell] p. 102.
*      Alternate proof of ~ notnot2 . The following User's Proof is a Natural
*      Deduction Sequent Calculus transcription of a Fitch-style Natural
*      Deduction proof. completeusersproof.c completes this proof. (Contributed
*      by Alan Sare, 11-Sep-2016.)(Proof modification is discouraged.) (New
*      usage is discouraged.) $)
*      notnot2ALT2UP $p |- ( -. -. ph -> ph ) $=
1::         |- (. -. -. ph ->. -. -. ph ).
2:1:        |- (. -. -. ph ->. ( -. ph -> -. -. -. ph ) ).
3:2:        |- (. -. -. ph ->. ( -. -. ph -> ph ) ).
4:1,3:      |- (. -. -. ph ->. ph ).
qed:4:      |- ( -. -. ph -> ph )
$)

$( <MM> <PROOF_ASST> THEOREM=suctrALT4UP LOC_AFTER=?
*   $d z A $.  $d y A $.  $d z y $.
*   $( The sucessor of a transitive class is transitive. completeusersproof.c
*      completes this proof. The labels picked by completeusersproof which
*      are in a Mathbox and have been replaced are ~ bnj533 and ~ bnj531 .
*      (Contributed by Alan Sare, 11-Sep-2016.)(Proof modification is
*      discouraged.) (New usage is discouraged.) $)
*   suctrALT4UP $p |- ( Tr A -> Tr suc A ) $=
1::         |- (.    Tr A ->. Tr A ).
2::         |- (.            ( z e. y /\ y e. suc A )    ->. ( z e. y /\ y e. suc A ) ).
3:2:        |- (.            ( z e. y /\ y e. suc A )    ->. z e. y ).
4::         |- (.                                        y e. A    ->. y e. A ).
5:1,3,4:    |- (. (. Tr A ,. ( z e. y /\ y e. suc A ) ,. y e. A ). ->. z e. A ).
6::         |- A C_ suc A
7:5,6:      |- (. (. Tr A ,. ( z e. y /\ y e. suc A ) ,. y e. A ). ->. z e. suc A ).
8:7:        |- (. (. Tr A ,. ( z e. y /\ y e. suc A ) ). ->. ( y e. A -> z e. suc A ) ).
9::         |- (.                                        y = A     ->. y = A ).
10:3,9:     |- (. (.         ( z e. y /\ y e. suc A ) ,. y = A ).  ->. z e. A ).
11:10,6:    |- (. (.         ( z e. y /\ y e. suc A ) ,. y = A ).  ->. z e. suc A ).
12:11:      |- (.            ( z e. y /\ y e. suc A )    ->. ( y = A -> z e. suc A ) ).
13:2:       |- (.            ( z e. y /\ y e. suc A )    ->. y e. suc A ).
14:13:      |- (.            ( z e. y /\ y e. suc A )    ->. ( y e. A \/ y = A ) ).
15:8,12,14: |- (. (. Tr A ,. ( z e. y /\ y e. suc A ) ). ->. z e. suc A ).
16:15:      |- (.    Tr A ->. ( ( z e. y /\ y e. suc A ) -> z e. suc A ) ).
17:16:      |- (.    Tr A ->. A. z A. y ( ( z e. y /\ y e. suc A ) -> z e. suc A ) ).
18:17:      |- (.    Tr A ->. Tr suc A ).
qed:18:     |- ( Tr A -> Tr suc A )
$)

$( <MM> <PROOF_ASST> THEOREM=sspwimpALT2UP LOC_AFTER=?
*   $d x A $.  $d x B $.
*   $( If a class is a subclass of another class, then its power class is a
*      subclass of that other class's power class.  Left-to-right implication
*      of Exercise 18 of [TakeutiZaring] p. 18. completeusersproof.c completes
*      this proof. (Contributed by Alan Sare, 11-Sep-2016.) $)
*   sspwimpALT2UP $p |- ( A C_ B -> ~P A C_ ~P B ) $=
1::    |- (.    A C_ B ->. A C_ B ).
2::    |- (.              x e. ~P A    ->. x e. ~P A ).
3:2:   |- (.              x e. ~P A    ->. x C_ A ).
4:3,1: |- (. (. A C_ B ,. x e. ~P A ). ->. x C_ B ).
5::    |- x e. _V
6:4,5: |- (. (. A C_ B ,. x e. ~P A ). ->. x e. ~P B ).
7:6:   |- (.    A C_ B ->. ( x e. ~P A -> x e. ~P B ) ).
8:7:   |- (.    A C_ B ->. A. x ( x e. ~P A -> x e. ~P B ) ).
9:8:   |- (.    A C_ B ->. ~P A C_ ~P B ).
qed:9: |- ( A C_ B -> ~P A C_ ~P B )
$)

$( <MM> <PROOF_ASST> THEOREM=e2ebindALTUP LOC_AFTER=?
*   $( Absorption of an existential quantifier of a double existential
*      quantifier of non-distinct variables. completeusersproof.c completes
*      this proof. ~ 19.9v is a label picked by completeusersproof which
*      violates the distinct variable requirements (there are no distinct
*      variable requirements). Less preferred labels picked by
*      completeusersproof are ~ ax12o10lem5 and ~ ax12o10lem13 . These three
*      labels were excluded from the proof. (Contributed by Alan Sare,
*      11-Sep-2016.)(Proof modification is discouraged.)(New usage is
*      discouraged.) $)
*   e2ebindALTUP $p |- ( A. x x = y -> ( E. x E. y ph <-> E. y ph ) ) $=
1::          |- ( ph <-> ph )
2:1:         |- ( A. y y = x -> ( ph <-> ph ) )
3:2:         |- ( A. y y = x -> ( E. y ph <-> E. x ph ) )
4::          |- (. A. y y = x ->. A. y y = x ).
5:3,4:       |- (. A. y y = x ->. ( E. y ph <-> E. x ph ) ).
6::          |- ( A. y y = x -> A. y A. y y = x )
7:5,6:       |- (. A. y y = x ->. A. y ( E. y ph <-> E. x ph ) ).
8:7:         |- (. A. y y = x ->. ( E. y E. y ph <-> E. y E. x ph ) ).
9::          |- ( E. y E. x ph <-> E. x E. y ph )
10:8,9:      |- (. A. y y = x ->. ( E. y E. y ph <-> E. x E. y ph ) ).
11::         |- ( E. y ph -> A. y E. y ph )
12:11:       |- ( E. y E. y ph <-> E. y ph )
13:10,12:    |- (. A. y y = x ->. ( E. x E. y ph <-> E. y ph ) ).
14:13:       |- ( A. y y = x -> ( E. x E. y ph <-> E. y ph ) )
15::         |- ( A. x x = y -> A. y y = x )
qed:14,15:   |- ( A. x x = y -> ( E. x E. y ph <-> E. y ph ) )
$)

$( <MM> <PROOF_ASST> THEOREM=a9e2ndALTUP LOC_AFTER=?
*   $d u x $.  $d u y $.  $d v x z $.  $d y z $.
*   $( If at least two sets exist ( ~ dtru ) , then the same is true expressed
*      in an alternate form similar to the form of ~ a9e . completeusersproof.c
*      completes this proof. The labels picked by completeusersproof which
*      are less preferred and have been replaced are ~ ax12o10lem2 and
*      ~ dvelimfALT .(Contributed by Alan Sare, 11-Sep-2016.)(Proof modification
*      is discouraged.) (New usage is discouraged.) $)
*   a9e2ndALTUP $p |- ( -. A. x x = y -> E. x E. y ( x = u /\ y = v ) ) $= 
1::          |- E. y y = v
2::          |- u e. _V
3:1,2:       |- ( u e. _V /\ E. y y = v )
4:3:         |- E. y ( u e. _V /\ y = v )
5::          |- ( u e. _V <-> E. x x = u )
6:5:         |- ( ( u e. _V /\ y = v ) <-> ( E. x x = u /\ y = v ) )
7:6:         |- ( E. y ( u e. _V /\ y = v ) <-> E. y ( E. x x = u /\ y = v ) )
8:4,7:       |- E. y ( E. x x = u /\ y = v )
9::          |- ( z = v -> A. x z = v )
10::         |- ( y = v -> A. z y = v )
11::         |- (. z = y ->. z = y ).
12:11:       |- (. z = y ->. ( z = v <-> y = v ) ).
120:11:      |- ( z = y -> ( z = v <-> y = v ) )
13:9,10,120: |- ( -. A. x x = y -> ( y = v -> A. x y = v ) )
14::         |- (. -. A. x x = y ->. -. A. x x = y ).
15:14,13:    |- (. -. A. x x = y ->. ( y = v -> A. x y = v ) ).
16:15:       |- ( -. A. x x = y -> ( y = v -> A. x y = v ) )
17:16:       |- ( A. x -. A. x x = y -> A. x ( y = v -> A. x y = v ) )
18::         |- ( -. A. x x = y -> A. x -. A. x x = y )
19:17,18:    |- ( -. A. x x = y -> A. x ( y = v -> A. x y = v ) )
20:14,19:    |- (. -. A. x x = y ->. A. x ( y = v -> A. x y = v ) ).
21:20:       |- (. -. A. x x = y ->. ( ( E. x x = u /\ y = v ) -> E. x ( x = u /\ y = v ) ) ).
22:21:       |- ( -. A. x x = y -> ( ( E. x x = u /\ y = v ) -> E. x ( x = u /\ y = v ) ) )
23:22:       |- ( A. y -. A. x x = y -> A. y ( ( E. x x = u /\ y = v ) -> E. x ( x = u /\ y = v ) ) )
24::         |- ( -. A. x x = y -> A. y -. A. x x = y )
25:23,24:    |- ( -. A. x x = y -> A. y ( ( E. x x = u /\ y = v ) -> E. x ( x = u /\ y = v ) ) )
26:14,25:    |- (. -. A. x x = y ->. A. y ( ( E. x x = u /\ y = v ) -> E. x ( x = u /\ y = v ) ) ).
27:26:       |- (. -. A. x x = y ->. ( E. y ( E. x x = u /\ y = v ) -> E. y E. x ( x = u /\ y = v ) ) ).
28:8,27:     |- (. -. A. x x = y ->.  E. y E. x ( x = u /\ y = v ) ).
29:28:       |- (. -. A. x x = y ->.  E. x E. y ( x = u /\ y = v ) ).
qed:29:      |- ( -. A. x x = y -> E. x E. y ( x = u /\ y = v ) ) 
$)

$( <MM> <PROOF_ASST> THEOREM=a9e2ndeqALTUP LOC_AFTER=?
*   $d u x $.  $d u y $.  $d v x $.  $d v y $.
*   $( "At least two sets exist" expressed in the form of ~ dtru is logically
*      equivalent to the same expressed in a form similar to ~ a9e if ~ dtru is
*      false implies ` u = v ` . Proof derived by completeusersproof.c from
*      User's Proof in VirtualDeductionProofs.txt. The labels picked by
*      completeusersproof which violate the distinct variable requirements
*      are: ~ dtru , ~ dtruALT , ~ dtruALT2 . Mathbox labels or otherwise
*      less preferred labels picked by the completeusersproof are: ~ bnj1119 ,
*      ~ ax12o10lem3 , ~ ax12o10lem5 , ~ ax12o10lem13 .(Contributed by Alan
*      Sare, 11-Sep-2016.)(Proof modification is discouraged.)
*      (New usage is discouraged.) $)
*   a9e2ndeqALTUP $p |- ( ( -. A. x x = y \/ u = v ) <->
*                       E. x E. y ( x = u /\ y = v ) ) $=
1::          |- (. u =/= v ->. u =/= v ).
2::          |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. ( x = u /\ y = v ) ).
3:2:         |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. x = u ).
4:1,3:       |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. x =/= v ).
5:2:         |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. y = v ).
6:4,5:       |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. x =/= y ).
7::          |- ( A. x x = y -> x = y )
8:7:         |- ( -. x = y -> -. A. x x = y )
9::          |- ( -. x = y <-> x =/= y )
10:8,9:      |- ( x =/= y -> -. A. x x = y )
11:6,10:     |- (. (. u =/= v ,. ( x = u /\ y = v ) ). ->. -. A. x x = y ).
12:11:       |- (. u =/= v ->. ( ( x = u /\ y = v ) -> -. A. x x = y ) ).
13:12:       |- (. u =/= v ->. A. x ( ( x = u /\ y = v ) -> -. A. x x = y ) ).
14:13:       |- (. u =/= v ->. ( E. x ( x = u /\ y = v ) -> E. x -. A. x x = y ) ).
15::         |- ( -. A. x x = y -> A. x -. A. x x = y )
19:15:       |- ( E. x -. A. x x = y <-> -. A. x x = y )
20:14,19:    |- (. u =/= v ->. ( E. x ( x = u /\ y = v ) -> -. A. x x = y ) ).
21:20:       |- (. u =/= v ->. A. y ( E. x ( x = u /\ y = v ) -> -. A. x x = y ) ).
22:21:       |- (. u =/= v ->. ( E. y E. x ( x = u /\ y = v ) -> E. y -. A. x x = y ) ).
23::         |- ( E. x E. y ( x = u /\ y = v ) <-> E. y E. x ( x = u /\ y = v ) )
24:22,23:    |- (. u =/= v ->. ( E. x E. y ( x = u /\ y = v ) -> E. y -. A. x x = y ) ).
25::         |- ( -. A. x x = y -> A. y -. A. x x = y )
26:25:       |- ( E. y -. A. x x = y -> E. y A. y -. A. x x = y )
260::        |- ( A. y -. A. x x = y -> A. y A. y -. A. x x = y )
27:260:      |- ( E. y A. y -. A. x x = y <-> A. y -. A. x x = y )
270:26,27:   |- ( E. y -. A. x x = y -> A. y -. A. x x = y )
28::         |- ( A. y -. A. x x = y -> -. A. x x = y )
29:270,28:   |- ( E. y -. A. x x = y -> -. A. x x = y )
30:24,29:    |- (. u =/= v ->. ( E. x E. y ( x = u /\ y = v ) -> -. A. x x = y ) ).
31:30:       |- (. u =/= v ->. ( E. x E. y ( x = u /\ y = v ) -> ( -. A. x x = y \/ u = v ) ) ).
32:31:       |- ( u =/= v -> ( E. x E. y ( x = u /\ y = v ) -> ( -. A. x x = y \/ u = v ) ) )
33::         |- (. u = v ->. u = v ).
34:33:       |- (. u = v ->. ( E. x E. y ( x = u /\ y = v ) -> u = v ) ).
35:34:       |- (. u = v ->. ( E. x E. y ( x = u /\ y = v ) -> ( -. A. x x = y \/ u = v ) ) ).
36:35:       |- ( u = v -> ( E. x E. y ( x = u /\ y = v ) -> ( -. A. x x = y \/ u = v ) ) )
37::         |- ( u = v \/ u =/= v )
38:32,36,37: |- ( E. x E. y ( x = u /\ y = v ) -> ( -. A. x x = y \/ u = v ) )
39::         |- ( A. x x = y -> ( u = v -> E. x E. y ( x = u /\ y = v ) ) )
40::         |- ( -. A. x x = y -> E. x E. y ( x = u /\ y = v ) )
41:40:       |- ( -. A. x x = y -> ( u = v -> E. x E. y ( x = u /\ y = v ) ) )
42::         |- ( A. x x = y \/ -. A. x x = y )
43:39,41,42: |- ( u = v -> E. x E. y ( x = u /\ y = v ) )
44:40,43:    |- ( ( -. A. x x = y \/ u = v ) -> E. x E. y ( x = u /\ y = v ) )
qed:38,44:   |- ( ( -. A. x x = y \/ u = v ) <-> E. x E. y ( x = u /\ y = v ) )
$)

$( <MM> <PROOF_ASST> THEOREM=2sb5ndALTUP LOC_AFTER=?
*   $d u x $.  $d u y $.  $d v x $.  $d v y $.
*   $( Equivalence for double substitution ~ 2sb5 without distinct ` x ` ,
*      ` y ` requirement. completeusersproof.c completes this proof. ~ sbal ,
*      ~ a17d and ~ ax-17 are labels picked by completeusersproof which violate
*      the distinct variable requirements. Less preferred labels picked by
*      completeusersproof are ~ ax10o and ~ ax-10 . All of these labels were
*      excluded from the proof. (Contributed by Alan Sare, 11-Sep-2016.)(Proof
*      modification is discouraged.)(New usage is discouraged.) $)
*   2sb5ndALTUP $p |- ( ( -. A. x x = y \/ u = v ) -> ( [ u / x ] [ v / y ] ph
*                     <-> E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) ) $=
1::          |- ( ( ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> ( ( x = u /\ y = v ) /\ ph ) )
2:1:         |- ( E. y ( ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> E. y ( ( x = u /\ y = v ) /\ ph ) )
3::          |- ( [ v / y ] ph -> A. y [ v / y ] ph )
4:3:         |- [ u / x ] ( [ v / y ] ph -> A. y [ v / y ] ph )
5:4:         |- ( [ u / x ] [ v / y ] ph -> [ u / x ] A. y [ v / y ] ph )
6::          |- (. -. A. x x = y ->. -. A. x x = y ).
7::          |- ( A. y y = x -> A. x x = y )
8:7:         |- ( -. A. x x = y -> -. A. y y = x )
9:6,8:       |- (. -. A. x x = y ->. -. A. y y = x ).
10:9:        |- (. -. A. x x = y ->. ( [ u / x ] A. y [ v / y ] ph <-> A. y [ u / x ] [ v / y ] ph ) ).
11:5,10:     |- (. -. A. x x = y ->. ( [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph ) ).
12:11:       |- ( -. A. x x = y -> ( [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph ) )
13::         |- ( [ u / x ] [ v / y ] ph -> A. x [ u / x ] [ v / y ] ph )
14::         |- (. A. x x = y ->. A. x x = y ).
15:14:       |- (. A. x x = y ->. ( A. x [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph ) ).
16:13,15:    |- (. A. x x = y ->. ( [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph ) ).
17:16:       |- ( A. x x = y -> ( [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph ) )
19:12,17:    |- ( [ u / x ] [ v / y ] ph -> A. y [ u / x ] [ v / y ] ph )
20:19:       |- ( E. y ( ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph )  <-> ( E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) )
21:2,20:     |- ( E. y ( ( x = u /\ y = v ) /\ ph ) <-> ( E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) )
22:21:       |- ( E. x E. y ( ( x = u /\ y = v ) /\ ph ) <-> E. x ( E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) )
23:13:       |- ( E. x ( E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) )
24:22,23:    |- ( ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> E. x E. y ( ( x = u /\ y = v ) /\ ph ) )
240:24:      |- ( ( E. x E. y ( x = u /\ y = v ) /\ ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) ) <-> ( E. x E. y ( x = u /\ y = v ) /\ E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) )
241::        |- ( ( E. x E. y ( x = u /\ y = v ) /\ ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) ) <-> ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) )
242:241,240: |- ( ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> ( E. x E. y ( x = u /\ y = v ) /\ E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) )
243::        |- ( ( E. x E. y ( x = u /\ y = v ) -> ( [ u / x ] [ v / y ] ph <-> E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) ) <->  ( ( E. x E. y ( x = u /\ y = v ) /\ [ u / x ] [ v / y ] ph ) <-> ( E. x E. y ( x = u /\ y = v ) /\ E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) ) )
25:242,243:  |- ( E. x E. y ( x = u /\ y = v ) -> ( [ u / x ] [ v / y ] ph <-> E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) )
26::         |- ( ( -. A. x x = y \/ u = v ) <-> E. x E. y ( x = u /\ y = v ) )
qed:25,26:   |- ( ( -. A. x x = y \/ u = v ) -> ( [ u / x ] [ v / y ] ph <-> E. x E. y ( ( x = u /\ y = v ) /\ ph ) ) )
$)

$( <MM> <PROOF_ASST> THEOREM=chordthmALTVD LOC_AFTER=?
* ${
*   $d A v w x y $.  $d B v w x y $.  $d C v w x y $.  $d D v w x y $.
*   $d F v w $.  $d ph v w $.  $d P v w x y $.
*   chordthmALTVD.angdef $e |- F = ( x e. ( CC \ { 0 } ) , y e. ( CC \ { 0 } ) |-> ( Im ` ( log ` ( y / x ) ) ) ) $.
*   chordthmALTVD.A      $e |- (. ph ->. A e. CC ). $.
*   chordthmALTVD.B      $e |- (. ph ->. B e. CC ). $.
*   chordthmALTVD.C      $e |- (. ph ->. C e. CC ). $.
*   chordthmALTVD.D      $e |- (. ph ->. D e. CC ). $.
*   chordthmALTVD.P      $e |- (. ph ->. P e. CC ). $.
*   chordthmALTVD.AneP   $e |- (. ph ->. A =/= P ). $.
*   chordthmALTVD.BneP   $e |- (. ph ->. B =/= P ). $.
*   chordthmALTVD.CneP   $e |- (. ph ->. C =/= P ). $.
*   chordthmALTVD.DneP   $e |- (. ph ->. D =/= P ). $.
*   chordthmALTVD.APB    $e |- (. ph ->. ( ( A - P ) F ( B - P ) ) = pi ). $.
*   chordthmALTVD.CPD    $e |- (. ph ->. ( ( C - P ) F ( D - P ) ) = pi ). $.
*   chordthmALTVD.Q      $e |- (. ph ->. Q e. CC ). $.
*   chordthmALTVD.ABcirc $e |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( B - Q ) ) ). $.
*   chordthmALTVD.ACcirc $e |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( C - Q ) ) ). $.
*   chordthmALTVD.ADcirc $e |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( D - Q ) ) ). $.
*   $( The intersecting chords theorem. If points A, B, C, and D lie on a
*      circle (with center Q, say), and the point P is on the interior of the
*      segments AB and CD, then the two products of lengths PA ` x. ` PB and
*      PC ` x. ` PD are equal. The Euclidean plane is identified with the
*      complex plane, and the fact that P is on AB and on CD is expressed by
*      the hypothesis that the angles APB and CPD are equal to ` pi ` . The
*      result is proven by using ~ chordthmlem5 twice to show that PA
*      ` x. ` PB and PC ` x. ` PD both equal BQ<HTML><sup>2</sup></HTML> ` - `
*      PQ<HTML><sup>2</sup></HTML>. This is similar to the proof of the
*      theorem given in Euclid's Elements_, where it is Proposition III.35.
*      Proven by David Moews
*      on 28-Feb-2017 as ~ chordthm . ~ chordthmALTVD is a Virtual Deduction
*      User's Proof transcription of ~ chordthm . Using the command line
*      argument argv1 having the value "runCompleteusersproofsmv" and excluding
*      ~ bnj1196 , completeusersproof will automatically complete
*      ~ chordthmALTVD , transforming it into the set.mm Metamath proof
*      ~ chordthmALT . The text file VirtualDeductionProofs.txt included in the
*      completeusersproof download contains the ~ chordthmALTVD proof in .txt
*      format. That proof may copied into its own .txt file. That file may be
*      input into completeusersproof and an RPN proof of ~ chordthmALT will be
*      generated. The qed step and the step numbers of ~ chordthmALTVD which
*      contain "h" or only numerals correspond to step numbers of ~ chordthm .
*      The step numbers containing "b" or "c" are of added steps. (Contributed
*      by Alan Sare, 18-Sep-2017.) $)
*   chordthmALTVD        $p |- (. ph ->. ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ). $= ? $.
* $}
h1::                  |- (. ph ->. ( ( C - P ) F ( D - P ) ) = pi ).
h2::                  |- F = ( x e. ( CC \ { 0 } ) , y e. ( CC \ { 0 } ) |-> ( Im ` ( log ` ( y / x ) ) ) )
h3::                  |- (. ph ->. C e. CC ).
h4::                  |- (. ph ->. P e. CC ).
h5::                  |- (. ph ->. D e. CC ).
h6::                  |- (. ph ->. C =/= P ).
h7::                  |- (. ph ->. D =/= P ).
8:7:                  |- (. ph ->. P =/= D ).
9:2,3,4,5,6,8:        |- (. ph ->. ( ( ( C - P ) F ( D - P ) ) = pi <-> E. v e. ( 0 (,) 1 ) P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ).
10:1,9:               |- (. ph ->. E. v e. ( 0 (,) 1 ) P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ).
10b:10:               |- (. ph ->. E. v ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ).
h11::                 |- (. ph ->. ( ( A - P ) F ( B - P ) ) = pi ).
h12::                 |- (. ph ->. A e. CC ).
h13::                 |- (. ph ->. B e. CC ).
h14::                 |- (. ph ->. A =/= P ).
h15::                 |- (. ph ->. B =/= P ).
16:15:                |- (. ph ->. P =/= B ).
17:2,12,4,13,14,16:   |- (. ph ->. ( ( ( A - P ) F ( B - P ) ) = pi <-> E. w e. ( 0 (,) 1 ) P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ) ).
18:11,17:             |- (. ph ->. E. w e. ( 0 (,) 1 ) P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ).
18b:18:               |- (. ph ->. E. w ( w e. ( 0 (,) 1 ) /\ P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ) ).
h20::                 |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( B - Q ) ) ).
h22::                 |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( D - Q ) ) ).
24:20,22:             |- (. ph ->. ( abs ` ( B - Q ) ) = ( abs ` ( D - Q ) ) ).
25:24:                |- (. ph ->. ( ( abs ` ( B - Q ) ) ^ 2 ) = ( ( abs ` ( D - Q ) ) ^ 2 ) ).
26:25:                |- (. ph ->. ( ( ( abs ` ( B - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) = ( ( ( abs ` ( D - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) ).
h29::                 |- (. ph ->. Q e. CC ).
31::                  |- ( 0 (,) 1 ) C_ ( 0 [,] 1 )
32::                  |- (. w e. ( 0 (,) 1 ) ->. w e. ( 0 (,) 1 ) ).
33:32,31:             |- (. w e. ( 0 (,) 1 ) ->. w e. ( 0 [,] 1 ) ).
34::                  |- (. P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ->. P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ).
35:12,13,29,33,34,20: |- (. (. ph ,.   w e. ( 0 (,) 1 ) ,. P = ( ( w x. A ) + ( ( 1 - w ) x. B ) )   ). ->. ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( ( abs ` ( B - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) ).
35b:35:               |- (. (. ph ,. ( w e. ( 0 (,) 1 ) /\ P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ) ). ->. ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( ( abs ` ( B - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) ).
38::                  |- (. v e. ( 0 (,) 1 ) ->. v e. ( 0 (,) 1 ) ).
39:38,31:             |- (. v e. ( 0 (,) 1 ) ->. v e. ( 0 [,] 1 ) ).
40::                  |- (. P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ->. P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ).
h41::                 |- (. ph ->. ( abs ` ( A - Q ) ) = ( abs ` ( C - Q ) ) ).
43:22,41:             |- (. ph ->. ( abs ` ( C - Q ) ) = ( abs ` ( D - Q ) ) ).
44:3,5,29,39,40,43:   |- (. (. ph ,.      v e. ( 0 (,) 1 ) ,. P = ( ( v x. C ) + ( ( 1 - v ) x. D ) )   ). ->. ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) = ( ( ( abs ` ( D - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) ).
44b:44:               |- (. (. ph ,.    ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ). ->. ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) = ( ( ( abs ` ( D - Q ) ) ^ 2 ) - ( ( abs ` ( P - Q ) ) ^ 2 ) ) ).
45:26,35b,44b:        |- (. (. ph ,.    ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ,.      (   w e. ( 0 (,) 1 ) /\ P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ) ). ->.  ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ).
45b:45:               |- (. (. ph ,.    ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ). ->. ( (  w e. ( 0 (,) 1 ) /\ P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) )    ->   ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ) ).
45c:45b:              |- (. (. ph ,.    ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ). ->. ( E. w (  w e. ( 0 (,) 1 ) /\ P = ( ( w x. A ) + ( ( 1 - w ) x. B ) ) ) -> ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ) ).
46:18b,45c:           |- (. (. ph ,.    ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) ) ). ->. ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ).
46b:46:               |- (.    ph ->.        ( ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) )      ->  ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ) ).
46c:46b:              |- (.    ph ->. ( E. v   ( v e. ( 0 (,) 1 ) /\ P = ( ( v x. C ) + ( ( 1 - v ) x. D ) ) )      ->  ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ) ).
qed:10b,46c:          |- (.    ph ->. ( ( abs ` ( P - A ) ) x. ( abs ` ( P - B ) ) ) = ( ( abs ` ( P - C ) ) x. ( abs ` ( P - D ) ) ) ).
$)

$( <MM> <PROOF_ASST> THEOREM=isosctrlem1ALTVD LOC_AFTER=?
* ${
*   $( Lemma for ~ isosctr was proven by Saveliy Skresanov on 30-Dec-2016
*      as ~ isosctrlem1 . ~ isosctrlem1ALTVD is a Virtual Deduction
*      User's Proof based on ~ isosctrlem1 . Using the command line
*      argument argv1 having the value "runCompleteusersproofsmv"
*      completeusersproof will automatically complete
*      ~ isosctrlem1ALTVD , transforming it into a Metamath proof. $)
*   isosctrlem1 $p |- ( ( A e. CC /\ ( abs ` A ) = 1 /\ -. 1 = A ) -> ( Im ` ( log ` ( 1 - A ) ) ) =/= pi ) $= ? $.
* $}
*
1::                |- (. A e. CC ->. A e. CC ).
2::                |- 1 e. CC
3:1,2:             |- (. A e. CC ->. ( ( 1 - A ) = 0 -> 1 = A ) ).
4:3:               |- (. A e. CC ->. ( -. 1 = A -> -. ( 1 - A ) = 0 ) ).
5::                |- ( -. ( 1 - A ) = 0 -> ( 1 - A ) =/= 0 )
6:4,5:             |- (. A e. CC ->. ( -. 1 = A -> ( 1 - A ) =/= 0 ) ).
7:6:               |- (. (. A e. CC ,. -. 1 = A ). ->. ( 1 - A ) =/= 0 ).
8:1:               |- (. A e. CC ->. ( Re ` A ) <_ ( abs ` A ) ).
9::                |- (. ( abs ` A ) = 1 ->. ( abs ` A ) = 1  ).
10:8,9:            |- (. (. A e. CC ,. ( abs ` A ) = 1 ). ->. ( Re ` A ) <_ 1 ).
11:1:              |- (. A e. CC ->. ( Re ` A ) e. RR ).
12:2:              |- 1 e. RR
13:11,12,10:       |- (. (. A e. CC ,. ( abs ` A ) = 1  ). ->. ( ( Re ` A ) - ( Re ` A ) ) <_ ( 1 - ( Re ` A ) ) ).
14:1:              |- (. A e. CC ->. ( Re ` A ) e. RR ).
15:14:             |- (. A e. CC ->. ( Re ` A ) e. CC ).
16:15:             |- (. A e. CC ->. ( ( Re ` A ) - ( Re ` A ) ) = 0 ).
17:13,16:          |- (. (. A e. CC ,. ( abs ` A ) = 1 ). ->. 0 <_ ( 1 - ( Re ` A ) ) ).
18:12:             |- ( Re ` 1 ) = 1
19:18:             |- ( 1 - ( Re ` A ) ) = ( ( Re ` 1 ) - ( Re ` A ) )
20:1,2:            |- (. A e. CC ->. ( ( Re ` 1 ) - ( Re ` A ) ) = ( Re ` ( 1 - A ) ) ).
21:19,20:          |- (. A e. CC ->. ( 1 - ( Re ` A ) ) = ( Re ` ( 1 - A ) ) ).
22:17,21:          |- (. (. A e. CC ,. ( abs ` A ) = 1 ). ->. 0 <_ ( Re ` ( 1 - A ) ) ).
23:1,2:            |- (. A e. CC ->. ( 1 - A ) e. CC ).
24:23,7,22:        |- (. (. A e. CC ,. ( abs ` A ) = 1 ,. -. 1 = A ). ->. ( Im ` ( log ` ( 1 - A ) ) ) e. ( -u ( pi / 2 ) [,] ( pi / 2 ) ) ).
25::               |- pi e. RR
26::               |- 2 e. RR
27::               |- 2 =/= 0
28:25,26,27:       |- ( pi / 2 ) e. RR
29:28:             |- ( pi / 2 ) e. RR*
30:28:             |- -u ( pi / 2 ) e. RR
31:30:             |- -u ( pi / 2 ) e. RR*
32:31,29,24:       |- (. (. A e. CC ,. ( abs ` A ) = 1 ,. -. 1 = A ). ->. ( Im ` ( log ` ( 1 - A ) ) ) <_ ( pi / 2 ) ).
33::               |- 0 < pi
34:33,25:          |- pi e. RR+
35:34:             |- ( pi / 2 ) < pi
36:7,23:           |- (. (. A e. CC ,. -. 1 = A ). ->. ( log ` ( 1 - A ) ) e. CC ).
37:36:             |- (. (. A e. CC ,. -. 1 = A ). ->. ( Im ` ( log ` ( 1 - A ) ) ) e. RR ).
38:37,28,25,32,35: |- (. (. A e. CC ,. ( abs ` A ) = 1 ,.  -. 1 = A ). ->. ( Im ` ( log ` ( 1 - A ) ) ) < pi ).
qed:38,37:         |- (. (. A e. CC ,. ( abs ` A ) = 1 ,.  -. 1 = A ). ->. ( Im ` ( log ` ( 1 - A ) ) ) =/= pi ).
$)

$( <MM> <PROOF_ASST> THEOREM=iunconlem2VD LOC_AFTER=?
* ${
*   $d k u v ph $. $d k u w $. $d A k $. $d A u $. $d A v $. $d A w $.
*   $d B u $. $d B v $. $d B w $. $d J k $. $d J u $. $d J v $. 
*   $d P k $. $d X k $. $d X u $. $d X v $.
*   iunconlem2VD.1     $e |- ( ps <-> (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). ) $.
*   iunconlem2VD.2     $e |- (. ph ->. J e. ( TopOn ` X ) ). $.
*   iunconlem2VD.3     $e |- (. (. ph ,. k e. A ). ->. B C_ X ). $.
*   iunconlem2VD.4     $e |- (. (. ph ,. k e. A ). ->. P e. B ). $.
*   iunconlem2VD.5     $e |- (. (. ph ,. k e. A ). ->. ( J |`t B ) e. Con ). $.
*   $( The indexed union of connected overlapping subspaces sharing a common
*      point is connected. The proof of ~ iunconlem2VD is a Virtual Deduction
*      proof based on Mario Carneiro's proof of ~ iuncon . ~ iunconlem2VD
*      differs from ~ iuncon only in that it is in Virtual Deduction notation
*      and ~ iuncon does not have the first hypothesis of ~ iunconlem2VD ,
*      which is eliminated in ~ iunconALT . The proof of ~ iunconlem2VD is
*      verified by automatically transforming it into the Metamath proof of
*      ~ iunconlem2 using completeusersproof, which is verified by the
*      Metamath program. (Contributed by Alan Sare, 5-Apr-2018.) $) 
*   iunconlem2VD       $p |- (. ph ->. ( J |`t U_ k e. A B ) e. Con ). $= ? $.
* $}
1::                               |- F/ k (. ph ,. u e. J ).
2::                               |- F/ k v e. J
3:1,2:                            |- F/ k ( ( ph /\ u e. J ) /\ v e. J )
4::                               |- F/_ k u
5::                               |- F/_ k U_ k e. A B
6:4,5:                            |- F/_ k ( u i^i U_ k e. A B )
7::                               |- F/_ k (/)
8:6,7:                            |- F/ k ( u i^i U_ k e. A B ) =/= (/)
9:3,8:                            |- F/ k (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ).
10::                              |- F/_ k v
11:10,5:                          |- F/_ k ( v i^i U_ k e. A B )
12:11,7:                          |- F/ k ( v i^i U_ k e. A B ) =/= (/)
13:9,12:                          |- F/ k (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ).
14::                              |- F/_ k ( u i^i v )
15::                              |- F/_ k X
16:15,5:                          |- F/_ k ( X \ U_ k e. A B )
17:14,16:                         |- F/ k ( u i^i v ) C_ ( X \ U_ k e. A B )
18:13,17:                         |- F/ k (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ).
19::                              |- F/_ k ( u u. v )
20:5,19:                          |- F/ k U_ k e. A B C_ ( u u. v )
21:18,20:                         |- F/ k (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ).
h22::                             |- ( ps <-> (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). )
23:22:                            |- ( F/ k ps <-> F/ k (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). )
24:21,23:                         |- F/ k ps
25:22:                            |- (.    ps ->. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). ).
26:25:                            |- (.    ps ->. ph ).
h27::                             |- (.    ph ->. J e. ( TopOn ` X ) ).
28:26,27:                         |- (.    ps ->. J e. ( TopOn ` X ) ).
h29::                             |- (. (. ph ,. k e. A ). ->. B C_ X ).
30:26,29:                         |- (. (. ps ,. k e. A ). ->. B C_ X ).
h31::                             |- (. (. ph ,. k e. A ). ->. P e. B ).
32:26,31:                         |- (. (. ps ,. k e. A ). ->. P e. B ).
33:32:                            |- (.    ps ->. ( k e. A -> P e. B ) ).
h34::                             |- (. (. ph ,. k e. A ). ->. ( J |`t B ) e. Con ).
35:26,34:                         |- (. (. ps ,. k e. A ). ->. ( J |`t B ) e. Con ).
36:25:                            |- (.    ps ->. u e. J ).
37:25:                            |- (.    ps ->. v e. J ).
38:25:                            |- (.    ps ->. ( v i^i U_ k e. A B ) =/= (/) ).
39:25:                            |- (.    ps ->. ( u i^i v ) C_ ( X \ U_ k e. A B ) ).
40:25:                            |- (.    ps ->. U_ k e. A B C_ ( u u. v ) ).
41:28,30,32,35,36,37,38,39,40,24: |- (.    ps ->. -. P e. u ).
42::                              |- ( v i^i u ) = ( u i^i v )
43:39,42:                         |- (.    ps ->. ( v i^i u ) C_ ( X \ U_ k e. A B ) ).
44::                              |- ( v u. u ) = ( u u. v )
45:40,44:                         |- (.    ps ->. U_ k e. A B C_ ( v u. u ) ).
46:25:                            |- (.    ps ->. ( u i^i U_ k e. A B ) =/= (/) ).
47:28,30,32,35,37,36,46,43,45,24: |- (.    ps ->. -. P e. v ).
48:41,47:                         |- (.    ps ->. -. ( P e. u \/ P e. v ) ).
49::                              |- (. w e. ( u i^i U_ k e. A B ) ->. w e. ( u i^i U_ k e. A B ) ).
50::                              |- ( u i^i U_ k e. A B ) C_  U_ k e. A B
51:49,50:                         |- (. w e. ( u i^i U_ k e. A B ) ->. w e. U_ k e. A B ).
52:51:                            |- (. w e. ( u i^i U_ k e. A B ) ->. E. k e. A w e. B ).
53:52:                            |- (. w e. ( u i^i U_ k e. A B ) ->. A =/= (/) ).
54:53:                            |- ( E. w w e. ( u i^i U_ k e. A B ) -> A =/= (/) )
55:46:                            |- (.    ps ->. E. w w e. ( u i^i U_ k e. A B ) ).
56:55,54:                         |- (.    ps ->. A =/= (/) ).
57:24,33:                         |- (.    ps ->. A. k e. A P e. B ).
58:56,57:                         |- (.    ps ->. E. k e. A P e. B ).
59:58:                            |- (.    ps ->. P e. U_ k e. A B ).
60:59,40:                         |- (.    ps ->. P e. ( u u. v ) ).
61:60:                            |- (.    ps ->. ( P e. u \/ P e. v ) ).
62:48,22:                         |- (. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). ->. -. ( P e. u \/ P e. v ) ).
63:61,22:                         |- (. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). ->. ( P e. u \/ P e. v ) ).
64:62,63:                         |- (. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ). ->. -. U_ k e. A B C_ ( u u. v ) ).
65:64:                            |- (. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ). ->. ( ( u i^i v ) C_ ( X \ U_ k e. A B ) -> -. U_ k e. A B C_ ( u u. v ) ) ).
66:65:                            |- (. (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ). ->. ( ( v i^i U_ k e. A B ) =/= (/) -> ( ( u i^i v ) C_ ( X \ U_ k e. A B ) -> -. U_ k e. A B C_ ( u u. v ) ) ) ).
67:66:                            |- (. (. ph ,. u e. J ,. v e. J ). ->. ( ( u i^i U_ k e. A B ) =/= (/) -> ( ( v i^i U_ k e. A B ) =/= (/) -> ( ( u i^i v ) C_ ( X \ U_ k e. A B ) -> -. U_ k e. A B C_ ( u u. v ) ) ) ) ).
68:67:                            |- (. (. ph ,. u e. J ,. v e. J ). ->. ( ( ( u i^i U_ k e. A B ) =/= (/) /\ ( v i^i U_ k e. A B ) =/= (/) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) -> -. U_ k e. A B C_ ( u u. v ) ) ).
69:68:                            |- (. (. ph ,. u e. J ). ->. ( v e. J -> ( ( ( u i^i U_ k e. A B ) =/= (/) /\ ( v i^i U_ k e. A B ) =/= (/) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) -> -. U_ k e. A B C_ ( u u. v ) ) ) ).
70:69:                            |- (.    ph ->. ( u e. J -> ( v e. J -> ( ( ( u i^i U_ k e. A B ) =/= (/) /\ ( v i^i U_ k e. A B ) =/= (/) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) -> -. U_ k e. A B C_ ( u u. v ) ) ) ) ).
71:70:                            |- (.    ph ->. ( ( u e. J /\ v e. J ) -> ( ( ( u i^i U_ k e. A B ) =/= (/) /\ ( v i^i U_ k e. A B ) =/= (/) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) -> -. U_ k e. A B C_ ( u u. v ) ) ) ).
72:71:                            |- (.    ph ->. A. u e. J A. v e. J ( ( ( u i^i U_ k e. A B ) =/= (/) /\ ( v i^i U_ k e. A B ) =/= (/) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) -> -. U_ k e. A B C_ ( u u. v ) ) ).
73:29:                            |- (.    ph ->. ( k e. A -> B C_ X ) ).
74:73:                            |- (.    ph ->. A. k e. A B C_ X ).
75:74:                            |- (.    ph ->. U_ k e. A B C_ X ).
qed:27,75,72:                     |- (.    ph ->. ( J |`t U_ k e. A B ) e. Con ).
$)

$( <MM> <PROOF_ASST> THEOREM=iunconALTVD LOC_AFTER=?
* ${
*   $d k u v ph $. $d k u w $. $d A k $. $d A u $. $d A v $. $d A w $.
*   $d B u $. $d B v $. $d B w $. $d J k $. $d J u $. $d J v $. 
*   $d P k $. $d X k $. $d X u $. $d X v $.
*   iunconALTVD.2      $e |- (. ph ->. J e. (TopOn ` X ) ). $.
*   iunconALTVD.3      $e |- (. (. ph ,. k e. A ). ->. B C_ X ). $.
*   iunconALTVD.4      $e |- (. (. ph ,. k e. A ). ->. P e. B ). $.
*   iunconALTVD.5      $e |- (. (. ph ,. k e. A ). ->. ( J |`t B ) e. Con ). $.
*   $( The indexed union of connected overlapping subspaces sharing a common
*      point is connected. The proof of ~ iunconALTVD is a Virtual Deduction
*      proof of based on Mario Carneiro's proof of ~ iuncon . The proof of
*      ~ iunconALTVD is verified by automatically transforming it into the
*      Metamath proof of ~ iunconALT using completeusersproof, which is
*      verified by the Metamath program. (Contributed by
*      Alan Sare, 9-Apr-2018.) $)
*   iunconALTVD       $p |- (. ph ->. ( J |`t U_ k e. A B ) e. Con ). $= ? $.
* $}
h1::                     |- (.    ph ->. J e. ( TopOn ` X ) ).
h2::                     |- (. (. ph ,. k e. A ). ->. B C_ X ).
h3::                     |- (. (. ph ,. k e. A ). ->. P e. B ).
h4::                     |- (. (. ph ,. k e. A ). ->. ( J |`t B ) e. Con ).
5::                      |- ( ( ( ( ( ( ( ph /\ u e. J ) /\ v e. J ) /\ ( u i^i U_ k e. A B ) =/= (/) ) /\ ( v i^i U_ k e. A B ) =/= (/) ) /\ ( u i^i v ) C_ ( X \ U_ k e. A B ) ) /\ U_ k e. A B C_ ( u u. v ) ) <-> (. ph ,. u e. J ,. v e. J ,. ( u i^i U_ k e. A B ) =/= (/) ,. ( v i^i U_ k e. A B ) =/= (/) ,. ( u i^i v ) C_ ( X \ U_ k e. A B ) ,. U_ k e. A B C_ ( u u. v ) ). )
qed:1,2,3,4,5:           |- (.    ph ->. ( J |`t U_ k e. A B ) e. Con ).
$)