dgamr.f

Go to the documentation of this file.

*DECK DGAMR
      DOUBLE PRECISION FUNCTION dgamr (X)
C***BEGIN PROLOGUE  DGAMR
C***PURPOSE  Compute the reciprocal of the Gamma function.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C7A
C***TYPE      DOUBLE PRECISION (GAMR-S, DGAMR-D, CGAMR-C)
C***KEYWORDS  FNLIB, RECIPROCAL GAMMA FUNCTION, SPECIAL FUNCTIONS
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C DGAMR(X) calculates the double precision reciprocal of the
C complete Gamma function for double precision argument X.
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  DGAMMA, DLGAMS, XERCLR, XGETF, XSETF
C***REVISION HISTORY  (YYMMDD)
C   770701  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C   900727  Added EXTERNAL statement.  (WRB)
C***END PROLOGUE  DGAMR
      DOUBLE PRECISION X, ALNGX, SGNGX, DGAMMA
      EXTERNAL dgamma
C***FIRST EXECUTABLE STATEMENT  DGAMR
      dgamr = 0.0d0
      IF (x.LE.0.0d0 .AND. aint(x).EQ.x) RETURN
C
      CALL xgetf(irold)
      CALL xsetf(1)
      IF (abs(x).GT.10.0d0) go to 10
      dgamr = 1.0d0/dgamma(x)
      CALL xerclr
      CALL xsetf(irold)
      RETURN
C
 10   CALL dlgams(x, alngx, sgngx)
      CALL xerclr
      CALL xsetf(irold)
      dgamr = sgngx * exp(-alngx)
      RETURN
C
      END