atanh.f

Go to the documentation of this file.

*DECK ATANH
      FUNCTION atanh (X)
C***BEGIN PROLOGUE  ATANH
C***PURPOSE  Compute the arc hyperbolic tangent.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C4C
C***TYPE      SINGLE PRECISION (ATANH-S, DATANH-D, CATANH-C)
C***KEYWORDS  ARC HYPERBOLIC TANGENT, ATANH, ELEMENTARY FUNCTIONS,
C             FNLIB, INVERSE HYPERBOLIC TANGENT
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C ATANH(X) computes the arc hyperbolic tangent of X.
C
C Series for ATNH       on the interval  0.          to  2.50000D-01
C                                        with weighted error   6.70E-18
C                                         log weighted error  17.17
C                               significant figures required  16.01
C                                    decimal places required  17.76
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  CSEVL, INITS, R1MACH, XERMSG
C***REVISION HISTORY  (YYMMDD)
C   770401  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900315  CALLs to XERROR changed to CALLs to XERMSG.  (THJ)
C   900326  Removed duplicate information from DESCRIPTION section.
C           (WRB)
C***END PROLOGUE  ATANH
      dimension atnhcs(15)
      LOGICAL FIRST
      SAVE atnhcs, nterms, dxrel, sqeps, first
      DATA atnhcs( 1) /    .0943951023 93195492e0 /
      DATA atnhcs( 2) /    .0491984370 55786159e0 /
      DATA atnhcs( 3) /    .0021025935 22455432e0 /
      DATA atnhcs( 4) /    .0001073554 44977611e0 /
      DATA atnhcs( 5) /    .0000059782 67249293e0 /
      DATA atnhcs( 6) /    .0000003505 06203088e0 /
      DATA atnhcs( 7) /    .0000000212 63743437e0 /
      DATA atnhcs( 8) /    .0000000013 21694535e0 /
      DATA atnhcs( 9) /    .0000000000 83658755e0 /
      DATA atnhcs(10) /    .0000000000 05370503e0 /
      DATA atnhcs(11) /    .0000000000 00348665e0 /
      DATA atnhcs(12) /    .0000000000 00022845e0 /
      DATA atnhcs(13) /    .0000000000 00001508e0 /
      DATA atnhcs(14) /    .0000000000 00000100e0 /
      DATA atnhcs(15) /    .0000000000 00000006e0 /
      DATA first /.true./
C***FIRST EXECUTABLE STATEMENT  ATANH
      IF (first) THEN
         nterms = inits(atnhcs, 15, 0.1*r1mach(3))
         dxrel = sqrt(r1mach(4))
         sqeps = sqrt(3.0*r1mach(3))
      ENDIF
      first = .false.
C
      y = abs(x)
      IF (y .GE. 1.0) THEN
         IF (y .GT. 1.0) THEN
            atanh = (x - x) / (x - x)
         ELSE
            atanh = x / 0.0
         ENDIF
         RETURN
      ENDIF
C
      IF (1.0-y .LT. dxrel) CALL xermsg('SLATEC', 'ATANH',
     +   'ANSWER LT HALF PRECISION BECAUSE ABS(X) TOO NEAR 1', 1, 1)
C
      atanh = x
      IF (y.GT.sqeps .AND. y.LE.0.5) atanh = x*(1.0 + csevl(8.*x*x-1.,
     1  atnhcs, nterms))
      IF (y.GT.0.5) atanh = 0.5*log((1.0+x)/(1.0-x))
C
      RETURN
      END