37.11. 从Oracle的 PL/SQL 移植

Example 37-2. 从 PL/SQL 向 PL/pgSQL 移植一个简单的函数

下面是一个Oracle PL/SQL函数：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW errors;

让我们读一遍这个函数然后看看PL/pgSQL与之的不同：

• PostgreSQL 没有命名的参数。 你必须在自己的函数中明确地给它们取个别名。

• Oracle可以有 IN，OUT， 和 INOUT 参数传递给函数。比如， INOUT 的意思是该参数将接受一个数值并且返回另外一个。 PostgreSQL只有 "IN" 参数。

• 在函数原型里的 RETURN （不是函数体里的）关键字到了 PostgreSQL 里就是 RETURNS．

• 在PostgreSQL里，函数是使用单引号做为分隔符创建的， 因此你必须在你的函数体里逃逸单引号。

• 在PostgreSQL里没有 /show errors 命令。

下面是这个函数移植到PostgreSQL之后的样子：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(varchar, varchar)
RETURNS varchar AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE plpgsql;

Example 37-3. 从PL/SQL 向 PL/pgSQL 移植一个创建其它函数的函数

下面的过程从一个 SELECT 语句中抓取若干行， 然后为了提高效率，又用 IF 语句中的结果制作了一个巨大的函数。 请特别注意在游标和 FOR 循环里面的不同。

这是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS 
    CURSOR referrer_keys IS 
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    a_output varchar(4000); 
BEGIN 
    a_output := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN varchar, v_domain IN varchar, 
v_url IN varchar) RETURN varchar IS BEGIN'; 

    for referrer_key in referrer_keys loop 
        a_output := a_output || ' IF v_' || referrer_key.kind || ' LIKE ''' || 
referrer_key.key_string || ''' THEN RETURN ''' || referrer_key.referrer_type || 
'''; END IF;'; 
    END loop; 

    a_output := a_output || ' RETURN NULL; END;'; 
    EXECUTE IMMEDIATE a_output; 
END; 
/ 
show errors;

下面是这个函数在 PostgreSQL 里面的样子：

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS integer AS '
DECLARE
    referrer_keys RECORD;  -- 声明一个在 FOR 里用的通用的记录
    a_output varchar(4000);
BEGIN 
    a_output := ''CREATE FUNCTION cs_find_referrer_type(varchar,varchar,varchar) 
                  RETURNS varchar AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3;
		     BEGIN ''; 

    -- 请注意我们是如何在一个 FOR 循环中使用 FOR <record> 构造
    -- 扫描各条结果的

    FOR referrer_keys IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        a_output := a_output || '' IF v_'' || referrer_keys.kind || '' LIKE '''''''''' 
                 || referrer_keys.key_string || '''''''''' THEN RETURN '''''' 
                 || referrer_keys.referrer_type || ''''''; END IF;''; 
    END LOOP; 
  
    a_output := a_output || '' RETURN NULL; END; '''' LANGUAGE plpgsql;''; 
 
    -- 这样是可以 EXECUTE 的原因是因为我们没有代换任何变量
    -- 否则它可就不能玩了。请查阅 PERFORM 获取另外一种运行函数的方法
    
    EXECUTE a_output; 
END; 
' LANGUAGE plpgsql;

Example 37-4. 从 PL/SQL 向 PL/pgSQL 移植一个字串操作和OUT参数的过程

下面的OraclePL/SQL 过程用于分析一个 URL 并且返回若干个元素 （主机，路径和命令）。PL/pgSQL函数只能返回一个数值。 在 PostgreSQL里，一个绕开这个局限的方法就是把过程分裂成三个不同的函数： 一个返回主机，另外一个返回路径，最后一个返回命令。

下面是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN varchar,
    v_host OUT varchar,  -- 这个变量是要传回的
    v_path OUT varchar,  -- 这个也是
    v_query OUT varchar) -- 还有这个
IS
    a_pos1 integer;
    a_pos2 integer;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); 

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

下面就是把这个过程翻译成PostgreSQL的样子：

CREATE OR REPLACE FUNCTION cs_parse_url_host(varchar) RETURNS varchar AS ' 
DECLARE 
    v_url ALIAS FOR $1; 
    v_host varchar; 
    v_path varchar; 
    a_pos1 integer; 
    a_pos2 integer; 
    a_pos3 integer; 
BEGIN 
    v_host := NULL; 
    a_pos1 := instr(v_url,''//''); 

    IF a_pos1 = 0 THEN 
        RETURN '''';  -- 返回一个空
    END IF; 

    a_pos2 := instr(v_url,''/'',a_pos1 + 2); 
    IF a_pos2 = 0 THEN 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        RETURN v_host; 
    END IF; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    RETURN v_host; 
END; 
' LANGUAGE plpgsql;

Example 37-5. 从 PL/SQL 向 PL/pgSQL 移植一个过程

Oracle 版本：

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id in integer)
IS
    a_running_job_count integer;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- free lock(3)
        raise_application_error(-20000, 'Unable to create a new job: a job IS currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    BEGIN
        INSERT INTO cs_jobs(job_id, start_stamp) values(v_job_id, sysdate);
        EXCEPTION WHEN dup_val_on_index THEN NULL; -- don't worry IF it already exists(4)
    END;
    COMMIT;
END;
/
show errors

象这样的过程可以很容易用返回 integer 的 函数移植到PostgreSQL里．我们对这个过程特别感兴趣是因为它可以教我们一些东西：

下面是我们把这个过程移植到PL/pgSQL里的一种方法：

CREATE OR REPLACE FUNCTION cs_create_job(integer) RETURNS integer AS '
DECLARE
    v_job_id aliAS for $1;
    a_running_job_count integer;
    a_num integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;
    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        RAISE EXCEPTION ''Unable to create a new job: a job IS currently running.'';
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    SELECT count(*) INTO a_num FROM cs_jobs WHERE job_id=v_job_id;
    IF NOT FOUND THEN  -- If nothing wAS RETURNed in the last query
        -- 该作业不在该表中，因此让我们把它插入
        INSERT INTO cs_jobs(job_id, start_stamp) values(v_job_id, current_timestamp);
        RETURN 1;
    ELSE
        RAISE NOTICE ''Job already running.'';(1)
    END IF;

    RETURN 0;
END;
' LANGUAGE plpgsql;