dnsik.f

Go to the documentation of this file.

C Work performed under the auspices of the U.S. Department of Energy
C by Lawrence Livermore National Laboratory under contract number
C W-7405-Eng-48.
C
      SUBROUTINE dnsik(X,Y,YPRIME,NEQ,ICOPT,ID,RES,PSOL,WT,RPAR,IPAR,
     *   savr,delta,r,yic,ypic,pwk,wm,iwm,cj,sqrtn,rsqrtn,eplin,epcon,
     *   ratemx,maxit,stptol,icnflg,icnstr,iernew)
C
C***BEGIN PROLOGUE  DNSIK
C***REFER TO  DDASPK
C***DATE WRITTEN   940701   (YYMMDD)
C***REVISION DATE  950714   (YYMMDD)
C
C
C-----------------------------------------------------------------------
C***DESCRIPTION
C
C     DNSIK solves a nonlinear system of algebraic equations of the
C     form G(X,Y,YPRIME) = 0 for the unknown parts of Y and YPRIME in
C     the initial conditions.
C
C     The method used is a Newton scheme combined with a linesearch
C     algorithm, using Krylov iterative linear system methods.
C
C     The parameters represent
C
C     X         -- Independent variable.
C     Y         -- Solution vector.
C     YPRIME    -- Derivative of solution vector.
C     NEQ       -- Number of unknowns.
C     ICOPT     -- Initial condition option chosen (1 or 2).
C     ID        -- Array of dimension NEQ, which must be initialized
C                  if ICOPT = 1.  See DDASIC.
C     RES       -- External user-supplied subroutine
C                  to evaluate the residual.  See RES description
C                  in DDASPK prologue.
C     PSOL      -- External user-supplied routine to solve
C                  a linear system using preconditioning.
C                  See explanation inside DDASPK.
C     WT        -- Vector of weights for error criterion.
C     RPAR,IPAR -- Real and integer arrays used for communication
C                  between the calling program and external user
C                  routines.  They are not altered within DASPK.
C     SAVR      -- Work vector for DNSIK of length NEQ.
C     DELTA     -- Residual vector on entry, and work vector of
C                  length NEQ for DNSIK.
C     R         -- Work vector for DNSIK of length NEQ.
C     YIC,YPIC  -- Work vectors for DNSIK, each of length NEQ.
C     PWK       -- Work vector for DNSIK of length NEQ.
C     WM,IWM    -- Real and integer arrays storing
C                  matrix information such as the matrix
C                  of partial derivatives, permutation
C                  vector, and various other information.
C     CJ        -- Matrix parameter = 1/H (ICOPT = 1) or 0 (ICOPT = 2).
C     SQRTN     -- Square root of NEQ.
C     RSQRTN    -- reciprical of square root of NEQ.
C     EPLIN     -- Tolerance for linear system solver.
C     EPCON     -- Tolerance to test for convergence of the Newton
C                  iteration.
C     RATEMX    -- Maximum convergence rate for which Newton iteration
C                  is considered converging.
C     MAXIT     -- Maximum allowed number of Newton iterations.
C     STPTOL    -- Tolerance used in calculating the minimum lambda
C                  value allowed.
C     ICNFLG    -- Integer scalar.  If nonzero, then constraint
C                  violations in the proposed new approximate solution
C                  will be checked for, and the maximum step length
C                  will be adjusted accordingly.
C     ICNSTR    -- Integer array of length NEQ containing flags for
C                  checking constraints.
C     IERNEW    -- Error flag for Newton iteration.
C                   0  ==> Newton iteration converged.
C                   1  ==> failed to converge, but RATE .lt. 1.
C                   2  ==> failed to converge, RATE .gt. RATEMX.
C                   3  ==> other recoverable error.
C                  -1  ==> unrecoverable error inside Newton iteration.
C-----------------------------------------------------------------------
C
C***ROUTINES CALLED
C   DFNRMK, DSLVK, DDWNRM, DLINSK, DCOPY
C
C***END PROLOGUE  DNSIK
C
C
      IMPLICIT DOUBLE PRECISION(a-h,o-z)
      dimension y(*),yprime(*),wt(*),id(*),delta(*),r(*),savr(*)
      dimension yic(*),ypic(*),pwk(*),wm(*),iwm(*), rpar(*),ipar(*)
      dimension icnstr(*)
      EXTERNAL res, psol
C
      parameter(lnni=19, lnps=21, llocwp=29, llciwp=30)
      parameter(llsoff=35, lstol=14)
C
C
C     Initializations.  M is the Newton iteration counter.
C
      lsoff = iwm(llsoff)
      m = 0
      rate = 1.0d0
      lwp = iwm(llocwp)
      liwp = iwm(llciwp)
      rlx = 0.4d0
C
C     Save residual in SAVR.
C
      CALL dcopy(neq, delta, 1, savr, 1)
C
C     Compute norm of (P-inverse)*(residual).
C
      CALL dfnrmk(neq, y, x, yprime, savr, r, cj, wt, sqrtn, rsqrtn,
     *   res, ires, psol, 1, ier, fnrm, eplin, wm(lwp), iwm(liwp),
     *   pwk, rpar, ipar)
      iwm(lnps) = iwm(lnps) + 1
      IF (ier .NE. 0) THEN
        iernew = 3
        RETURN
      ENDIF
C
C     Return now if residual norm is .le. EPCON.
C
      IF (fnrm .LE. epcon) RETURN
C
C     Newton iteration loop.
C
300   CONTINUE
      iwm(lnni) = iwm(lnni) + 1
C
C     Compute a new step vector DELTA.
C
      CALL dslvk(neq, y, x, yprime, savr, delta, wt, wm, iwm,
     *   res, ires, psol, iersl, cj, eplin, sqrtn, rsqrtn, rhok,
     *   rpar, ipar)
      IF (ires .NE. 0 .OR. iersl .NE. 0) go to 390
C
C     Get norm of DELTA.  Return now if DELTA is zero.
C
      delnrm = ddwnrm(neq,delta,wt,rpar,ipar)
      IF (delnrm .EQ. 0.0d0) RETURN
C
C     Call linesearch routine for global strategy and set RATE.
C
      oldfnm = fnrm
C
      CALL dlinsk(neq, y, x, yprime, savr, cj, delta, delnrm, wt,
     *   sqrtn, rsqrtn, lsoff, stptol, iret, res, ires, psol, wm, iwm,
     *   rhok, fnrm, icopt, id, wm(lwp), iwm(liwp), r, eplin, yic, ypic,
     *   pwk, icnflg, icnstr, rlx, rpar, ipar)
C
      rate = fnrm/oldfnm
C
C     Check for error condition from linesearch.
      IF (iret .NE. 0) go to 390
C
C     Test for convergence of the iteration, and return or loop.
C
      IF (fnrm .LE. epcon) RETURN
C
C     The iteration has not yet converged.  Update M.
C     Test whether the maximum number of iterations have been tried.
C
      m=m+1
      IF(m .GE. maxit) go to 380
C
C     Copy the residual SAVR to DELTA and loop for another iteration.
C
      CALL dcopy(neq,  savr, 1, delta, 1)
      go to 300
C
C     The maximum number of iterations was done.  Set IERNEW and return.
C
380   IF (rate .LE. ratemx) THEN
         iernew = 1
      ELSE
         iernew = 2
      ENDIF
      RETURN
C
390   IF (ires .LE. -2 .OR. iersl .LT. 0) THEN
         iernew = -1
      ELSE
         iernew = 3
         IF (ires .EQ. 0 .AND. iersl .EQ. 1 .AND. m .GE. 2
     1       .AND. rate .LT. 1.0d0) iernew = 1
      ENDIF
      RETURN
C
C
C----------------------- END OF SUBROUTINE DNSIK------------------------
      END