chetrs_aa.f

Go to the documentation of this file.

*> \brief \b CHETRS_AA
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CHETRS_AA + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chetrs_aa.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chetrs_aa.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chetrs_aa.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHETRS_AA( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
*                             WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            N, NRHS, LDA, LDB, LWORK, INFO
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CHETRS_AA solves a system of linear equations A*X = B with a complex
*> hermitian matrix A using the factorization A = U*T*U**H or
*> A = L*T*L**H computed by CHETRF_AA.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U*T*U**H;
*>          = 'L':  Lower triangular, form is A = L*T*L**H.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          Details of factors computed by CHETRF_AA.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges as computed by CHETRF_AA.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in] WORK
*> \verbatim
*>          WORK is DOUBLE array, dimension (MAX(1,LWORK))
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER, LWORK >= MAX(1,3*N-2).
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup complexHEcomputational
*
*  =====================================================================
      SUBROUTINE chetrs_aa( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
     $                      work, lwork, info )
*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N, NRHS, LDA, LDB, LWORK, INFO
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( lda, * ), B( ldb, * ), WORK( * )
*     ..
*
*  =====================================================================
*
      COMPLEX            ONE
      parameter                ( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      INTEGER            K, KP, LWKOPT
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgtsv, cswap, ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      lquery = ( lwork.EQ.-1 )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.max( 1, 3*n-2 ) .AND. .NOT.lquery ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHETRS_AA', -info )
         RETURN
      ELSE IF( lquery ) THEN
         lwkopt = (3*n-2)
         work( 1 ) = lwkopt
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U*T*U**T.
*
*        P**T * B
*
         k = 1
         DO WHILE ( k.LE.n )
            kp = ipiv( k )
            IF( kp.NE.k )
     $          CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k + 1
         END DO
*
*        Compute (U \P**T * B) -> B    [ (U \P**T * B) ]
*
         CALL ctrsm('L', 'U', 'C', 'U', n-1, nrhs, one, a( 1, 2 ), lda,
     $               b( 2, 1 ), ldb)
*
*        Compute T \ B -> B   [ T \ (U \P**T * B) ]
*
         CALL clacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1)
         IF( n.GT.1 ) THEN
             CALL clacpy( 'F', 1, n-1, a( 1, 2 ), lda+1, work( 2*n ), 1)
             CALL clacpy( 'F', 1, n-1, a( 1, 2 ), lda+1, work( 1 ), 1)
             CALL clacgv( n-1, work( 1 ), 1 )
         END IF
         CALL cgtsv(n, nrhs, work(1), work(n), work(2*n), b, ldb,
     $              info)
*
*        Compute (U**T \ B) -> B   [ U**T \ (T \ (U \P**T * B) ) ]
*
         CALL ctrsm( 'L', 'U', 'N', 'U', n-1, nrhs, one, a( 1, 2 ), lda,
     $               b(2, 1), ldb)
*
*        Pivot, P * B  [ P * (U**T \ (T \ (U \P**T * B) )) ]
*
         k = n
         DO WHILE ( k.GE.1 )
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k - 1
         END DO
*
      ELSE
*
*        Solve A*X = B, where A = L*T*L**T.
*
*        Pivot, P**T * B
*
         k = 1
         DO WHILE ( k.LE.n )
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k + 1
         END DO
*
*        Compute (L \P**T * B) -> B    [ (L \P**T * B) ]
*
         CALL ctrsm( 'L', 'L', 'N', 'U', n-1, nrhs, one, a( 2, 1), lda,
     $               b(2, 1), ldb)
*
*        Compute T \ B -> B   [ T \ (L \P**T * B) ]
*
         CALL clacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1)
         IF( n.GT.1 ) THEN
             CALL clacpy( 'F', 1, n-1, a( 2, 1 ), lda+1, work( 1 ), 1)
             CALL clacpy( 'F', 1, n-1, a( 2, 1 ), lda+1, work( 2*n ), 1)
             CALL clacgv( n-1, work( 2*n ), 1 )
         END IF
         CALL cgtsv(n, nrhs, work(1), work(n), work(2*n), b, ldb,
     $              info)
*
*        Compute (L**T \ B) -> B   [ L**T \ (T \ (L \P**T * B) ) ]
*
         CALL ctrsm( 'L', 'L', 'C', 'U', n-1, nrhs, one, a( 2, 1 ), lda,
     $              b( 2, 1 ), ldb)
*
*        Pivot, P * B  [ P * (L**T \ (T \ (L \P**T * B) )) ]
*
         k = n
         DO WHILE ( k.GE.1 )
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k - 1
         END DO
*
      END IF
*
      RETURN
*
*     End of CHETRS_AA
*
      END