Connecting to your Zend_Amf_Server from your Flex project is quite simple; you simply need to point your endpoint URI to your Zend_Amf_Server script.

Say, for instance, you have created your server and placed it in the server.php file in your application root, and thus the URI is http://example.com/server.php. In this case, you would modify your services-config.xml file to set the channel endpoint uri attribute to this value.

If you have never created a service-config.xml file you can do so by opening your project in your Navigator window. Right click on the project name and select ‘properties’. In the Project properties dialog go into ‘Flex Build Path’ menu, ‘Library path’ tab and be sure the ‘rpc.swc’ file is added to your projects path and Press Ok to close the window.

You will also need to tell the compiler to use the service-config.xml to find the RemoteObject endpoint. To do this open your project properties panel again by right clicking on the project folder from your Navigator and selecting properties. From the properties popup select ‘Flex Compiler’ and add the string: -services “services-config.xml”. Press Apply then OK to return to update the option. What you have just done is told the Flex compiler to look to the services-config.xml file for runtime variables that will be used by the RemotingObject class.

We now need to tell Flex which services configuration file to use for connecting to our remote methods. For this reason create a new ‘services-config.xml’ file into your Flex project src folder. To do this right click on the project folder and select ‘new’ ‘File’ which will popup a new window. Select the project folder and then name the file ‘services-config.xml’ and press finish.

Flex has created the new services-config.xml and has it open. Use the following example text for your services-config.xml file. Make sure that you update your endpoint to match that of your testing server. Make sure you save the file.

<?xml version="1.0" encoding="UTF-8"?>
<services-config>
    <services>
        <service id="zend-service"
            class="flex.messaging.services.RemotingService"
            messageTypes="flex.messaging.messages.RemotingMessage">
            <destination id="zend">
                <channels>
                    <channel ref="zend-endpoint"/>
                </channels>
                <properties>
                    <source>*</source>
                </properties>
            </destination>
        </service>
    </services>
    <channels>
        <channel-definition id="zend-endpoint"
            class="mx.messaging.channels.AMFChannel">
            <endpoint uri="http://example.com/server.php"
                class="flex.messaging.endpoints.AMFEndpoint"/>
        </channel-definition>
    </channels>
</services-config>

        

There are two key points in the example. First, but last in the listing, we create an AMF channel, and specify the endpoint as the URL to our Zend_Amf_Server:

<channel-definition id="zend-endpoint"
    <endpoint uri="http://example.com/server.php"
        class="flex.messaging.endpoints.AMFEndpoint"/>
</channel-definition>

        

Notice that we've given this channel an identifier, "zend-endpoint". The example create a service destination that refers to this channel, assigning it an ID as well -- in this case "zend".

Within our Flex MXML files, we need to bind a RemoteObject to the service. In MXML, this might be done as follows:

<mx:RemoteObject id="myservice"
    fault="faultHandler(event)"
    showBusyCursor="true"
    destination="zend">

        

Here, we've defined a new remote object identified by "myservice" bound to the service destination "zend" we defined in the services-config.xml file. We then call methods on it in in our ActionScript by simply calling "myservice.<method>". As an example:

myservice.hello("Wade");

        

When namespacing, you would use "myservice.<namespace>.<method>":

myservice.world.hello("Wade");

        

For more information on Flex RemoteObject invocation, visit the Adobe Flex 3 Help site.

By default, all exceptions thrown in your attached classes or functions will be caught and returned as AMF ErrorMessages. However, the content of these ErrorMessage objects will vary based on whether or not the server is in "production" mode (the default state).

When in production mode, only the exception code will be returned. If you disable production mode -- something that should be done for testing only -- most exception details will be returned: the exception message, line, and backtrace will all be attached.

To disable production mode, do the following:

$server->setProduction(false);

        

To re-enable it, pass a true boolean value instead:

$server->setProduction(true);

        

	Disable production mode sparingly!
	We recommend disabling production mode only when in development. Exception messages and backtraces can contain sensitive system information that you may not wish for outside parties to access. Even though AMF is a binary format, the specification is now open, meaning anybody can potentially deserialize the payload.

One area to be especially careful with is PHP errors themselves. When the display_errors INI directive is enabled, any PHP errors for the current error reporting level are rendered directly in the output -- potentially disrupting the AMF response payload. We suggest turning off the display_errors directive in production to prevent such problems

Occasionally you may desire to manipulate the response object slightly, typically to return extra message headers. The handle() method of the server returns the response object, allowing you to do so.

$response = $server->handle();
$response->addAmfHeader(new Zend_Amf_Value_MessageHeader('foo', true, 'bar'))
echo $response;

            

Similar to SOAP, AMF allows passing objects between the client and server. This allows a great amount of flexibility and coherence between the two environments.

Zend_Amf provides three methods for mapping ActionScript and PHP objects.

Although we have created the ContactVO on the server we now need to make its corresponding class in AS3 for the server object to be mapped to.

Right click on the src folder of the Flex project and select New -> ActionScript File. Name the file ContactVO and press finish to see the new file. Copy the following code into the file to finish creating the class.

package
{
    [Bindable]
    [RemoteClass(alias="ContactVO")]
    public class ContactVO
    {
        public var id:int;
        public var firstname:String;
        public var lastname:String;
        public var email:String;
        public var mobile:String;
        public function ProductVO():void {
        }
    }
}

            

The class is syntactically equivalent to the PHP of the same name. The variable names are exactly the same and need to be in the same case to work properly. There are two unique AS3 meta tags in this class. The first is bindable which makes fire a change event when it is updated. The second tag is the RemoteClass tag which defines that this class can have a a remote object mapped with the alias name in this case ContactVO It is mandatory that this tag the value that was set is the PHP class are strictly equivalent.

[Bindable]
private var myContact:ContactVO;

private function getContactHandler(event:ResultEvent):void {
    myContact = ContactVO(event.result);
}

        

The following result event from the service call is cast instantly onto the Flex ContactVO. Anything that is bound to myContact will be updated with the returned ContactVO data.

Connecting to your Zend_Amf_Server from your Flash project is slightly different than from Flex. However once the connection Flash functions with Zend_Amf_Server the same way is flex. The following example can also be used from a Flex AS3 file. We will reuse the same Zend_Amf_Server configuration along with the World class for our connection.

Open Flash CS and create and new Flash File (ActionScript 3). Name the document ZendExample.fla and save the document into a folder that you will use for this example. Create a new AS3 file in the same directory and call the file Main.as. Have both files open in your editor. We are now going to connect the two files via the document class. Select ZendExample and click on the stage. From the stage properties panel change the Document class to Main. This links the Main.as ActionScript file with the user interface in ZendExample.fla. When you run the Flash file ZendExample the Main.as class will now be run. Next we will add ActionScript to make the AMF call.

We now are going to make a Main class so that we can send the data to the server and display the result. Copy the following code into your Main.as file and then we will walk through the code to describe what each element's role is.

package {
  import flash.display.MovieClip;
  import flash.events.*;
  import flash.net.NetConnection;
  import flash.net.Responder;

  public class Main extends MovieClip {
    private var gateway:String = "http://example.com/server.php";
    private var connection:NetConnection;
    private var responder:Responder;

    public function Main() {
      responder = new Responder(onResult, onFault);
      connection = new NetConnection;
      connection.connect(gateway);
    }

    public function onComplete( e:Event ):void{
      var params = "Sent to Server";
      connection.call("World.hello", responder, params);
    }

    private function onResult(result:Object):void {
      // Display the returned data
      trace(String(result));
    }
    private function onFault(fault:Object):void {
      trace(String(fault.description));
    }
  }
}

        

We first need to import two ActionScript libraries that perform the bulk of the work. The first is NetConnection which acts like a by directional pipe between the client and the server. The second is a Responder object which handles the return values from the server related to the success or failure of the call.

import flash.net.NetConnection;
import flash.net.Responder;

        

In the class we need three variables to represent the NetConnection, Responder, and the gateway URL to our Zend_Amf_Server installation.

private var gateway:String = "http://example.com/server.php";
private var connection:NetConnection;
private var responder:Responder;

        

In the Main constructor we create a responder and a new connection to the Zend_Amf_Server endpoint. The responder defines two different methods for handling the response from the server. For simplicity I have called these onResult and onFault.

responder = new Responder(onResult, onFault);
connection = new NetConnection;
connection.connect(gateway);

        

In the onComplete function which is run as soon as the construct has completed we send the data to the server. We need to add one more line that makes a call to the Zend_Amf_Server World->hello function.

connection.call("World.hello", responder, params);

        

When we created the responder variable we defined an onResult and onFault function to handle the response from the server. We added this function for the successful result from the server. A successful event handler is run every time the connection is handled properly to the server.

private function onResult(result:Object):void {
    // Display the returned data
    trace(String(result));
}

        

The onFault function, is called if there was an invalid response from the server. This happens when there is an error on the server, the URL to the server is invalid, the remote service or method does not exist, and any other connection related issues.

private function onFault(fault:Object):void {
    trace(String(fault.description));
}

        

Adding in the ActionScript to make the remoting connection is now complete. Running the ZendExample file now makes a connection to Zend Amf. In review you have added the required variables to open a connection to the remote server, defined what methods should be used when your application receives a response from the server, and finally displayed the returned data to output via trace().