asinh.f

Go to the documentation of this file.

*DECK ASINH
      FUNCTION asinh (X)
C***BEGIN PROLOGUE  ASINH
C***PURPOSE  Compute the arc hyperbolic sine.
C***LIBRARY   SLATEC (FNLIB)
C***CATEGORY  C4C
C***TYPE      SINGLE PRECISION (ASINH-S, DASINH-D, CASINH-C)
C***KEYWORDS  ARC HYPERBOLIC SINE, ASINH, ELEMENTARY FUNCTIONS, FNLIB,
C             INVERSE HYPERBOLIC SINE
C***AUTHOR  Fullerton, W., (LANL)
C***DESCRIPTION
C
C ASINH(X) computes the arc hyperbolic sine of X.
C
C Series for ASNH       on the interval  0.          to  1.00000D+00
C                                        with weighted error   2.19E-17
C                                         log weighted error  16.66
C                               significant figures required  15.60
C                                    decimal places required  17.31
C
C***REFERENCES  (NONE)
C***ROUTINES CALLED  CSEVL, INITS, R1MACH
C***REVISION HISTORY  (YYMMDD)
C   770401  DATE WRITTEN
C   890531  Changed all specific intrinsics to generic.  (WRB)
C   890531  REVISION DATE from Version 3.2
C   891214  Prologue converted to Version 4.0 format.  (BAB)
C***END PROLOGUE  ASINH
      dimension asnhcs(20)
      LOGICAL FIRST
      SAVE aln2, asnhcs, nterms, xmax, sqeps, first
      DATA aln2 /0.6931471805 5994530942e0/
      DATA asnhcs( 1) /   -.1282003991 1738186e0 /
      DATA asnhcs( 2) /   -.0588117611 89951768e0 /
      DATA asnhcs( 3) /    .0047274654 32212481e0 /
      DATA asnhcs( 4) /   -.0004938363 16265361e0 /
      DATA asnhcs( 5) /    .0000585062 07058557e0 /
      DATA asnhcs( 6) /   -.0000074669 98328931e0 /
      DATA asnhcs( 7) /    .0000010011 69358355e0 /
      DATA asnhcs( 8) /   -.0000001390 35438587e0 /
      DATA asnhcs( 9) /    .0000000198 23169483e0 /
      DATA asnhcs(10) /   -.0000000028 84746841e0 /
      DATA asnhcs(11) /    .0000000004 26729654e0 /
      DATA asnhcs(12) /   -.0000000000 63976084e0 /
      DATA asnhcs(13) /    .0000000000 09699168e0 /
      DATA asnhcs(14) /   -.0000000000 01484427e0 /
      DATA asnhcs(15) /    .0000000000 00229037e0 /
      DATA asnhcs(16) /   -.0000000000 00035588e0 /
      DATA asnhcs(17) /    .0000000000 00005563e0 /
      DATA asnhcs(18) /   -.0000000000 00000874e0 /
      DATA asnhcs(19) /    .0000000000 00000138e0 /
      DATA asnhcs(20) /   -.0000000000 00000021e0 /
      DATA first /.true./
C***FIRST EXECUTABLE STATEMENT  ASINH
      IF (first) THEN
         nterms = inits(asnhcs, 20, 0.1*r1mach(3))
         sqeps = sqrt(r1mach(3))
         xmax = 1.0/sqeps
      ENDIF
      first = .false.
C
      y = abs(x)
      IF (y.GT.1.0) go to 20
C
      asinh = x
      IF (y.GT.sqeps) asinh = x*(1.0 + csevl(2.*x*x-1., asnhcs,nterms))
      RETURN
C
 20   IF (y.LT.xmax) asinh = log(y + sqrt(y**2+1.))
      IF (y.GE.xmax) asinh = aln2 + log(y)
      asinh = sign(asinh, x)
C
      RETURN
      END