cwrsk.f

Go to the documentation of this file.

      SUBROUTINE cwrsk(ZR, FNU, KODE, N, Y, NZ, CW, TOL, ELIM, ALIM)
C***BEGIN PROLOGUE  CWRSK
C***REFER TO  CBESI,CBESK
C
C     CWRSK COMPUTES THE I BESSEL FUNCTION FOR RE(Z).GE.0.0 BY
C     NORMALIZING THE I FUNCTION RATIOS FROM CRATI BY THE WRONSKIAN
C
C***ROUTINES CALLED  CBKNU,CRATI,R1MACH
C***END PROLOGUE  CWRSK
      COMPLEX CINU, CSCL, CT, CW, C1, C2, RCT, ST, Y, ZR
      REAL ACT, ACW, ALIM, ASCLE, ELIM, FNU, S1, S2, TOL, YY
      INTEGER I, KODE, N, NW, NZ
      dimension y(n), cw(2)
C-----------------------------------------------------------------------
C     I(FNU+I-1,Z) BY BACKWARD RECURRENCE FOR RATIOS
C     Y(I)=I(FNU+I,Z)/I(FNU+I-1,Z) FROM CRATI NORMALIZED BY THE
C     WRONSKIAN WITH K(FNU,Z) AND K(FNU+1,Z) FROM CBKNU.
C-----------------------------------------------------------------------
      nz = 0
      CALL cbknu(zr, fnu, kode, 2, cw, nw, tol, elim, alim)
      IF (nw.NE.0) go to 50
      CALL crati(zr, fnu, n, y, tol)
C-----------------------------------------------------------------------
C     RECUR FORWARD ON I(FNU+1,Z) = R(FNU,Z)*I(FNU,Z),
C     R(FNU+J-1,Z)=Y(J),  J=1,...,N
C-----------------------------------------------------------------------
      cinu = cmplx(1.0e0,0.0e0)
      IF (kode.EQ.1) go to 10
      yy = aimag(zr)
      s1 = cos(yy)
      s2 = sin(yy)
      cinu = cmplx(s1,s2)
   10 CONTINUE
C-----------------------------------------------------------------------
C     ON LOW EXPONENT MACHINES THE K FUNCTIONS CAN BE CLOSE TO BOTH
C     THE UNDER AND OVERFLOW LIMITS AND THE NORMALIZATION MUST BE
C     SCALED TO PREVENT OVER OR UNDERFLOW. CUOIK HAS DETERMINED THAT
C     THE RESULT IS ON SCALE.
C-----------------------------------------------------------------------
      acw = cabs(cw(2))
      ascle = 1.0e+3*r1mach(1)/tol
      cscl = cmplx(1.0e0,0.0e0)
      IF (acw.GT.ascle) go to 20
      cscl = cmplx(1.0e0/tol,0.0e0)
      go to 30
   20 CONTINUE
      ascle = 1.0e0/ascle
      IF (acw.LT.ascle) go to 30
      cscl = cmplx(tol,0.0e0)
   30 CONTINUE
      c1 = cw(1)*cscl
      c2 = cw(2)*cscl
      st = y(1)
C-----------------------------------------------------------------------
C     CINU=CINU*(CONJG(CT)/CABS(CT))*(1.0E0/CABS(CT) PREVENTS
C     UNDER- OR OVERFLOW PREMATURELY BY SQUARING CABS(CT)
C-----------------------------------------------------------------------
      ct = zr*(c2+st*c1)
      act = cabs(ct)
      rct = cmplx(1.0e0/act,0.0e0)
      ct = conjg(ct)*rct
      cinu = cinu*rct*ct
      y(1) = cinu*cscl
      IF (n.EQ.1) RETURN
      DO 40 i=2,n
        cinu = st*cinu
        st = y(i)
        y(i) = cinu*cscl
   40 CONTINUE
      RETURN
   50 CONTINUE
      nz = -1
      IF(nw.EQ.(-2)) nz=-2
      RETURN
      END