Lets the user move forward or backward one frame in a SWF file at run time (does not appear for a single-frame SWF file).

Lets the user set a SWF file to start over automatically when it reaches the final frame (does not appear for a single-frame SWF file).

Lets the user start a paused SWF file (does not appear for a single-frame SWF file).

Lets the user send the displayed frame image to a printer.

Lets the user set the resolution of the SWF file at run time.

Lets the user set a SWF file to play from the first frame when selected, at any time (does not appear for a single-frame SWF file).

Lets the user with Shockmachine installed save a SWF file.

Lets the user zoom in and out on a SWF file at run time.

Creates a new ContextMenuBuiltInItems object so that you can set the properties for Flash Player to display or hide each menu item.

1. A property myContextMenu is declared and then assigned to a new ContextMenu object.
2. The method removeDefaultItems() is called, which removes all built-in context menu items except Print.
3. The method addCustomMenuItems() is called, which places a menu item called Hello World into the customItems array using the push() method of Array.
4. The Hello World menu item is then added to the Stage's context menu item list.
5. A TextField object with the text "Right Click" is added to the center of the Stage by using addChild() via createLabel().

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}