scfode.f

Go to the documentation of this file.

      SUBROUTINE scfode (METH, ELCO, TESCO)
C***BEGIN PROLOGUE  SCFODE
C***SUBSIDIARY
C***PURPOSE  Set ODE integrator coefficients.
C***TYPE      SINGLE PRECISION (SCFODE-S, DCFODE-D)
C***AUTHOR  Hindmarsh, Alan C., (LLNL)
C***DESCRIPTION
C
C  SCFODE is called by the integrator routine to set coefficients
C  needed there.  The coefficients for the current method, as
C  given by the value of METH, are set for all orders and saved.
C  The maximum order assumed here is 12 if METH = 1 and 5 if METH = 2.
C  (A smaller value of the maximum order is also allowed.)
C  SCFODE is called once at the beginning of the problem,
C  and is not called again unless and until METH is changed.
C
C  The ELCO array contains the basic method coefficients.
C  The coefficients el(i), 1 .le. i .le. nq+1, for the method of
C  order nq are stored in ELCO(i,nq).  They are given by a genetrating
C  polynomial, i.e.,
C      l(x) = el(1) + el(2)*x + ... + el(nq+1)*x**nq.
C  For the implicit Adams methods, l(x) is given by
C      dl/dx = (x+1)*(x+2)*...*(x+nq-1)/factorial(nq-1),    l(-1) = 0.
C  For the BDF methods, l(x) is given by
C      l(x) = (x+1)*(x+2)* ... *(x+nq)/K,
C  where         K = factorial(nq)*(1 + 1/2 + ... + 1/nq).
C
C  The TESCO array contains test constants used for the
C  local error test and the selection of step size and/or order.
C  At order nq, TESCO(k,nq) is used for the selection of step
C  size at order nq - 1 if k = 1, at order nq if k = 2, and at order
C  nq + 1 if k = 3.
C
C***SEE ALSO  SLSODE
C***ROUTINES CALLED  (NONE)
C***REVISION HISTORY  (YYMMDD)
C   791129  DATE WRITTEN
C   890501  Modified prologue to SLATEC/LDOC format.  (FNF)
C   890503  Minor cosmetic changes.  (FNF)
C   930809  Renamed to allow single/double precision versions. (ACH)
C***END PROLOGUE  SCFODE
C**End
      INTEGER METH
      INTEGER I, IB, NQ, NQM1, NQP1
      REAL ELCO, TESCO
      REAL AGAMQ, FNQ, FNQM1, PC, PINT, RAGQ,
     1   rqfac, rq1fac, tsign, xpin
      dimension elco(13,12), tesco(3,12)
      dimension pc(12)
C
C***FIRST EXECUTABLE STATEMENT  SCFODE
      go to(100, 200), meth
C
 100  elco(1,1) = 1.0e0
      elco(2,1) = 1.0e0
      tesco(1,1) = 0.0e0
      tesco(2,1) = 2.0e0
      tesco(1,2) = 1.0e0
      tesco(3,12) = 0.0e0
      pc(1) = 1.0e0
      rqfac = 1.0e0
      DO 140 nq = 2,12
C-----------------------------------------------------------------------
C The PC array will contain the coefficients of the polynomial
C     p(x) = (x+1)*(x+2)*...*(x+nq-1).
C Initially, p(x) = 1.
C-----------------------------------------------------------------------
        rq1fac = rqfac
        rqfac = rqfac/nq
        nqm1 = nq - 1
        fnqm1 = nqm1
        nqp1 = nq + 1
C Form coefficients of p(x)*(x+nq-1). ----------------------------------
        pc(nq) = 0.0e0
        DO 110 ib = 1,nqm1
          i = nqp1 - ib
 110      pc(i) = pc(i-1) + fnqm1*pc(i)
        pc(1) = fnqm1*pc(1)
C Compute integral, -1 to 0, of p(x) and x*p(x). -----------------------
        pint = pc(1)
        xpin = pc(1)/2.0e0
        tsign = 1.0e0
        DO 120 i = 2,nq
          tsign = -tsign
          pint = pint + tsign*pc(i)/i
 120      xpin = xpin + tsign*pc(i)/(i+1)
C Store coefficients in ELCO and TESCO. --------------------------------
        elco(1,nq) = pint*rq1fac
        elco(2,nq) = 1.0e0
        DO 130 i = 2,nq
 130      elco(i+1,nq) = rq1fac*pc(i)/i
        agamq = rqfac*xpin
        ragq = 1.0e0/agamq
        tesco(2,nq) = ragq
        IF (nq .LT. 12) tesco(1,nqp1) = ragq*rqfac/nqp1
        tesco(3,nqm1) = ragq
 140    CONTINUE
      RETURN
C
 200  pc(1) = 1.0e0
      rq1fac = 1.0e0
      DO 230 nq = 1,5
C-----------------------------------------------------------------------
C The PC array will contain the coefficients of the polynomial
C     p(x) = (x+1)*(x+2)*...*(x+nq).
C Initially, p(x) = 1.
C-----------------------------------------------------------------------
        fnq = nq
        nqp1 = nq + 1
C Form coefficients of p(x)*(x+nq). ------------------------------------
        pc(nqp1) = 0.0e0
        DO 210 ib = 1,nq
          i = nq + 2 - ib
 210      pc(i) = pc(i-1) + fnq*pc(i)
        pc(1) = fnq*pc(1)
C Store coefficients in ELCO and TESCO. --------------------------------
        DO 220 i = 1,nqp1
 220      elco(i,nq) = pc(i)/pc(2)
        elco(2,nq) = 1.0e0
        tesco(1,nq) = rq1fac
        tesco(2,nq) = nqp1/elco(1,nq)
        tesco(3,nq) = (nq+2)/elco(1,nq)
        rq1fac = rq1fac/fnq
 230    CONTINUE
      RETURN
C----------------------- END OF SUBROUTINE SCFODE ----------------------
      END