real function cqrt17	(	character	TRANS,
		integer	IRESID,
		integer	M,
		integer	N,
		integer	NRHS,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldx, * )	X,
		integer	LDX,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		complex, dimension( ldb, * )	C,
		complex, dimension( lwork )	WORK,
		integer	LWORK
	)

CQRT17

Purpose:

 CQRT17 computes the ratio

    || R'*op(A) ||/(||A||*alpha*max(M,N,NRHS)*eps)

 where R = op(A)*X - B, op(A) is A or A', and

    alpha = ||B|| if IRESID = 1 (zero-residual problem)
    alpha = ||R|| if IRESID = 2 (otherwise).

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies whether or not the transpose of A is used. = 'N': No transpose, op(A) = A. = 'C': Conjugate transpose, op(A) = A'.
[in]	IRESID	IRESID is INTEGER IRESID = 1 indicates zero-residual problem. IRESID = 2 indicates non-zero residual.
[in]	M	M is INTEGER The number of rows of the matrix A. If TRANS = 'N', the number of rows of the matrix B. If TRANS = 'C', the number of rows of the matrix X.
[in]	N	N is INTEGER The number of columns of the matrix A. If TRANS = 'N', the number of rows of the matrix X. If TRANS = 'C', the number of rows of the matrix B.
[in]	NRHS	NRHS is INTEGER The number of columns of the matrices X and B.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= M.
[in]	X	X is COMPLEX array, dimension (LDX,NRHS) If TRANS = 'N', the n-by-nrhs matrix X. If TRANS = 'C', the m-by-nrhs matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= N. If TRANS = 'C', LDX >= M.
[in]	B	B is COMPLEX array, dimension (LDB,NRHS) If TRANS = 'N', the m-by-nrhs matrix B. If TRANS = 'C', the n-by-nrhs matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. If TRANS = 'N', LDB >= M. If TRANS = 'C', LDB >= N.
[out]	C	C is COMPLEX array, dimension (LDB,NRHS)
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= NRHS*(M+N).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 152 of file cqrt17.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            iresid, lda, ldb, ldx, lwork, m, n, nrhs
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), b( ldb, * ), c( ldb, * ),
     $                   work( lwork ), x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, iscl, ncols, nrows
      REAL               bignum, err, norma, normb, normrs, smlnum
*     ..
*     .. Local Arrays ..
      REAL               rwork( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clange, slamch
      EXTERNAL           lsame, clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, clascl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Executable Statements ..
*
      cqrt17 = zero
*
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
      ELSE IF( lsame( trans, 'C' ) ) THEN
         nrows = n
         ncols = m
      ELSE
         CALL xerbla( 'CQRT17', 1 )
         RETURN
      END IF
*
      IF( lwork.LT.ncols*nrhs ) THEN
         CALL xerbla( 'CQRT17', 13 )
         RETURN
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 )
     $   RETURN
*
      norma = clange( 'One-norm', m, n, a, lda, rwork )
      smlnum = slamch( 'Safe minimum' ) / slamch( 'Precision' )
      bignum = one / smlnum
      iscl = 0
*
*     compute residual and scale it
*
      CALL clacpy( 'All', nrows, nrhs, b, ldb, c, ldb )
      CALL cgemm( trans, 'No transpose', nrows, nrhs, ncols,
     $            cmplx( -one ), a, lda, x, ldx, cmplx( one ), c, ldb )
      normrs = clange( 'Max', nrows, nrhs, c, ldb, rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL clascl( 'General', 0, 0, normrs, one, nrows, nrhs, c, ldb,
     $                info )
      END IF
*
*     compute R'*A
*
      CALL cgemm( 'Conjugate transpose', trans, nrhs, ncols, nrows,
     $            cmplx( one ), c, ldb, a, lda, cmplx( zero ), work,
     $            nrhs )
*
*     compute and properly scale error
*
      err = clange( 'One-norm', nrhs, ncols, work, nrhs, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = clange( 'One-norm', nrows, nrhs, b, ldb, rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         IF( normrs.NE.zero )
     $      err = err / normrs
      END IF
*
      cqrt17 = err / ( slamch( 'Epsilon' )*REAL( MAX( M, N, NRHS ) ) )
      RETURN
*
*     End of CQRT17
*

Here is the call graph for this function: