cbiry.f

Go to the documentation of this file.

      SUBROUTINE cbiry(Z, ID, KODE, BI, IERR)
C***BEGIN PROLOGUE  CBIRY
C***DATE WRITTEN   830501   (YYMMDD)
C***REVISION DATE  890801   (YYMMDD)
C***CATEGORY NO.  B5K
C***KEYWORDS  AIRY FUNCTION,BESSEL FUNCTIONS OF ORDER ONE THIRD
C***AUTHOR  AMOS, DONALD E., SANDIA NATIONAL LABORATORIES
C***PURPOSE  TO COMPUTE AIRY FUNCTIONS BI(Z) AND DBI(Z) FOR COMPLEX Z
C***DESCRIPTION
C
C         ON KODE=1, CBIRY COMPUTES THE COMPLEX AIRY FUNCTION BI(Z) OR
C         ITS DERIVATIVE DBI(Z)/DZ ON ID=0 OR ID=1 RESPECTIVELY. ON
C         KODE=2, A SCALING OPTION CEXP(-AXZTA)*BI(Z) OR CEXP(-AXZTA)*
C         DBI(Z)/DZ IS PROVIDED TO REMOVE THE EXPONENTIAL BEHAVIOR IN
C         BOTH THE LEFT AND RIGHT HALF PLANES WHERE
C         ZTA=(2/3)*Z*CSQRT(Z)=CMPLX(XZTA,YZTA) AND AXZTA=ABS(XZTA).
C         DEFINITIONS AND NOTATION ARE FOUND IN THE NBS HANDBOOK OF
C         MATHEMATICAL FUNCTIONS (REF. 1).
C
C         INPUT
C           Z      - Z=CMPLX(X,Y)
C           ID     - ORDER OF DERIVATIVE, ID=0 OR ID=1
C           KODE   - A PARAMETER TO INDICATE THE SCALING OPTION
C                    KODE= 1  RETURNS
C                             BI=BI(Z)                 ON ID=0 OR
C                             BI=DBI(Z)/DZ             ON ID=1
C                        = 2  RETURNS
C                             BI=CEXP(-AXZTA)*BI(Z)     ON ID=0 OR
C                             BI=CEXP(-AXZTA)*DBI(Z)/DZ ON ID=1 WHERE
C                             ZTA=(2/3)*Z*CSQRT(Z)=CMPLX(XZTA,YZTA)
C                             AND AXZTA=ABS(XZTA)
C
C         OUTPUT
C           BI     - COMPLEX ANSWER DEPENDING ON THE CHOICES FOR ID AND
C                    KODE
C           IERR   - ERROR FLAG
C                    IERR=0, NORMAL RETURN - COMPUTATION COMPLETED
C                    IERR=1, INPUT ERROR   - NO COMPUTATION
C                    IERR=2, OVERFLOW      - NO COMPUTATION, REAL(Z)
C                            TOO LARGE WITH KODE=1
C                    IERR=3, CABS(Z) LARGE      - COMPUTATION COMPLETED
C                            LOSSES OF SIGNIFCANCE BY ARGUMENT REDUCTION
C                            PRODUCE LESS THAN HALF OF MACHINE ACCURACY
C                    IERR=4, CABS(Z) TOO LARGE  - NO COMPUTATION
C                            COMPLETE LOSS OF ACCURACY BY ARGUMENT
C                            REDUCTION
C                    IERR=5, ERROR              - NO COMPUTATION,
C                            ALGORITHM TERMINATION CONDITION NOT MET
C
C***LONG DESCRIPTION
C
C         BI AND DBI ARE COMPUTED FOR CABS(Z).GT.1.0 FROM THE I BESSEL
C         FUNCTIONS BY
C
C                BI(Z)=C*SQRT(Z)*( I(-1/3,ZTA) + I(1/3,ZTA) )
C               DBI(Z)=C *  Z  * ( I(-2/3,ZTA) + I(2/3,ZTA) )
C                               C=1.0/SQRT(3.0)
C                               ZTA=(2/3)*Z**(3/2)
C
C         WITH THE POWER SERIES FOR CABS(Z).LE.1.0.
C
C         IN MOST COMPLEX VARIABLE COMPUTATION, ONE MUST EVALUATE ELE-
C         MENTARY FUNCTIONS. WHEN THE MAGNITUDE OF Z IS LARGE, LOSSES
C         OF SIGNIFICANCE BY ARGUMENT REDUCTION OCCUR. CONSEQUENTLY, IF
C         THE MAGNITUDE OF ZETA=(2/3)*Z**1.5 EXCEEDS U1=SQRT(0.5/UR),
C         THEN LOSSES EXCEEDING HALF PRECISION ARE LIKELY AND AN ERROR
C         FLAG IERR=3 IS TRIGGERED WHERE UR=R1MACH(4)=UNIT ROUNDOFF.
C         ALSO, IF THE MAGNITUDE OF ZETA IS LARGER THAN U2=0.5/UR, THEN
C         ALL SIGNIFICANCE IS LOST AND IERR=4. IN ORDER TO USE THE INT
C         FUNCTION, ZETA MUST BE FURTHER RESTRICTED NOT TO EXCEED THE
C         LARGEST INTEGER, U3=I1MACH(9). THUS, THE MAGNITUDE OF ZETA
C         MUST BE RESTRICTED BY MIN(U2,U3). ON 32 BIT MACHINES, U1,U2,
C         AND U3 ARE APPROXIMATELY 2.0E+3, 4.2E+6, 2.1E+9 IN SINGLE
C         PRECISION ARITHMETIC AND 1.3E+8, 1.8E+16, 2.1E+9 IN DOUBLE
C         PRECISION ARITHMETIC RESPECTIVELY. THIS MAKES U2 AND U3 LIMIT-
C         ING IN THEIR RESPECTIVE ARITHMETICS. THIS MEANS THAT THE MAG-
C         NITUDE OF Z CANNOT EXCEED 3.1E+4 IN SINGLE AND 2.1E+6 IN
C         DOUBLE PRECISION ARITHMETIC. THIS ALSO MEANS THAT ONE CAN
C         EXPECT TO RETAIN, IN THE WORST CASES ON 32 BIT MACHINES,
C         NO DIGITS IN SINGLE PRECISION AND ONLY 7 DIGITS IN DOUBLE
C         PRECISION ARITHMETIC.
C
C         THE APPROXIMATE RELATIVE ERROR IN THE MAGNITUDE OF A COMPLEX
C         BESSEL FUNCTION CAN BE EXPRESSED BY P*10**S WHERE P=MAX(UNIT
C         ROUNDOFF,1.0E-18) IS THE NOMINAL PRECISION AND 10**S REPRE-
C         SENTS THE INCREASE IN ERROR DUE TO ARGUMENT REDUCTION IN THE
C         ELEMENTARY FUNCTIONS. HERE, S=MAX(1,ABS(LOG10(CABS(Z))),
C         ABS(LOG10(FNU))) APPROXIMATELY (I.E. S=MAX(1,ABS(EXPONENT OF
C         CABS(Z),ABS(EXPONENT OF FNU)) ). HOWEVER, THE PHASE ANGLE MAY
C         HAVE ONLY ABSOLUTE ACCURACY. THIS IS MOST LIKELY TO OCCUR WHEN
C         ONE COMPONENT (IN ABSOLUTE VALUE) IS LARGER THAN THE OTHER BY
C         SEVERAL ORDERS OF MAGNITUDE. IF ONE COMPONENT IS 10**K LARGER
C         THAN THE OTHER, THEN ONE CAN EXPECT ONLY MAX(ABS(LOG10(P))-K,
C         0) SIGNIFICANT DIGITS; OR, STATED ANOTHER WAY, WHEN K EXCEEDS
C         THE EXPONENT OF P, NO SIGNIFICANT DIGITS REMAIN IN THE SMALLER
C         COMPONENT. HOWEVER, THE PHASE ANGLE RETAINS ABSOLUTE ACCURACY
C         BECAUSE, IN COMPLEX ARITHMETIC WITH PRECISION P, THE SMALLER
C         COMPONENT WILL NOT (AS A RULE) DECREASE BELOW P TIMES THE
C         MAGNITUDE OF THE LARGER COMPONENT. IN THESE EXTREME CASES,
C         THE PRINCIPAL PHASE ANGLE IS ON THE ORDER OF +P, -P, PI/2-P,
C         OR -PI/2+P.
C
C***REFERENCES  HANDBOOK OF MATHEMATICAL FUNCTIONS BY M. ABRAMOWITZ
C                 AND I. A. STEGUN, NBS AMS SERIES 55, U.S. DEPT. OF
C                 COMMERCE, 1955.
C
C               COMPUTATION OF BESSEL FUNCTIONS OF COMPLEX ARGUMENT
C                 AND LARGE ORDER BY D. E. AMOS, SAND83-0643, MAY, 1983
C
C               A SUBROUTINE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
C                 ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, SAND85-
C                 1018, MAY, 1985
C
C               A PORTABLE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
C                 ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, TRANS.
C                 MATH. SOFTWARE, 1986
C
C***ROUTINES CALLED  CBINU,I1MACH,R1MACH
C***END PROLOGUE  CBIRY
      COMPLEX BI, CONE, CSQ, CY, S1, S2, TRM1, TRM2, Z, ZTA, Z3
      REAL AA, AD, AK, ALIM, ATRM, AZ, AZ3, BB, BK, CK, COEF, C1, C2,
     * dig, dk, d1, d2, elim, fid, fmr, fnu, fnul, pi, rl, r1m5, sfac,
     * tol, tth, zi, zr, z3i, z3r, r1mach
      INTEGER ID, IERR, K, KODE, K1, K2, NZ, I1MACH
      dimension cy(2)
      DATA tth, c1, c2, coef, pi /6.66666666666666667e-01,
     * 6.14926627446000736e-01,4.48288357353826359e-01,
     * 5.77350269189625765e-01,3.14159265358979324e+00/
      DATA  cone / (1.0e0,0.0e0) /
C***FIRST EXECUTABLE STATEMENT  CBIRY
      ierr = 0
      nz=0
      IF (id.LT.0 .OR. id.GT.1) ierr=1
      IF (kode.LT.1 .OR. kode.GT.2) ierr=1
      IF (ierr.NE.0) RETURN
      az = cabs(z)
      tol = amax1(r1mach(4),1.0e-18)
      fid = float(id)
      IF (az.GT.1.0e0) go to 60
C-----------------------------------------------------------------------
C     POWER SERIES FOR CABS(Z).LE.1.
C-----------------------------------------------------------------------
      s1 = cone
      s2 = cone
      IF (az.LT.tol) go to 110
      aa = az*az
      IF (aa.LT.tol/az) go to 40
      trm1 = cone
      trm2 = cone
      atrm = 1.0e0
      z3 = z*z*z
      az3 = az*aa
      ak = 2.0e0 + fid
      bk = 3.0e0 - fid - fid
      ck = 4.0e0 - fid
      dk = 3.0e0 + fid + fid
      d1 = ak*dk
      d2 = bk*ck
      ad = amin1(d1,d2)
      ak = 24.0e0 + 9.0e0*fid
      bk = 30.0e0 - 9.0e0*fid
      z3r = REAL(z3)
      z3i = aimag(z3)
      DO 30 k=1,25
        trm1 = trm1*cmplx(z3r/d1,z3i/d1)
        s1 = s1 + trm1
        trm2 = trm2*cmplx(z3r/d2,z3i/d2)
        s2 = s2 + trm2
        atrm = atrm*az3/ad
        d1 = d1 + ak
        d2 = d2 + bk
        ad = amin1(d1,d2)
        IF (atrm.LT.tol*ad) go to 40
        ak = ak + 18.0e0
        bk = bk + 18.0e0
   30 CONTINUE
   40 CONTINUE
      IF (id.EQ.1) go to 50
      bi = s1*cmplx(c1,0.0e0) + z*s2*cmplx(c2,0.0e0)
      IF (kode.EQ.1) RETURN
      zta = z*csqrt(z)*cmplx(tth,0.0e0)
      aa = REAL(zta)
      aa = -abs(aa)
      bi = bi*cmplx(exp(aa),0.0e0)
      RETURN
   50 CONTINUE
      bi = s2*cmplx(c2,0.0e0)
      IF (az.GT.tol) bi = bi + z*z*s1*cmplx(c1/(1.0e0+fid),0.0e0)
      IF (kode.EQ.1) RETURN
      zta = z*csqrt(z)*cmplx(tth,0.0e0)
      aa = REAL(zta)
      aa = -abs(aa)
      bi = bi*cmplx(exp(aa),0.0e0)
      RETURN
C-----------------------------------------------------------------------
C     CASE FOR CABS(Z).GT.1.0
C-----------------------------------------------------------------------
   60 CONTINUE
      fnu = (1.0e0+fid)/3.0e0
C-----------------------------------------------------------------------
C     SET PARAMETERS RELATED TO MACHINE CONSTANTS.
C     TOL IS THE APPROXIMATE UNIT ROUNDOFF LIMITED TO 1.0E-18.
C     ELIM IS THE APPROXIMATE EXPONENTIAL OVER- AND UNDERFLOW LIMIT.
C     EXP(-ELIM).LT.EXP(-ALIM)=EXP(-ELIM)/TOL    AND
C     EXP(ELIM).GT.EXP(ALIM)=EXP(ELIM)*TOL       ARE INTERVALS NEAR
C     UNDERFLOW AND OVERFLOW LIMITS WHERE SCALED ARITHMETIC IS DONE.
C     RL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC EXPANSION FOR LARGE Z.
C     DIG = NUMBER OF BASE 10 DIGITS IN TOL = 10**(-DIG).
C     FNUL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC SERIES FOR LARGE FNU.
C-----------------------------------------------------------------------
      k1 = i1mach(12)
      k2 = i1mach(13)
      r1m5 = r1mach(5)
      k = min0(iabs(k1),iabs(k2))
      elim = 2.303e0*(float(k)*r1m5-3.0e0)
      k1 = i1mach(11) - 1
      aa = r1m5*float(k1)
      dig = amin1(aa,18.0e0)
      aa = aa*2.303e0
      alim = elim + amax1(-aa,-41.45e0)
      rl = 1.2e0*dig + 3.0e0
      fnul = 10.0e0 + 6.0e0*(dig-3.0e0)
C-----------------------------------------------------------------------
C     TEST FOR RANGE
C-----------------------------------------------------------------------
      aa=0.5e0/tol
      bb=float(i1mach(9))*0.5e0
      aa=amin1(aa,bb)
      aa=aa**tth
      IF (az.GT.aa) go to 190
      aa=sqrt(aa)
      IF (az.GT.aa) ierr=3
      csq=csqrt(z)
      zta=z*csq*cmplx(tth,0.0e0)
C-----------------------------------------------------------------------
C     RE(ZTA).LE.0 WHEN RE(Z).LT.0, ESPECIALLY WHEN IM(Z) IS SMALL
C-----------------------------------------------------------------------
      sfac = 1.0e0
      zi = aimag(z)
      zr = REAL(z)
      ak = aimag(zta)
      IF (zr.GE.0.0e0) go to 70
      bk = REAL(zta)
      ck = -abs(bk)
      zta = cmplx(ck,ak)
   70 CONTINUE
      IF (zi.EQ.0.0e0 .AND. zr.LE.0.0e0) zta = cmplx(0.0e0,ak)
      aa = REAL(zta)
      IF (kode.EQ.2) go to 80
C-----------------------------------------------------------------------
C     OVERFLOW TEST
C-----------------------------------------------------------------------
      bb = abs(aa)
      IF (bb.LT.alim) go to 80
      bb = bb + 0.25e0*alog(az)
      sfac = tol
      IF (bb.GT.elim) go to 170
   80 CONTINUE
      fmr = 0.0e0
      IF (aa.GE.0.0e0 .AND. zr.GT.0.0e0) go to 90
      fmr = pi
      IF (zi.LT.0.0e0) fmr = -pi
      zta = -zta
   90 CONTINUE
C-----------------------------------------------------------------------
C     AA=FACTOR FOR ANALYTIC CONTINUATION OF I(FNU,ZTA)
C     KODE=2 RETURNS EXP(-ABS(XZTA))*I(FNU,ZTA) FROM CBINU
C-----------------------------------------------------------------------
      CALL cbinu(zta, fnu, kode, 1, cy, nz, rl, fnul, tol, elim, alim)
      IF (nz.LT.0) go to 180
      aa = fmr*fnu
      z3 = cmplx(sfac,0.0e0)
      s1 = cy(1)*cmplx(cos(aa),sin(aa))*z3
      fnu = (2.0e0-fid)/3.0e0
      CALL cbinu(zta, fnu, kode, 2, cy, nz, rl, fnul, tol, elim, alim)
      cy(1) = cy(1)*z3
      cy(2) = cy(2)*z3
C-----------------------------------------------------------------------
C     BACKWARD RECUR ONE STEP FOR ORDERS -1/3 OR -2/3
C-----------------------------------------------------------------------
      s2 = cy(1)*cmplx(fnu+fnu,0.0e0)/zta + cy(2)
      aa = fmr*(fnu-1.0e0)
      s1 = (s1+s2*cmplx(cos(aa),sin(aa)))*cmplx(coef,0.0e0)
      IF (id.EQ.1) go to 100
      s1 = csq*s1
      bi = s1*cmplx(1.0e0/sfac,0.0e0)
      RETURN
  100 CONTINUE
      s1 = z*s1
      bi = s1*cmplx(1.0e0/sfac,0.0e0)
      RETURN
  110 CONTINUE
      aa = c1*(1.0e0-fid) + fid*c2
      bi = cmplx(aa,0.0e0)
      RETURN
  170 CONTINUE
      nz=0
      ierr=2
      RETURN
  180 CONTINUE
      IF(nz.EQ.(-1)) go to 170
      nz=0
      ierr=5
      RETURN
  190 CONTINUE
      ierr=4
      nz=0
      RETURN
      END