24.5. 从 Oracle 的 PL/SQL 向 PL/pgSQL移植

Example 24-5. 一个简单的函数

下面是一个 Oracle 函数∶

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW ERRORS;

让我们读一遍这个函数然后看看 PL/pgSQL 与之的不同∶

• 不允许 OR REPLACE 子句．你必须在创建函数之前 明确地删除它才能获得类似的行为．

• PostgreSQL 没有命名的参数． 你必须在自己的函数中明确地给它们取个别名．

• Oracle 可以有 IN，OUT， 和 INOUT 参数传递给函数．比如， INOUT 的意思是该参数将接受一个数值并且返回 另外一个．PostgreSQL 只有 “IN” 参数并且函数只能 返回一个数值．

• 在函数原型里的 RETURN(不是函数体里的) 关键字到了 PostgreSQL 里就是RETURNS．

• 在 PostgreSQL 里，函数是使用单引号做为分隔符创建的， 因此你必须在你的函数里逃逸单引号(有时候会相当麻烦；参阅 Section 24.5.1.1)．

• 在 PostgreSQL 里没有 /show errors 命令．

现在让我们看看移植到 PostgreSQL 之后这个函数是什么样子∶

DROP FUNCTION cs_fmt_browser_version(varchar, varchar);
CREATE FUNCTION cs_fmt_browser_version(varchar, varchar)
RETRUNS varchar AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        return v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE 'plpgsql';

Example 24-6. 一个创建其它函数的函数

下面的过程从一个 SELECT 语句中抓取 若干行，然后为了提高效率，又用 IF 语句中的 结果制作了一个巨大的函数． 请特别注意在 PostgreSQL 里游标，FOR 循环和需要逃逸的 单引号的区别．

create or replace procedure cs_update_referrer_type_proc is 
    cursor referrer_keys is 
        select * from cs_referrer_keys 
        order by try_order;

    a_output varchar(4000); 
begin 
    a_output := 'create or replace function cs_find_referrer_type(v_host IN varchar, v_domain IN varchar, 
v_url IN varchar) return varchar is begin'; 

    for referrer_key in referrer_keys loop 
        a_output := a_output || ' if v_' || referrer_key.kind || ' like ''' || 
referrer_key.key_string || ''' then return ''' || referrer_key.referrer_type || 
'''; end if;'; 
    end loop; 

    a_output := a_output || ' return null; end;'; 
    execute immediate a_output; 
end; 
/ 
show errors

下面是这个函数在 PostgreSQL 里面的样子∶

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS integer AS '
DECLARE
    referrer_keys RECORD;  -- 声明一个在 FOR 里用的通用的记录
    a_output varchar(4000);
BEGIN 
    a_output := ''CREATE FUNCTION cs_find_referrer_type(varchar,varchar,varchar) 
                  RETURNS varchar AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3; ''; 

    -- 
    -- 请注意我们是如何在一个 FOR 循环中使用 FOR <record> 构造
    -- 扫描各条结果的
    --

    FOR referrer_keys IN select * from cs_referrer_keys order by try_order LOOP
        a_output := a_output || '' if v_'' || referrer_keys.kind || '' like '''''''''' 
                 || referrer_keys.key_string || '''''''''' then return '''''' 
                 || referrer_keys.referrer_type || ''''''; end if;''; 
    END LOOP; 
  
    a_output := a_output || '' return null; end; '''' language ''''plpgsql'''';''; 
 
    -- 这样是可以运行的原因是因为我们没有代换任何变量
    -- 否则它可就不能玩了．请查阅 PERFORM 获取另外一种运行函数的方法
    
    EXECUTE a_output; 
end; 
' LANGUAGE 'plpgsql';

Example 24-7. 一个有许多字串操作和 OUT 参数的过程

下面的 Oracle PL/SQL 过程用于分析一个 URL 并且返回若干个元素 (主机，路径和查询)．它是一个过程是因为在 PL/pgSQL 函数里， 只有一个函数可以返回(参阅 Section 24.5.3)．在 PostgreSQL 里， 一个绕开这个局限的方法就是把过程分裂成三个不同的函数∶ 一个返回主机，另外一个返回路径，最后一个返回查询．

create or replace procedure cs_parse_url(
    v_url IN varchar,
    v_host OUT varchar,  -- 这个变量是要传回的
    v_path OUT varchar,  -- 这个也是
    v_query OUT varchar) -- 还有这个
is
    a_pos1 integer;
    a_pos2 integer;
begin
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); -- PostgreSQL 没有 instr 函数

    if a_pos1 = 0 then
        return;
    end if;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    if a_pos2 = 0 then
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        return;
    end if;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    if a_pos1 = 0 then
        v_path := substr(v_url, a_pos2);
        return;
    end if;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
end;
/
show errors;

下面就是把这个过程翻译成 PostgreSQL 的样子∶

drop function cs_parse_url_host(varchar); 
create function cs_parse_url_host(varchar) returns varchar as ' 
declare 
    v_url ALIAS FOR $1; 
    v_host varchar; 
    v_path varchar; 
    a_pos1 integer; 
    a_pos2 integer; 
    a_pos3 integer; 
begin 
    v_host := NULL; 
    a_pos1 := instr(v_url,''//''); 

    if a_pos1 = 0 then 
        return '''';  -- 返回一个空
    end if; 

    a_pos2 := instr(v_url,''/'',a_pos1 + 2); 
    if a_pos2 = 0 then 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        return v_host; 
    end if; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    return v_host; 
end; 
' language 'plpgsql';