Home · All Namespaces · All Classes · Main Classes · Grouped Classes · Modules · Functions

[Previous: qmake Reference] [Contents] [Next: qmake Function Reference]

qmake Variable Reference

qmake's fundamental behavior is influenced by variable declarations that define the build process of each project. Some of these declare resources, such as headers and source files, that are common to each platform; others are used to customize the behavior of compilers and linkers on specific platforms.

Platform-specific variables follow the naming pattern of the variables which they extend or modify, but include the name of the relevant platform in their name. For example, QMAKE_LIBS can be used to specify a list of libraries that a project needs to link against, and QMAKE_LIBS_X11 can be used to extend or override this list.

CONFIG

The CONFIG variable specifies project configuration and compiler options. The values will be recognized internally by qmake and have special meaning. They are as follows.

These CONFIG values control compilation flags:

Since the debug option overrides the release option when both are defined in the CONFIG variable, it is necessary to use the debug_and_release option if you want to allow both debug and release versions of a project to be built. In such a case, the Makefile that qmake generates includes a rule that builds both versions, and this can be invoked in the following way:

 make all

On Windows (or if Qt is configured with -debug_and_release, adding the build_all option to the CONFIG variable makes this rule the default when building the project, and installation targets will be created for both debug and release builds.

Additionally, adding debug_and_release to the CONFIG variable will cause both debug and release to be defined in the contents of CONFIG. When the project file is processed, the scopes that test for each value will be processed for both debug and release modes. The build_pass variable will be set for each of these mode, and you can test for this to perform build-specific tasks. For example:

 build_pass:CONFIG(debug, debug|release) {
     unix: TARGET = $$join(TARGET,,,_debug)
     else: TARGET = $$join(TARGET,,,d)
 }

As a result, it may be useful to define mode-specific variables, such as QMAKE_LFLAGS_RELEASE, instead of general variables, such as QMAKE_LFLAGS, where possible.

The following options define the application/library type:

These options are used to set the compiler flags:

These options define specific features on Windows only:

See qmake Platform Notes for more information on the options for embedding manifest files.

These options only have an effect on Mac OS X:

The build process for bundles is also influenced by the contents of the QMAKE_BUNDLE_DATA variable.

These options have an effect on Linux/Unix platforms:

The CONFIG variable will also be checked when resolving scopes. You may assign anything to this variable.

For example:

 CONFIG += qt console newstuff
 ...
 newstuff {
     SOURCES += new.cpp
     HEADERS += new.h
 }

DEFINES

qmake adds the values of this variable as compiler C preprocessor macros (-D option).

For example:

 DEFINES += USE_MY_STUFF QT_DLL

DEF_FILE

This is only used on Windows when using the app template.

Specifies a .def file to be included in the project.

DEPENDPATH

This variable contains the list of all directories to look in to resolve dependencies. This will be used when crawling through included files.

DEPLOYMENT

This is only used on Windows CE.

Specifies which additional files will be deployed. Deployment means the transfer of files from the development system to the target device or emulator.

Files can be deployed by either creating a Visual Studio project or using the cetest executable.

For example:

 myFiles.sources = path\*.png
 DEPLOYMENT += myFiles

This will upload all PNG images in path to the same directory your build target will be deployed to.

The default deployment target path for Windows CE is %CSIDL_PROGRAM_FILES%\target, which usually gets expanded to \Program Files\target.

It is also possible to specify multiple sources to be deployed on target paths. In addition, different variables can be used for deployment to different directories.

For example:

 myFiles.sources = path\file1.ext1 path2\file2.ext1 path3\*
 myFiles.path = \some\path\on\device
 someother.sources = C:\additional\files\*
 someother.path = \myFiles\path2
 DEPLOYMENT += myFiles someother

Note: All linked Qt libraries will be deployed to the path specified by myFiles.path.

DEPLOYMENT_PLUGIN

This is only used on Windows CE.

This variable specifies the Qt plugins that will be deployed. All plugins available in Qt can be explicitly deployed to the device. See Static Plugins for a complete list.

Note: No plugins will be deployed automatically. If the application depends on plugins, these plugins have to be specified manually.

For example:

 DEPLOYMENT_PLUGIN += qjpeg

This will upload the jpeg imageformat plugin to the plugins directory on the Windows CE device.

DESTDIR

Specifies where to put the target file.

For example:

 DESTDIR = ../../lib

DESTDIR_TARGET

This variable is set internally by qmake, which is basically the DESTDIR variable with the TARGET variable appened at the end. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

DLLDESTDIR

Specifies where to copy the target dll.

DISTFILES

This variable contains a list of files to be included in the dist target. This feature is supported by UnixMake specs only.

For example:

 DISTFILES += ../program.txt

DSP_TEMPLATE

This variable is set internally by qmake, which specifies where the dsp template file for basing generated dsp files is stored. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

FORMS

This variable specifies the .ui files (see Qt Designer) to be processed through uic before compiling. All dependencies, headers and source files required to build these .ui files will automatically be added to the project.

For example:

 FORMS = mydialog.ui \
     mywidget.ui \
         myconfig.ui

If FORMS3 is defined in your project, then this variable must contain forms for uic, and not uic3. If CONFIG contains uic3, and FORMS3 is not defined, the this variable must contain only uic3 type forms.

FORMS3

This variable specifies the old style .ui files to be processed through uic3 before compiling, when CONFIG contains uic3. All dependencies, headers and source files required to build these .ui files will automatically be added to the project.

For example:

 FORMS3 = my_uic3_dialog.ui \
      my_uic3_widget.ui \
          my_uic3_config.ui

GUID

Specifies the GUID that is set inside a .vcproj file. The GUID is usually randomly determined. However, should you require a fixed GUID, it can be set using this variable.

This variable is specific to .vcproj files only; it is ignored otherwise.

HEADERS

Defines the header files for the project.

qmake will generate dependency information (unless -nodepend is specified on the command line) for the specified headers. qmake will also automatically detect if moc is required by the classes in these headers, and add the appropriate dependencies and files to the project for generating and linking the moc files.

For example:

 HEADERS = myclass.h \
           login.h \
           mainwindow.h

See also SOURCES.

INCLUDEPATH

This variable specifies the #include directories which should be searched when compiling the project. Use ';' or a space as the directory separator.

For example:

 INCLUDEPATH = c:/msdev/include d:/stl/include

INSTALLS

This variable contains a list of resources that will be installed when make install or a similar installation procedure is executed. Each item in the list is typically defined with attributes that provide information about where it will be installed.

For example, the following target.path definition describes where the build target will be installed, and the INSTALLS assignment adds the build target to the list of existing resources to be installed:

 target.path += $$[QT_INSTALL_PLUGINS]/imageformats
 INSTALLS += target

LEXIMPLS

This variable contains a list of lex implementation files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

LEXOBJECTS

This variable contains the names of intermediate lex object files.The value of this variable is typically handled by qmake and rarely needs to be modified.

LEXSOURCES

This variable contains a list of lex source files. All dependencies, headers and source files will automatically be added to the project for building these lex files.

For example:

 LEXSOURCES = lexer.l

LIBS

This variable contains a list of libraries to be linked into the project. You can use the Unix -l (library) and -L (library path) flags and qmake will do the correct thing with these libraries on Windows (namely this means passing the full path of the library to the linker). The only limitation to this is the library must exist, for qmake to find which directory a -l lib lives in.

For example:

 unix:LIBS += -L/usr/local/lib -lmath
 win32:LIBS += c:/mylibs/math.lib

Note: On Windows, specifying libraries with the -l option, as in the above example, will cause the library with the highest version number to be used; for example, libmath2.lib could potentially be used instead of libmathlib. To avoid this ambiguity, we recommend that you explicitly specify the library to be used by including the .lib file name suffix.

By default, the list of libraries stored in LIBS is reduced to a list of unique names before it is used. To change this behavior, add the no_lflags_merge option to the CONFIG variable:

 CONFIG += no_lflags_merge

LITERAL_HASH

This variable is used whenever a literal hash character (#) is needed in a variable declaration, perhaps as part of a file name or in a string passed to some external application.

For example:

 # To include a literal hash character, use the $$LITERAL_HASH variable:
 urlPieces = http://doc.trolltech.com/4.0/qtextdocument.html pageCount
 message($$join(urlPieces, $$LITERAL_HASH))

By using LITERAL_HASH in this way, the # character can be used to construct a URL for the message() function to print to the console.

MAKEFILE

This variable specifies the name of the Makefile which qmake should use when outputting the dependency information for building a project. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

MAKEFILE_GENERATOR

This variable contains the name of the Makefile generator to use when generating a Makefile. The value of this variable is typically handled internally by qmake and rarely needs to be modified.

MOC_DIR

This variable specifies the directory where all intermediate moc files should be placed.

For example:

 unix:MOC_DIR = ../myproject/tmp
 win32:MOC_DIR = c:/myproject/tmp

OBJECTS

This variable is generated from the SOURCES variable. The extension of each source file will have been replaced by .o (Unix) or .obj (Win32). The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

OBJECTS_DIR

This variable specifies the directory where all intermediate objects should be placed.

For example:

 unix:OBJECTS_DIR = ../myproject/tmp
 win32:OBJECTS_DIR = c:/myproject/tmp

OBJMOC

This variable is set by qmake if files can be found that contain the Q_OBJECT macro. OBJMOC contains the name of all intermediate moc object files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

POST_TARGETDEPS

All libraries that the target depends on can be listed in this variable. Some backends do not support this, these include MSVC Dsp, and ProjectBuilder .pbproj files. Generally this is supported internally by these build tools, this is useful for explicitly listing dependant static libraries.

This list will go after all builtin (and $$PRE_TARGETDEPS) dependencies.

PRE_TARGETDEPS

All libraries that the target depends on can be listed in this variable. Some backends do not support this, these include MSVC Dsp, and ProjectBuilder .pbproj files. Generally this is supported internally by these build tools, this is useful for explicitly listing dependant static libraries.

This list will go before all builtin dependencies.

PRECOMPILED_HEADER

This variable indicates the header file for creating a precompiled header file, to increase the compilation speed of a project. Precompiled headers are currently only supported on some platforms (Windows - all MSVC project types, Mac OS X - Xcode, Makefile, Unix - gcc 3.3 and up).

On other platforms, this variable has different meaning, as noted below.

This variable contains a list of header files that require some sort of pre-compilation step (such as with moc). The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

PWD

This variable contains the full path leading to the directory where the qmake project file (project.pro) is located.

OUT_PWD

This variable contains the full path leading to the directory where qmake places the generated Makefile.

QMAKE

This variable contains the name of the qmake program itself and is placed in generated Makefiles. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKESPEC

This variable contains the name of the qmake configuration to use when generating Makefiles. The value of this variable is typically handled by qmake and rarely needs to be modified.

Use the QMAKESPEC environment variable to override the qmake configuration. Note that, due to the way qmake reads project files, setting the QMAKESPEC environment variable from within a project file will have no effect.

QMAKE_APP_FLAG

This variable is empty unless the app TEMPLATE is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified. Use the following instead:

 app {
     # Conditional code for 'app' template here
 }

QMAKE_APP_OR_DLL

This variable is empty unless the app or dll TEMPLATE is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_AR_CMD

This is used on Unix platforms only.

This variable contains the command for invoking the program which creates, modifies and extracts archives. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_BUNDLE_DATA

This variable is used to hold the data that will be installed with a library bundle, and is often used to specify a collection of header files.

For example, the following lines add path/to/header_one.h and path/to/header_two.h to a group containing information about the headers supplied with the framework:

 FRAMEWORK_HEADERS.version = Versions
 FRAMEWORK_HEADERS.files = path/to/header_one.h path/to/header_two.h
 FRAMEWORK_HEADERS.path = Headers
 QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS

The last line adds the information about the headers to the collection of resources that will be installed with the library bundle.

Library bundles are created when the lib_bundle option is added to the CONFIG variable.

See qmake Platform Notes for more information about creating library bundles.

This is used on Mac OS X only.

QMAKE_BUNDLE_EXTENSION

This variable defines the extension to be used for library bundles. This allows frameworks to be created with custom extensions instead of the standard .framework directory name extension.

For example, the following definition will result in a framework with the .myframework extension:

 QMAKE_BUNDLE_EXTENSION = .myframework

This is used on Mac OS X only.

QMAKE_CC

This variable specifies the C compiler that will be used when building projects containing C source code. Only the file name of the compiler executable needs to be specified as long as it is on a path contained in the PATH variable when the Makefile is processed.

QMAKE_CFLAGS_DEBUG

This variable contains the flags for the C compiler in debug mode.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_MT

This variable contains the compiler flags for creating a multi-threaded application or when the version of Qt that you link against is a multi-threaded statically linked library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_MT_DBG

This variable contains the compiler flags for creating a debuggable multi-threaded application or when the version of Qt that you link against is a debuggable multi-threaded statically linked library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_MT_DLL

This is used on Windows only.

This variable contains the compiler flags for creating a multi-threaded dll or when the version of Qt that you link against is a multi-threaded dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_MT_DLLDBG

This is used on Windows only.

This variable contains the compiler flags for creating a debuggable multi-threaded dll or when the version of Qt that you link against is a debuggable multi-threaded statically linked library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_RELEASE

This variable contains the compiler flags for creating a non-debuggable application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_SHLIB

This is used on Unix platforms only.

This variable contains the compiler flags for creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_THREAD

This variable contains the compiler flags for creating a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_WARN_OFF

This variable is not empty if the warn_off TEMPLATE option is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CFLAGS_WARN_ON

This variable is not empty if the warn_on TEMPLATE option is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CLEAN

This variable contains any files which are not generated files (such as moc and uic generated files) and object files that should be removed when using "make clean".

QMAKE_CXX

This variable specifies the C++ compiler that will be used when building projects containing C++ source code. Only the file name of the compiler executable needs to be specified as long as it is on a path contained in the PATH variable when the Makefile is processed.

QMAKE_CXXFLAGS

This variable contains the C++ compiler flags that are used when building a project. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified. The flags specific to debug and release modes can be adjusted by modifying the QMAKE_CXXFLAGS_DEBUG and QMAKE_CXXFLAGS_RELEASE variables, respectively.

QMAKE_CXXFLAGS_DEBUG

This variable contains the C++ compiler flags for creating a debuggable application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_MT

This variable contains the C++ compiler flags for creating a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_MT_DBG

This variable contains the C++ compiler flags for creating a debuggable multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_MT_DLL

This is used on Windows only.

This variable contains the C++ compiler flags for creating a multi-threaded dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_MT_DLLDBG

This is used on Windows only.

This variable contains the C++ compiler flags for creating a multi-threaded debuggable dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_RELEASE

This variable contains the C++ compiler flags for creating an application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_SHLIB

This variable contains the C++ compiler flags for creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_THREAD

This variable contains the C++ compiler flags for creating a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_WARN_OFF

This variable contains the C++ compiler flags for suppressing compiler warnings. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_CXXFLAGS_WARN_ON

This variable contains C++ compiler flags for generating compiler warnings. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_DISTCLEAN

This variable removes extra files upon the invocation of make distclean.

QMAKE_EXTENSION_SHLIB

This variable contains the extention for shared libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

Note that platform-specific variables that change the extension will override the contents of this variable.

QMAKE_EXT_MOC

This variable changes the extention used on included moc files.

See also File Extensions.

QMAKE_EXT_UI

This variable changes the extention used on /e Designer UI files.

See also File Extensions.

QMAKE_EXT_PRL

This variable changes the extention used on created PRL files.

See also File Extensions, Library Dependencies.

QMAKE_EXT_LEX

This variable changes the extention used on files given to lex.

See also File Extensions, LEXSOURCES.

QMAKE_EXT_YACC

This variable changes the extention used on files given to yacc.

See also File Extensions, YACCSOURCES.

QMAKE_EXT_OBJ

This variable changes the extention used on generated object files.

See also File Extensions.

QMAKE_EXT_CPP

This variable changes the interpretation of all suffixes in this list of values as files of type C++ source code.

See also File Extensions.

QMAKE_EXT_H

This variable changes the interpretation of all suffixes in this list of values as files of type C header files.

See also File Extensions.

QMAKE_EXTRA_COMPILERS

This variable contains the extra compilers/preprocessors that have been added

See also Customizing Makefile Output

QMAKE_EXTRA_TARGETS

This variable contains the extra targets that have been added

See also Customizing Makefile Output

QMAKE_FAILED_REQUIREMENTS

This variable contains the list of requirements that were failed to be met when qmake was used. For example, the sql module is needed and wasn't compiled into Qt. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_FILETAGS

This variable contains the file tags needed to be entered into the Makefile, such as SOURCES and HEADERS. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_FRAMEWORK_BUNDLE_NAME

In a framework project, this variable contains the name to be used for the framework that is built.

By default, this variable contains the same value as the TARGET variable.

See qmake Platform Notes for more information about creating frameworks and library bundles.

This is used on Mac OS X only.

QMAKE_FRAMEWORK_VERSION

For projects where the build target is a Mac OS X framework, this variable is used to specify the version number that will be applied to the framework that is built.

By default, this variable contains the same value as the VERSION variable.

See qmake Platform Notes for more information about creating frameworks.

This is used on Mac OS X only.

QMAKE_INCDIR

This variable contains the location of all known header files to be added to INCLUDEPATH when building an application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_OPENGL

This variable contains the location of OpenGL header files to be added to INCLUDEPATH when building an application with OpenGL support. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_QT

This variable contains the location of all known header file paths to be added to INCLUDEPATH when building a Qt application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_THREAD

This variable contains the location of all known header file paths to be added to INCLUDEPATH when building a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INCDIR_X11

This is used on Unix platforms only.

This variable contains the location of X11 header file paths to be added to INCLUDEPATH when building a X11 application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_INFO_PLIST

This is used on Mac OS X platforms only.

This variable contains the name of the property list file, .plist, you would like to include in your Mac OS X application bundle.

In the .plist file, you can define some variables, e.g., @EXECUTABLE@, which qmake will replace with the actual executable name. Other variables include @ICON@, @TYPEINFO@, @LIBRARY@, and @SHORT_VERSION@.

Note: Most of the time, the default Info.plist is good enough.

QMAKE_LFLAGS

This variable contains a general set of flags that are passed to the linker. If you need to change the flags used for a particular platform or type of project, use one of the specialized variables for that purpose instead of this variable.

QMAKE_LFLAGS_CONSOLE

This is used on Windows only.

This variable contains link flags when building console programs. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_CONSOLE_DLL

This is used on Windows only.

This variable contains link flags when building console dlls. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_DEBUG

This variable contains link flags when building debuggable applications. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_PLUGIN

This variable contains link flags when building plugins. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_QT_DLL

This variable contains link flags when building programs that use the Qt library built as a dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_RELEASE

This variable contains link flags when building applications for release. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_SHAPP

This variable contains link flags when building applications which are using the app template. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_SHLIB

This variable contains link flags when building shared libraries The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_SONAME

This variable specifies the link flags to set the name of shared objects, such as .so or .dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_THREAD

This variable contains link flags when building multi-threaded projects. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_WINDOWS

This is used on Windows only.

This variable contains link flags when building Windows GUI projects (i.e. non-console applications). The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LFLAGS_WINDOWS_DLL

This is used on Windows only.

This variable contains link flags when building Windows DLL projects. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR

This variable contains the location of all known library directories.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_FLAGS

This is used on Unix platforms only.

This variable contains the location of all library directory with -L prefixed. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_OPENGL

This variable contains the location of the OpenGL library directory.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_QT

This variable contains the location of the Qt library directory.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBDIR_X11

This is used on Unix platforms only.

This variable contains the location of the X11 library directory.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS

This variable contains all project libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_CONSOLE

This Windows-specific variable is no longer used.

Prior to Qt 4.2, this variable was used to list the libraries that should be linked against when building a console application project on Windows. QMAKE_LIBS_WINDOW should now be used instead.

QMAKE_LIBS_OPENGL

This variable contains all OpenGL libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_OPENGL_QT

This variable contains all OpenGL Qt libraries.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_QT

This variable contains all Qt libraries.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_QT_DLL

This is used on Windows only.

This variable contains all Qt libraries when Qt is built as a dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_QT_OPENGL

This variable contains all the libraries needed to link against if OpenGL support is turned on. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_QT_THREAD

This variable contains all the libraries needed to link against if thread support is turned on. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_RT

This is used with Borland compilers only.

This variable contains the runtime library needed to link against when building an application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_RTMT

This is used with Borland compilers only.

This variable contains the runtime library needed to link against when building a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_THREAD

This is used on Unix platforms only.

This variable contains all libraries that need to be linked against when building a multi-threaded application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_WINDOWS

This is used on Windows only.

This variable contains all windows libraries.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_X11

This is used on Unix platforms only.

This variable contains all X11 libraries.The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIBS_X11SM

This is used on Unix platforms only.

This variable contains all X11 session management libraries. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LIB_FLAG

This variable is not empty if the lib template is specified. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_LINK_SHLIB_CMD

This variable contains the command to execute when creating a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_POST_LINK

This variable contains the command to execute after linking the TARGET together. This variable is normally empty and therefore nothing is executed, additionally some backends will not support this - mostly only Makefile backends.

QMAKE_PRE_LINK

This variable contains the command to execute before linking the TARGET together. This variable is normally empty and therefore nothing is executed, additionally some backends will not support this - mostly only Makefile backends.

QMAKE_LN_SHLIB

This variable contains the command to execute when creating a link to a shared library. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_MAC_SDK

This variable is used on Mac OS X when building universal binaries. This process is described in more detail in the Deploying an Application on Mac OS X document.

QMAKE_MACOSX_DEPLOYMENT_TARGET

This variable only has an effect when building on Mac OS X. On that platform, the variable will be forwarded to the MACOSX_DEPLOYMENT_TARGET environment variable, which is interpreted by the compiler or linker. For more information, see the Deploying an Application on Mac OS X document.

QMAKE_MAKEFILE

This variable contains the name of the Makefile to create. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_MOC_SRC

This variable contains the names of all moc source files to generate and include in the project. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_QMAKE

This variable contains the location of qmake if it is not in the path. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_QT_DLL

This variable is not empty if Qt was built as a dll. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RESOURCE_FLAGS

This variable is used to customize the list of options passed to the Resource Compiler in each of the build rules where it is used. For example, the following line ensures that the -threshold and -compress options are used with particular values each time that rcc is invoked:

 QMAKE_RESOURCE_FLAGS += -threshold 0 -compress 9

QMAKE_RUN_CC

This variable specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CC_IMP

This variable specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CXX

This variable specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_RUN_CXX_IMP

This variable specifies the individual rule needed to build an object. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_TARGET

This variable contains the name of the project target. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

QMAKE_UIC

This variable contains the location of uic if it is not in the path. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

It can be used to specify arguments to uic as well, such as additional plugin paths. For example:

 QMAKE_UIC = uic -L /path/to/plugin

QT

The values stored in the QT variable control which of the Qt modules are used by your project.

The table below shows the options that can be used with the QT variable and the features that are associated with each of them:

By default, QT contains both core and gui, ensuring that standard GUI applications can be built without further configuration.

If you want to build a project without the QtGui module, you need to exclude the gui value with the "-=" operator; the following line will result in a minimal Qt project being built:

 QT -= gui # Only the core module is used.

Note that adding the opengl option to the QT variable automatically causes the equivalent option to be added to the CONFIG variable. Therefore, for Qt applications, it is not necessary to add the opengl option to both CONFIG and QT.

QTPLUGIN

This variable contains a list of names of static plugins that are to be compiled with an application so that they are available as built-in resources.

QT_VERSION

This variable contains the current version of Qt.

QT_MAJOR_VERSION

This variable contains the current major version of Qt.

QT_MINOR_VERSION

This variable contains the current minor version of Qt.

QT_PATCH_VERSION

This variable contains the current patch version of Qt.

RC_FILE

This variable contains the name of the resource file for the application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

RCC_DIR

This variable specifies the directory where all intermediate resource files should be placed.

For example:

 unix:RCC_DIR = ../myproject/resources
 win32:RCC_DIR = c:/myproject/resources

REQUIRES

This is a special variable processed by qmake. If the contents of this variable do not appear in CONFIG by the time this variable is assigned, then a minimal Makefile will be generated that states what dependencies (the values assigned to REQUIRES) are missing.

This is mainly used in Qt's build system for building the examples.

RES_FILE

This variable contains the name of the resource file for the application. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

SIGNATURE_FILE

This is only used on Windows CE.

Specifies which signature file should be used to sign the project target.

Note: This variable will overwrite the setting you have specified in configure, with the -signature option.

SOURCES

This variable contains the name of all source files in the project.

For example:

 SOURCES = myclass.cpp \
       login.cpp \
       mainwindow.cpp

See also HEADERS

SRCMOC

This variable is set by qmake if files can be found that contain the Q_OBJECT macro. SRCMOC contains the name of all the generated moc files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

SUBDIRS

This variable, when used with the subdirs template contains the names of all subdirectories that contain parts of the project that need be built. Each subdirectory must contain its own project file.

For example:

 SUBDIRS = kernel \
           tools

It is essential that the project file in each subdirectory has the same name as the subdirectory itself, so that qmake can find it. For example, if the subdirectory is called myapp then the project file in that directory should be called myapp.pro.

If you need to ensure that the subdirectories are built in the order in which they are specified, update the CONFIG variable to include the ordered option:

 CONFIG += ordered

TARGET

This specifies the name of the target file.

For example:

 TEMPLATE = app
 TARGET = myapp
 SOURCES = main.cpp

The project file above would produce an executable named myapp on unix and 'myapp.exe' on windows.

TARGET_EXT

This variable specifies the target's extension. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TARGET_x

This variable specifies the target's extension with a major version number. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TARGET_x.y.z

This variable specifies the target's extension with version number. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

TEMPLATE

This variable contains the name of the template to use when generating the project. The allowed values are:

For example:

 TEMPLATE = lib
 SOURCES = main.cpp
 TARGET = mylib

The template can be overridden by specifying a new template type with the -t command line option. This overrides the template type after the .pro file has been processed. With .pro files that use the template type to determine how the project is built, it is necessary to declare TEMPLATE on the command line rather than use the -t option.

TRANSLATIONS

This variable contains a list of translation (.ts) files that contain translations of the user interface text into non-native languages.

See the Qt Linguist Manual for more information about internationalization (i18n) and localization (l10n) with Qt.

UICIMPLS

This variable contains a list of the generated implementation files by UIC. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

UICOBJECTS

This variable is generated from the UICIMPLS variable. The extension of each file will have been replaced by .o (Unix) or .obj (Win32). The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

UI_DIR

This variable specifies the directory where all intermediate files from uic should be placed. This variable overrides both UI_SOURCES_DIR and UI_HEADERS_DIR.

For example:

 unix:UI_DIR = ../myproject/ui
 win32:UI_DIR = c:/myproject/ui

UI_HEADERS_DIR

This variable specifies the directory where all declaration files (as generated by uic) should be placed.

For example:

 unix:UI_HEADERS_DIR = ../myproject/ui/include
 win32:UI_HEADERS_DIR = c:/myproject/ui/include

UI_SOURCES_DIR

This variable specifies the directory where all implementation files (as generated by uic) should be placed.

For example:

 unix:UI_SOURCES_DIR = ../myproject/ui/src
 win32:UI_SOURCES_DIR = c:/myproject/ui/src

VERSION

This variable contains the version number of the application or library if either the app TEMPLATE or the lib TEMPLATE is specified.

For example:

 VERSION = 1.2.3

VER_MAJ

This variable contains the major version number of the library, if the lib template is specified.

VER_MIN

This variable contains the minor version number of the library, if the lib template is specified.

VER_PAT

This variable contains the patch version number of the library, if the lib template is specified.

VPATH

This variable tells qmake where to search for files it cannot open. With this you may tell qmake where it may look for things like SOURCES, and if it finds an entry in SOURCES that cannot be opened it will look through the entire VPATH list to see if it can find the file on its own.

See also DEPENDPATH.

YACCIMPLS

This variable contains a list of yacc source files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

YACCOBJECTS

This variable contains a list of yacc object files. The value of this variable is typically handled by qmake or qmake.conf and rarely needs to be modified.

YACCSOURCES

This variable contains a list of yacc source files to be included in the project. All dependencies, headers and source files will automatically be included in the project.

For example:

 YACCSOURCES = moc.y

_PRO_FILE_

This variable contains the path to the project file in use.

For example, the following line causes the location of the project file to be written to the console:

 message($$_PRO_FILE_)

_PRO_FILE_PWD_

This variable contains the path to the directory containing the project file in use.

For example, the following line causes the location of the directory containing the project file to be written to the console:

 message($$_PRO_FILE_PWD_)

[Previous: qmake Reference] [Contents] [Next: qmake Function Reference]