Binding QML Type

Enables the arbitrary creation of property bindings More...

• List of all members, including inherited members

Properties

• property : string
• target : Object
• value : any
• when : bool

Detailed Description

Binding to an Inaccessible Property

Sometimes it is necessary to bind to a property of an object that wasn't directly instantiated by QML - generally a property of a class exported to QML by C++. In these cases, regular property binding doesn't work. Binding allows you to bind any value to any property.

For example, imagine a C++ application that maps an "app.enteredText" property into QML. You could use Binding to update the enteredText property like this.

TextEdit { id: myTextField; text: "Please type here..." }
Binding { target: app; property: "enteredText"; value: myTextField.text }

Whenever the text in the TextEdit is updated, the C++ property will be updated also.

"Single-branch" conditional binding

In some circumstances you may want to control the value of a property only when a certain condition is true (and relinquish control in all other circumstances). This often isn't possible to accomplish with a direct binding, as you need to supply values for all possible branches.

// produces warning: "Unable to assign [undefined] to double value"
value: if (mouse.pressed) mouse.mouseX

The above example will produce a warning whenever we release the mouse, as the value of the binding is undefined when the mouse isn't pressed. We can use the Binding type to rewrite the above code and avoid the warning.

Binding on value {
    when: mouse.pressed
    value: mouse.mouseX
}

The Binding type will also restore any previously set direct bindings on the property. In that sense, it functions much like a simplified State.

// this is equivalent to the above Binding
State {
    name: "pressed"
    when: mouse.pressed
    PropertyChanges {
        target: obj
        value: mouse.mouseX
    }
}

If the binding target or binding property is changed, the bound value is immediately pushed onto the new target.

See also Qt QML.

Property Documentation

Binding {
    target: contactName; property: 'text'
    value: name; when: list.ListView.isCurrentItem
}