了解受保护的内容工作流程

下列步骤介绍了使用 DRMContentData 对象为保护的媒体文件预加载凭证的工作流程。

1. 获取打包内容的二进制元数据。如果使用的是 Flash Access Java Reference 包装程序，则会自动生成带有 .metadata 扩展名的元数据文件。例如，可以使用 URLLoader 类下载此元数据。

2. 创建一个 DRMContentData 对象，将此元数据传递给构造函数：

   var drmData:DRMContentData = new DRMContentData( metadata );

3. 其余步骤与了解受保护的内容工作流程中介绍的工作流程相同。

下列步骤介绍了使用 preloadEmbeddedMetadata() 为 DRM 保护的媒体文件预加载凭证的工作流程：

1. 下载并存储媒体文件。（只能从本地存储的文件中预加载 DRM 元数据。）

2. 创建 NetConnection 和 NetStream 对象，为 NetStream 客户端对象的 onDRMContentData() 和 onPlayStatus() 回调函数提供实现。

3. 创建 NetStreamPlayOptions 对象，并将 stream 属性设置为本地媒体文件的 URL。

4. 调用 NetStream preloadEmbeddedMetadata()，并传入 NetStreamPlayOptions 对象，从而标识要分析的媒体文件。

5. 如果媒体文件包含 DRM 元数据，则调用 onDRMContentData() 回调函数。将元数据作为 DRMContentData 对象传递到此函数。

6. 使用 DRMContentData 对象通过 DRMManager loadVoucher() 方法获取凭证。

   如果 DRMContentData 对象的 authenticationMethod 属性的值为 userNameAndPassword，则在加载凭证之前对媒体权限服务器上的用户进行身份验证。可以将 DRMContentData 对象的 serverURL 和 domain 属性传递给 DRMManager authenticate() 方法，附带用户的凭据。

7. 文件分析完毕后将调用 onPlayStatus() 回调函数。如果尚未调用 onDRMContentData() 函数，则文件不包含获取凭证所需的元数据。此缺失调用还可能意味着 Flash Access 不保护此文件。

以下 AIR 代码示例说明如何为本地媒体文件预加载凭证：

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}