acosh.f

Go to the documentation of this file.

*DECK ACOSH
      FUNCTION acosh (X)
C***BEGIN PROLOGUE  ACOSH
C***PURPOSE  Compute the arc hyperbolic cosine.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C4C
C***TYPE      SINGLE PRECISION (ACOSH-S, DACOSH-D, CACOSH-C)
C***KEYWORDS  ACOSH, ARC HYPERBOLIC COSINE, ELEMENTARY FUNCTIONS, FNLIB,
C             INVERSE HYPERBOLIC COSINE
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C ACOSH(X) computes the arc hyperbolic cosine of X.
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  R1MACH, XERMSG
C***REVISION HISTORY  (YYMMDD)
C   770401  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900315  CALLs to XERROR changed to CALLs to XERMSG.  (THJ)
C   900326  Removed duplicate information from DESCRIPTION section.
C           (WRB)
C***END PROLOGUE  ACOSH
      SAVE aln2,xmax
      DATA aln2 / 0.6931471805 5994530942e0/
      DATA xmax /0./
C***FIRST EXECUTABLE STATEMENT  ACOSH
      IF (xmax.EQ.0.) xmax = 1.0/sqrt(r1mach(3))
C
      IF (x .LT. 1.0) CALL xermsg('SLATEC', 'ACOSH', 'X LESS THAN 1',
     +   1, 2)
C
      IF (x.LT.xmax) acosh = log(x + sqrt(x*x-1.0))
      IF (x.GE.xmax) acosh = aln2 + log(x)
C
      RETURN
      END