r9lgit.f

Go to the documentation of this file.

*DECK R9LGIT
      FUNCTION r9lgit (A, X, ALGAP1)
C***BEGIN PROLOGUE  R9LGIT
C***SUBSIDIARY
C***PURPOSE  Compute the logarithm of Tricomi's incomplete Gamma
C            function with Perron's continued fraction for large X and
C            A .GE. X.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C7E
C***TYPE      SINGLE PRECISION (R9LGIT-S, D9LGIT-D)
C***KEYWORDS  FNLIB, INCOMPLETE GAMMA FUNCTION, LOGARITHM,
C             PERRON'S CONTINUED FRACTION, SPECIAL FUNCTIONS, TRICOMI
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C Compute the log of Tricomi's incomplete gamma function with Perron's
C continued fraction for large X and for A .GE. X.
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  R1MACH, XERMSG
C***REVISION HISTORY  (YYMMDD)
C   770701  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900315  CALLs to XERROR changed to CALLs to XERMSG.  (THJ)
C   900720  Routine changed from user-callable to subsidiary.  (WRB)
C***END PROLOGUE  R9LGIT
      SAVE eps, sqeps
      DATA eps, sqeps / 2*0.0 /
C***FIRST EXECUTABLE STATEMENT  R9LGIT
      IF (eps.EQ.0.0) eps = 0.5*r1mach(3)
      IF (sqeps.EQ.0.0) sqeps = sqrt(r1mach(4))
C
      IF (x .LE. 0.0 .OR. a .LT. x) CALL xermsg('SLATEC', 'R9LGIT',
     +   'X SHOULD BE GT 0.0 AND LE A', 2, 2)
C
      ax = a + x
      a1x = ax + 1.0
      r = 0.0
      p = 1.0
      s = p
      DO 20 k=1,200
        fk = k
        t = (a+fk)*x*(1.0+r)
        r = t/((ax+fk)*(a1x+fk)-t)
        p = r*p
        s = s + p
        IF (abs(p).LT.eps*s) go to 30
 20   CONTINUE
      CALL xermsg('SLATEC', 'R9LGIT',
     +   'NO CONVERGENCE IN 200 TERMS OF CONTINUED FRACTION', 3, 2)
C
 30   hstar = 1.0 - x*s/a1x
      IF (hstar .LT. sqeps) CALL xermsg('SLATEC', 'R9LGIT',
     +   'RESULT LESS THAN HALF PRECISION', 1, 1)
C
      r9lgit = -x - algap1 - log(hstar)
C
      RETURN
      END