Qt Documentation

import.pro Example File

sensor_explorer/import/import.pro

TEMPLATE = lib
CONFIG += plugin

TARGET = $$qtLibraryTarget(declarative_explorer)
DESTDIR = ../Explorer

QT += qml sensors

SOURCES = \
    main.cpp \
    explorer.cpp \
    sensoritem.cpp \
    propertyinfo.cpp

HEADERS = \
    explorer.h \
    sensoritem.h \
    propertyinfo.h

DESTPATH=$$[QT_INSTALL_EXAMPLES]/sensors/sensor_explorer/Explorer

target.path=$$DESTPATH
qmldir.files=$$PWD/qmldir
qmldir.path=$$DESTPATH
INSTALLS += target qmldir

CONFIG += install_ok  # Do not cargo-cult this!

OTHER_FILES += \
    import.json qmldir

# Copy the qmldir file to the same folder as the plugin binary
cpqmldir.files = $$PWD/qmldir
cpqmldir.path = $$DESTDIR
COPIES += cpqmldir

© 2017 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.