subroutine csyt01_3	(	character	UPLO,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldafac, * )	AFAC,
		integer	LDAFAC,
		complex, dimension( * )	E,
		integer, dimension( * )	IPIV,
		complex, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( * )	RWORK,
		real	RESID
	)

CSYT01_3

Purpose:

 CSYT01_3 reconstructs a symmetric indefinite matrix A from its
 block L*D*L' or U*D*U' factorization computed by CSYTRF_RK
 (or CSYTRF_BK) and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix and EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The original symmetric matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N)
[in]	AFAC	AFAC is COMPLEX array, dimension (LDAFAC,N) Diagonal of the block diagonal matrix D and factors U or L as computed by CSYTRF_RK and CSYTRF_BK: a) ONLY diagonal elements of the symmetric block diagonal matrix D on the diagonal of A, i.e. D(k,k) = A(k,k); (superdiagonal (or subdiagonal) elements of D should be provided on entry in array E), and b) If UPLO = 'U': factor U in the superdiagonal part of A. If UPLO = 'L': factor L in the subdiagonal part of A.
[in]	LDAFAC	LDAFAC is INTEGER The leading dimension of the array AFAC. LDAFAC >= max(1,N).
[in]	E	E is COMPLEX array, dimension (N) On entry, contains the superdiagonal (or subdiagonal) elements of the symmetric block diagonal matrix D with 1-by-1 or 2-by-2 diagonal blocks, where If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not refernced; If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced.
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from CSYTRF_RK (or CSYTRF_BK).
[out]	C	C is COMPLEX array, dimension (LDC,N)
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESID	RESID is REAL If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 143 of file csyt01_3.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, ldc, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      REAL               rwork( * )
      COMPLEX            a( lda, * ), afac( ldafac, * ), c( ldc, * ),
     $                   e( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            czero, cone
      parameter                ( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
      REAL               anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               slamch, clansy
      EXTERNAL           lsame, slamch, clansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           claset, clavsy_rook, csyconvf_rook
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     a) Revert to multiplyers of L
*
      CALL csyconvf_rook( uplo, 'R', n, afac, ldafac, e, ipiv, info )
*
*     1) Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clansy( '1', uplo, n, a, lda, rwork )
*
*     2) Initialize C to the identity matrix.
*
      CALL claset( 'Full', n, n, czero, cone, c, ldc )
*
*     3) Call ZLAVSY_ROOK to form the product D * U' (or D * L' ).
*
      CALL clavsy_rook( uplo, 'Transpose', 'Non-unit', n, n, afac,
     $                  ldafac, ipiv, c, ldc, info )
*
*     4) Call ZLAVSY_ROOK again to multiply by U (or L ).
*
      CALL clavsy_rook( uplo, 'No transpose', 'Unit', n, n, afac,
     $                  ldafac, ipiv, c, ldc, info )
*
*     5) Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO j = 1, n
            DO i = 1, j
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      ELSE
         DO j = 1, n
            DO i = j, n
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      END IF
*
*     6) Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clansy( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / REAL( N ) ) / anorm ) / eps
      END IF

*
*     b) Convert to factor of L (or U)
*
      CALL csyconvf_rook( uplo, 'C', n, afac, ldafac, e, ipiv, info )
*
      RETURN
*
*     End of CSYT01_3
*

Here is the call graph for this function:

Here is the caller graph for this function: